extension/lib/events.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file sets up all event listeners needed to power VimFx: To know when to
  22 # launch commands and to provide state to them. Events in web page content are
  23 # listened for in events-frame.coffee.
  24
  25 button = require('./button')
  26 messageManager = require('./message-manager')
  27 prefs = require('./prefs')
  28 utils = require('./utils')
  29
  30 HELD_MODIFIERS_ATTRIBUTE = 'vimfx-held-modifiers'
  31
  32 class UIEventManager
  33   constructor: (@vimfx, @window) ->
  34     @listen = utils.listen.bind(null, @window)
  35     @listenOnce = utils.listenOnce.bind(null, @window)
  36
  37     # This flag controls whether to suppress the various key events or not.
  38     @suppress = false
  39
  40     # If a matched shortcut has the `<late>` special key, this flag is set to
  41     # `true`.
  42     @late = false
  43
  44     # When a menu or panel is shown VimFx should temporarily stop processing
  45     # keyboard input, allowing accesskeys to be used.
  46     @popupPassthrough = false
  47
  48     @enteredKeys = new EnteredKeysManager(@window)
  49
  50   addListeners: ->
  51     checkPassthrough = (value, event) =>
  52       target = event.originalTarget
  53       if target.localName in ['menupopup', 'panel'] and
  54          # Don’t set `@popupPassthrough` to `false` if there actually are popups
  55          # open. This is the case when a sub-menu closes.
  56          (value or not @anyPopupsOpen())
  57         @popupPassthrough = value
  58
  59     @listen('popupshown',  checkPassthrough.bind(null, true))
  60     @listen('popuphidden', checkPassthrough.bind(null, false))
  61
  62     @listen('keydown', (event) =>
  63       # No matter what, always reset the `@suppress` flag, so we don't
  64       # suppress more than intended.
  65       @suppress = false
  66
  67       # Reset the `@late` flag, telling any late listeners for the previous
  68       # event not to run. Also reset the `late` pref, telling frame scripts not
  69       # to do synchronous message passing on every keydown.
  70       @late = false
  71       prefs.set('late', false)
  72
  73       if @popupPassthrough
  74         # The `@popupPassthrough` flag is set a bit unreliably. Sometimes it
  75         # can be stuck as `true` even though no popup is shown, effectively
  76         # disabling the extension. Therefore we check if there actually _are_
  77         # any open popups before stopping processing keyboard input. This is
  78         # only done when popups (might) be open (not on every keystroke) for
  79         # performance reasons.
  80         return if @anyPopupsOpen()
  81         @popupPassthrough = false # No popup was actually open.
  82
  83       return unless vim = @vimfx.getCurrentVim(@window)
  84
  85       @consumeKeyEvent(vim, event)
  86       if @suppress
  87         utils.suppressEvent(event) # This also suppresses the 'keypress' event.
  88       else
  89         # If this keydown event wasn’t suppressed, it’s an obvious interaction
  90         # with the page. If it _was_ suppressed, though, it’s an interaction
  91         # depending on the command triggered; if _it_ calls
  92         # `vim.markPageInteraction()` or not.
  93         vim.markPageInteraction() if vim.isUIEvent(event)
  94     )
  95
  96     @listen('keyup', (event) =>
  97       utils.suppressEvent(event) if @suppress
  98       @setHeldModifiers(event, {filterCurrentOnly: true})
  99     )
 100
 101     @listen('focus', => @setFocusType())
 102     @listen('blur', =>
 103       @window.setTimeout((=>
 104         @setFocusType()
 105       ), @vimfx.options.blur_timeout)
 106     )
 107
 108     @listen('click', (event) =>
 109       target = event.originalTarget
 110       return unless vim = @vimfx.getCurrentVim(@window)
 111
 112       vim.hideNotification()
 113
 114       # In multi-process, clicks simulated by VimFx cannot be caught here. In
 115       # non-multi-process, they unfortunately can. This hack should be
 116       # sufficient for that case until non-multi-process is removed from
 117       # Firefox.
 118       isVimFxGeneratedEvent = (
 119         event.layerX == 0 and event.layerY == 0 and
 120         event.movementX == 0 and event.movementY == 0
 121       )
 122
 123       # If the user clicks the reload button or a link when in hints mode, we’re
 124       # going to end up in hints mode without any markers. Or if the user clicks
 125       # a text input, then that input will be focused, but you can’t type in it
 126       # (instead markers will be matched). So if the user clicks anything in
 127       # hints mode it’s better to leave it.
 128       if vim.mode == 'hints' and not isVimFxGeneratedEvent and
 129          # Exclude the VimFx button, though, since clicking it returns to normal
 130          # mode. Otherwise we’d first return to normal mode and then the button
 131          # would open the help dialog.
 132          target != button.getButton(@window)
 133         vim.enterMode('normal')
 134
 135       vim._send('clearHover') unless isVimFxGeneratedEvent
 136     )
 137
 138     @listen('overflow', (event) =>
 139       target = event.originalTarget
 140       return unless vim = @vimfx.getCurrentVim(@window)
 141       if vim._isUIElement(target)
 142         vim._state.scrollableElements.addChecked(target)
 143     )
 144
 145     @listen('underflow', (event) =>
 146       target = event.originalTarget
 147       return unless vim = @vimfx.getCurrentVim(@window)
 148       if vim._isUIElement(target)
 149         vim._state.scrollableElements.deleteChecked(target)
 150     )
 151
 152     @listen('TabSelect', (event) =>
 153       target = event.originalTarget
 154       target.setAttribute('VimFx-visited', 'true')
 155       @vimfx.emit('TabSelect', {event})
 156
 157       return unless vim = @vimfx.getCurrentVim(@window)
 158       vim.hideNotification()
 159       @vimfx.emit('focusTypeChange', {vim})
 160     )
 161
 162     @listen('TabClose', (event) =>
 163       browser = @window.gBrowser.getBrowserForTab(event.originalTarget)
 164       return unless vim = @vimfx.vims.get(browser)
 165       # Note: `lastClosedVim` must be stored so that any window can access it.
 166       @vimfx.lastClosedVim = vim
 167     )
 168
 169     messageManager.listen('cachedPageshow', ((data, callback, browser) =>
 170       [oldVim, @vimfx.lastClosedVim] = [@vimfx.lastClosedVim, null]
 171       unless oldVim
 172         callback(false)
 173         return
 174
 175       if @vimfx.vims.has(browser)
 176         vim = @vimfx.vims.get(browser)
 177         if vim._messageManager == vim.browser.messageManager
 178           callback(false)
 179           return
 180
 181       # If we get here, it means that we’ve detected a tab dragged from one
 182       # window to another. If so, the `vim` object from the last closed tab (the
 183       # moved tab) should be re-used. See the commit message for commit bb70257d
 184       # for more details.
 185       oldVim._setBrowser(browser)
 186       @vimfx.vims.set(browser, oldVim)
 187       @vimfx.emit('modeChange', {vim: oldVim})
 188       callback(true)
 189     ), {messageManager: @window.messageManager})
 190
 191   setFocusType: ->
 192     return unless vim = @vimfx.getCurrentVim(@window)
 193
 194     activeElement = utils.getActiveElement(@window)
 195
 196     if activeElement == @window.gBrowser.selectedBrowser
 197       vim._send('checkFocusType')
 198       return
 199
 200     focusType = utils.getFocusType(activeElement)
 201     vim._setFocusType(focusType)
 202
 203     if focusType == 'editable' and vim.mode == 'caret'
 204       vim.enterMode('normal')
 205
 206   consumeKeyEvent: (vim, event) ->
 207     match = vim._consumeKeyEvent(event)
 208
 209     if match
 210       if @vimfx.options.notify_entered_keys and vim.mode != 'ignore'
 211         if match.type in ['none', 'full'] or match.likelyConflict
 212           @enteredKeys.clear(vim)
 213         else
 214           @enteredKeys.push(vim, match.keyStr, @vimfx.options.timeout)
 215       else
 216         vim.hideNotification()
 217
 218       if match.specialKeys['<late>']
 219         @suppress = false
 220         @consumeLateKeydown(vim, event, match)
 221       else
 222         @suppress = vim._onInput(match, event)
 223     else
 224       @suppress = null
 225     @setHeldModifiers(event)
 226
 227   consumeLateKeydown: (vim, event, match) ->
 228     @late = true
 229
 230     # The passed in `event` is the regular non-late browser UI keydown event.
 231     # It is only used to set held keys. This is easier than sending an event
 232     # subset from frame scripts.
 233     listener = ({defaultPrevented}) =>
 234       # `@late` is reset on every keydown. If it is no longer `true`, it means
 235       # that the page called `event.stopPropagation()`, which prevented this
 236       # listener from running for that event.
 237       return unless @late
 238       @suppress =
 239         if defaultPrevented
 240           false
 241         else
 242           vim._onInput(match, event)
 243       @setHeldModifiers(event)
 244       return @suppress
 245
 246     if vim.isUIEvent(event)
 247       @listenOnce('keydown', ((lateEvent) =>
 248         listener(lateEvent)
 249         if @suppress
 250           utils.suppressEvent(lateEvent)
 251           @listenOnce('keyup', utils.suppressEvent, false)
 252       ), false)
 253     else
 254       # Hack to avoid synchronous messages on every keydown (see
 255       # events-frame.coffee).
 256       prefs.set('late', true)
 257       vim._listenOnce('lateKeydown', listener)
 258
 259   setHeldModifiers: (event, {filterCurrentOnly = false} = {}) ->
 260     mainWindow = @window.document.documentElement
 261     modifiers =
 262       if filterCurrentOnly
 263         mainWindow.getAttribute(HELD_MODIFIERS_ATTRIBUTE)
 264       else
 265         if @suppress == null then 'alt ctrl meta shift' else ''
 266     isHeld = (modifier) -> event["#{modifier}Key"]
 267     mainWindow.setAttribute(
 268       HELD_MODIFIERS_ATTRIBUTE, modifiers.split(' ').filter(isHeld).join(' ')
 269     )
 270
 271   anyPopupsOpen: ->
 272     # The autocomplete popup in text inputs (for example) is technically a
 273     # panel, but it does not respond to key presses. Therefore
 274     # `[ignorekeys="true"]` is excluded.
 275     #
 276     # coffeelint: disable=max_line_length
 277     # <https://developer.mozilla.org/en-US/docs/Mozilla/Tech/XUL/PopupGuide/PopupKeys#Ignoring_Keys>
 278     # coffeelint: enable=max_line_length
 279     popups = utils.querySelectorAllDeep(
 280       @window, ':-moz-any(menupopup, panel):not([ignorekeys="true"])'
 281     )
 282     for popup in popups
 283       return true if popup.state == 'open'
 284     return false
 285
 286 class EnteredKeysManager
 287   constructor: (@window) ->
 288     @keys = []
 289     @timeout = null
 290
 291   clear: (notifier) ->
 292     @keys = []
 293     @clearTimeout()
 294     notifier.hideNotification()
 295
 296   push: (notifier, keyStr, duration) ->
 297     @keys.push(keyStr)
 298     @clearTimeout()
 299     notifier.notify(@keys.join(''))
 300     clear = @clear.bind(this)
 301     @timeout = @window.setTimeout((-> clear(notifier)), duration)
 302
 303   clearTimeout: ->
 304     @window.clearTimeout(@timeout) if @timeout?
 305     @timeout = null
 306
 307 module.exports = UIEventManager