extension/lib/commands.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015.
   4 # Copyright Wang Zhuochun 2013, 2014.
   5 #
   6 # This file is part of VimFx.
   7 #
   8 # VimFx is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # VimFx is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  20 ###
  21
  22 # This file defines all Normal mode commands. Commands that need to interact
  23 # with web page content do so by running `vim._run(name)`, which invokes `name`
  24 # in commands-frame.coffee.
  25
  26 # NOTE: Most tab related commands need to do their actual tab manipulations in
  27 # the next tick (`utils.nextTick`) to work around bug 1200334.
  28
  29 help      = require('./help')
  30 hints     = require('./hints')
  31 prefs     = require('./prefs')
  32 translate = require('./l10n')
  33 utils     = require('./utils')
  34
  35 commands = {}
  36
  37
  38
  39 commands.focus_location_bar = ({vim}) ->
  40   vim.window.focusAndSelectUrlBar()
  41
  42 commands.focus_search_bar = ({vim, count}) ->
  43   # The `.webSearch()` method opens a search engine in a tab if the search bar
  44   # has been removed. Therefore we first check if it exists.
  45   if vim.window.BrowserSearch.searchBar
  46     vim.window.BrowserSearch.webSearch()
  47
  48 helper_paste_and_go = (props, {vim}) ->
  49   {gURLBar} = vim.window
  50   gURLBar.value = vim.window.readFromClipboard()
  51   gURLBar.handleCommand(new vim.window.KeyboardEvent('keydown', props))
  52
  53 commands.paste_and_go = helper_paste_and_go.bind(null, null)
  54
  55 commands.paste_and_go_in_tab = helper_paste_and_go.bind(null, {altKey: true})
  56
  57 commands.copy_current_url = ({vim}) ->
  58   utils.writeToClipboard(vim.window.gBrowser.currentURI.spec)
  59   vim.notify(translate('notification.copy_current_url'))
  60
  61 commands.go_up_path = ({vim, count}) ->
  62   vim._run('go_up_path', {count})
  63
  64 commands.go_to_root = ({vim}) ->
  65   vim._run('go_to_root')
  66
  67 commands.go_home = ({vim}) ->
  68   vim.window.BrowserHome()
  69
  70 helper_go_history = (direction, {vim, count = 1}) ->
  71   {SessionStore, gBrowser} = vim.window
  72
  73   # TODO: When Firefox 43 is released, only use the `.getSessionHistory`
  74   # version and bump the minimum Firefox version.
  75   if SessionStore.getSessionHistory
  76     SessionStore.getSessionHistory(gBrowser.selectedTab, (sessionHistory) ->
  77       {index} = sessionHistory
  78       newIndex = index + count * (if direction == 'back' then -1 else 1)
  79       newIndex = Math.max(newIndex, 0)
  80       newIndex = Math.min(newIndex, sessionHistory.entries.length - 1)
  81       if newIndex == index
  82         vim.notify(translate("notification.history_#{direction}.limit"))
  83       else
  84         gBrowser.gotoIndex(newIndex)
  85     )
  86   else
  87     # Until then, fall back to a no-count version.
  88     if direction == 'back' then gBrowser.goBack() else gBrowser.goForward()
  89
  90 commands.history_back    = helper_go_history.bind(null, 'back')
  91
  92 commands.history_forward = helper_go_history.bind(null, 'forward')
  93
  94 commands.history_list = ({vim}) ->
  95   menu = vim.window.document.getElementById('backForwardMenu')
  96   utils.openPopup(menu)
  97   vim.notify(translate('notification.history_list.none')) unless menu.open
  98
  99 commands.reload = ({vim}) ->
 100   vim.window.BrowserReload()
 101
 102 commands.reload_force = ({vim}) ->
 103   vim.window.BrowserReloadSkipCache()
 104
 105 commands.reload_all = ({vim}) ->
 106   vim.window.gBrowser.reloadAllTabs()
 107
 108 commands.reload_all_force = ({vim}) ->
 109   for tab in vim.window.gBrowser.visibleTabs
 110     gBrowser = tab.linkedBrowser
 111     consts = gBrowser.webNavigation
 112     flags = consts.LOAD_FLAGS_BYPASS_PROXY | consts.LOAD_FLAGS_BYPASS_CACHE
 113     gBrowser.reload(flags)
 114   return
 115
 116 commands.stop = ({vim}) ->
 117   vim.window.BrowserStop()
 118
 119 commands.stop_all = ({vim}) ->
 120   for tab in vim.window.gBrowser.visibleTabs
 121     tab.linkedBrowser.stop()
 122   return
 123
 124
 125
 126 helper_scroll = (vim, uiEvent, args...) ->
 127   [
 128     method, type, directions, amounts
 129     properties = null, adjustment = 0, name = 'scroll'
 130   ] = args
 131   options = {
 132     method, type, directions, amounts, properties, adjustment
 133     smooth: (prefs.root.get('general.smoothScroll') and
 134              prefs.root.get("general.smoothScroll.#{type}"))
 135   }
 136   reset = prefs.root.tmp(
 137     'layout.css.scroll-behavior.spring-constant',
 138     vim.options["smoothScroll.#{type}.spring-constant"]
 139   )
 140
 141   helpScroll = help.getHelp(vim.window)?.querySelector('.wrapper')
 142   if uiEvent or helpScroll
 143     activeElement = helpScroll or utils.getActiveElement(vim.window)
 144     if vim._state.scrollableElements.has(activeElement) or helpScroll
 145       utils.scroll(activeElement, options)
 146       reset()
 147       return
 148
 149   vim._run(name, options, reset)
 150
 151
 152 helper_scrollByLinesX = (amount, {vim, uiEvent, count = 1}) ->
 153   distance = prefs.root.get('toolkit.scrollbox.horizontalScrollDistance')
 154   helper_scroll(vim, uiEvent, 'scrollBy', 'lines', ['left'],
 155                 [amount * distance * count * 5])
 156
 157 helper_scrollByLinesY = (amount, {vim, uiEvent, count = 1}) ->
 158   distance = prefs.root.get('toolkit.scrollbox.verticalScrollDistance')
 159   helper_scroll(vim, uiEvent, 'scrollBy', 'lines', ['top'],
 160                 [amount * distance * count * 20])
 161
 162 helper_scrollByPagesY = (amount, type, {vim, uiEvent, count = 1}) ->
 163   adjustment = prefs.get("scroll.#{type}_page_adjustment")
 164   helper_scroll(vim, uiEvent, 'scrollBy', 'pages', ['top'],
 165                 [amount * count], ['clientHeight'], adjustment)
 166
 167 helper_scrollToX = (amount, {vim, uiEvent}) ->
 168   helper_scroll(vim, uiEvent, 'scrollTo', 'other', ['left'],
 169                 [amount], ['scrollLeftMax'])
 170   helper_mark_last_scroll_position(vim)
 171
 172 helper_scrollToY = (amount, {vim, uiEvent}) ->
 173   helper_scroll(vim, uiEvent, 'scrollTo', 'other', ['top'],
 174                 [amount], ['scrollTopMax'])
 175   helper_mark_last_scroll_position(vim)
 176
 177 commands.scroll_left           = helper_scrollByLinesX.bind(null, -1)
 178 commands.scroll_right          = helper_scrollByLinesX.bind(null, +1)
 179 commands.scroll_down           = helper_scrollByLinesY.bind(null, +1)
 180 commands.scroll_up             = helper_scrollByLinesY.bind(null, -1)
 181 commands.scroll_page_down      = helper_scrollByPagesY.bind(null, +1,   'full')
 182 commands.scroll_page_up        = helper_scrollByPagesY.bind(null, -1,   'full')
 183 commands.scroll_half_page_down = helper_scrollByPagesY.bind(null, +0.5, 'half')
 184 commands.scroll_half_page_up   = helper_scrollByPagesY.bind(null, -0.5, 'half')
 185 commands.scroll_to_top         = helper_scrollToY.bind(null, 0)
 186 commands.scroll_to_bottom      = helper_scrollToY.bind(null, Infinity)
 187 commands.scroll_to_left        = helper_scrollToX.bind(null, 0)
 188 commands.scroll_to_right       = helper_scrollToX.bind(null, Infinity)
 189
 190 helper_mark_last_scroll_position = (vim) ->
 191   keyStr = vim.options['scroll.last_position_mark']
 192   vim._run('mark_scroll_position', {keyStr, notify: false})
 193
 194 commands.mark_scroll_position = ({vim}) ->
 195   vim.enterMode('marks', (keyStr) -> vim._run('mark_scroll_position', {keyStr}))
 196
 197 commands.scroll_to_mark = ({vim}) ->
 198   vim.enterMode('marks', (keyStr) ->
 199     unless keyStr == vim.options['scroll.last_position_mark']
 200       helper_mark_last_scroll_position(vim)
 201     helper_scroll(vim, 'scrollTo', 'other', ['top', 'left'], keyStr,
 202                   ['scrollTopMax', 'scrollLeftMax'], 0, 'scroll_to_mark')
 203   )
 204
 205
 206
 207 commands.tab_new = ({vim}) ->
 208   utils.nextTick(vim.window, ->
 209     vim.window.BrowserOpenTab()
 210   )
 211
 212 commands.tab_duplicate = ({vim}) ->
 213   {gBrowser} = vim.window
 214   utils.nextTick(vim.window, ->
 215     gBrowser.duplicateTab(gBrowser.selectedTab)
 216   )
 217
 218 absoluteTabIndex = (relativeIndex, gBrowser, {pinnedSeparate}) ->
 219   tabs = gBrowser.visibleTabs
 220   {selectedTab} = gBrowser
 221
 222   currentIndex  = tabs.indexOf(selectedTab)
 223   absoluteIndex = currentIndex + relativeIndex
 224   numTabsTotal  = tabs.length
 225   numPinnedTabs = gBrowser._numPinnedTabs
 226
 227   [numTabs, min] = switch
 228     when not pinnedSeparate  then [numTabsTotal,  0]
 229     when selectedTab.pinned  then [numPinnedTabs, 0]
 230     else [numTabsTotal - numPinnedTabs, numPinnedTabs]
 231
 232   # Wrap _once_ if at one of the ends of the tab bar and cannot move in the
 233   # current direction.
 234   if (relativeIndex < 0 and currentIndex == min) or
 235      (relativeIndex > 0 and currentIndex == min + numTabs - 1)
 236     if absoluteIndex < min
 237       absoluteIndex += numTabs
 238     else if absoluteIndex >= min + numTabs
 239       absoluteIndex -= numTabs
 240
 241   absoluteIndex = Math.max(min, absoluteIndex)
 242   absoluteIndex = Math.min(absoluteIndex, min + numTabs - 1)
 243
 244   return absoluteIndex
 245
 246 helper_switch_tab = (direction, {vim, count = 1}) ->
 247   {gBrowser} = vim.window
 248   index = absoluteTabIndex(direction * count, gBrowser, {pinnedSeparate: false})
 249   utils.nextTick(vim.window, ->
 250     gBrowser.selectTabAtIndex(index)
 251   )
 252
 253 commands.tab_select_previous = helper_switch_tab.bind(null, -1)
 254
 255 commands.tab_select_next     = helper_switch_tab.bind(null, +1)
 256
 257 commands.tab_select_most_recent = ({vim}) ->
 258   {gBrowser} = vim.window
 259   mostRecentTab = null
 260   for tab in gBrowser.tabs when not tab.closing and tab != gBrowser.selectedTab
 261     if not mostRecentTab or tab.lastAccessed > mostRecentTab.lastAccessed
 262       mostRecentTab = tab
 263   gBrowser.selectedTab = mostRecentTab if mostRecentTab
 264
 265 helper_move_tab = (direction, {vim, count = 1}) ->
 266   {gBrowser} = vim.window
 267   index = absoluteTabIndex(direction * count, gBrowser, {pinnedSeparate: true})
 268   utils.nextTick(vim.window, ->
 269     gBrowser.moveTabTo(gBrowser.selectedTab, index)
 270   )
 271
 272 commands.tab_move_backward = helper_move_tab.bind(null, -1)
 273
 274 commands.tab_move_forward  = helper_move_tab.bind(null, +1)
 275
 276 commands.tab_move_to_window = ({vim}) ->
 277   {gBrowser} = vim.window
 278   gBrowser.replaceTabWithWindow(gBrowser.selectedTab)
 279
 280 commands.tab_select_first = ({vim, count = 1}) ->
 281   utils.nextTick(vim.window, ->
 282     vim.window.gBrowser.selectTabAtIndex(count - 1)
 283   )
 284
 285 commands.tab_select_first_non_pinned = ({vim, count = 1}) ->
 286   firstNonPinned = vim.window.gBrowser._numPinnedTabs
 287   utils.nextTick(vim.window, ->
 288     vim.window.gBrowser.selectTabAtIndex(firstNonPinned + count - 1)
 289   )
 290
 291 commands.tab_select_last = ({vim, count = 1}) ->
 292   utils.nextTick(vim.window, ->
 293     vim.window.gBrowser.selectTabAtIndex(-count)
 294   )
 295
 296 commands.tab_toggle_pinned = ({vim}) ->
 297   currentTab = vim.window.gBrowser.selectedTab
 298   if currentTab.pinned
 299     vim.window.gBrowser.unpinTab(currentTab)
 300   else
 301     vim.window.gBrowser.pinTab(currentTab)
 302
 303 commands.tab_close = ({vim, count = 1}) ->
 304   {gBrowser} = vim.window
 305   return if gBrowser.selectedTab.pinned
 306   currentIndex = gBrowser.visibleTabs.indexOf(gBrowser.selectedTab)
 307   utils.nextTick(vim.window, ->
 308     for tab in gBrowser.visibleTabs[currentIndex...(currentIndex + count)]
 309       gBrowser.removeTab(tab)
 310     return
 311   )
 312
 313 commands.tab_restore = ({vim, count = 1}) ->
 314   utils.nextTick(vim.window, ->
 315     for index in [0...count] by 1
 316       restoredTab = vim.window.undoCloseTab()
 317       if not restoredTab and index == 0
 318         vim.notify(translate('notification.tab_restore.none'))
 319         break
 320     return
 321   )
 322
 323 commands.tab_restore_list = ({vim}) ->
 324   {window} = vim
 325   fragment = window.RecentlyClosedTabsAndWindowsMenuUtils.getTabsFragment(
 326     window, 'menuitem'
 327   )
 328   if fragment.childElementCount == 0
 329     vim.notify(translate('notification.tab_restore.none'))
 330   else
 331     utils.openPopup(utils.injectTemporaryPopup(window.document, fragment))
 332
 333 commands.tab_close_to_end = ({vim}) ->
 334   {gBrowser} = vim.window
 335   gBrowser.removeTabsToTheEndFrom(gBrowser.selectedTab)
 336
 337 commands.tab_close_other = ({vim}) ->
 338   {gBrowser} = vim.window
 339   gBrowser.removeAllTabsBut(gBrowser.selectedTab)
 340
 341
 342
 343 helper_follow = (name, vim, callback, count = null) ->
 344   vim.markPageInteraction()
 345
 346   # Enter hints mode immediately, with an empty set of markers. The user might
 347   # press keys before the `vim._run` callback is invoked. Those key presses
 348   # should be handled in hints mode, not normal mode.
 349   initialMarkers = []
 350   storage = vim.enterMode('hints', initialMarkers, callback, count)
 351
 352   vim._run(name, null, ({wrappers, viewport}) ->
 353     # The user might have exited hints mode (and perhaps even entered it again)
 354     # before this callback is invoked. If so, `storage.markers` has been
 355     # cleared, or set to a new value. Only proceed if it is unchanged.
 356     return unless storage.markers == initialMarkers
 357
 358     if wrappers.length > 0
 359       markers = hints.injectHints(vim.window, wrappers, viewport, vim.options)
 360       storage.markers = markers
 361     else
 362       vim.notify(translate('notification.follow.none'))
 363       vim.enterMode('normal')
 364   )
 365
 366 helper_follow_clickable = ({inTab, inBackground}, {vim, count = 1}) ->
 367   callback = (marker, timesLeft, keyStr) ->
 368     {type, elementIndex} = marker.wrapper
 369     isLast = (timesLeft == 1)
 370     isLink = (type == 'link')
 371
 372     switch
 373       when keyStr.startsWith(vim.options.hints_toggle_in_tab)
 374         inTab = not inTab
 375       when keyStr.startsWith(vim.options.hints_toggle_in_background)
 376         inTab = true
 377         inBackground = not inBackground
 378       else
 379         unless isLast
 380           inTab = true
 381           inBackground = true
 382
 383     inTab = false unless isLink
 384
 385     if type == 'text' or (isLink and not (inTab and inBackground))
 386       isLast = true
 387
 388     vim._focusMarkerElement(elementIndex)
 389
 390     if inTab
 391       utils.nextTick(vim.window, ->
 392         utils.openTab(vim.window, marker.wrapper.href, {
 393           inBackground
 394           relatedToCurrent: true
 395         })
 396       )
 397     else
 398       vim._state.allowNextHintsClick = true
 399       vim._run('click_marker_element', {
 400         elementIndex, type
 401         preventTargetBlank: vim.options.prevent_target_blank
 402       })
 403
 404     return not isLast
 405
 406   name = if inTab then 'follow_in_tab' else 'follow'
 407   helper_follow(name, vim, callback, count)
 408
 409 commands.follow =
 410   helper_follow_clickable.bind(null, {inTab: false, inBackground: true})
 411
 412 commands.follow_in_tab =
 413   helper_follow_clickable.bind(null, {inTab: true, inBackground: true})
 414
 415 commands.follow_in_focused_tab =
 416   helper_follow_clickable.bind(null, {inTab: true, inBackground: false})
 417
 418 commands.follow_in_window = ({vim}) ->
 419   callback = (marker) ->
 420     vim._focusMarkerElement(marker.wrapper.elementIndex)
 421     vim.window.openLinkIn(marker.wrapper.href, 'window', {})
 422   helper_follow('follow_in_tab', vim, callback)
 423
 424 commands.follow_multiple = (args) ->
 425   args.count = Infinity
 426   commands.follow(args)
 427
 428 commands.follow_copy = ({vim}) ->
 429   callback = (marker) ->
 430     {elementIndex} = marker.wrapper
 431     property = switch marker.wrapper.type
 432       when 'link'            then 'href'
 433       when 'text'            then 'value'
 434       when 'contenteditable' then 'textContent'
 435     vim._run('copy_marker_element', {elementIndex, property})
 436   helper_follow('follow_copy', vim, callback)
 437
 438 commands.follow_focus = ({vim}) ->
 439   callback = (marker) ->
 440     vim._focusMarkerElement(marker.wrapper.elementIndex, {select: true})
 441   return helper_follow('follow_focus', vim, callback)
 442
 443 commands.click_browser_element = ({vim}) ->
 444   markerElements = []
 445
 446   filter = (element, getElementShape) ->
 447     document = element.ownerDocument
 448     type = switch
 449       when vim._state.scrollableElements.has(element)
 450         'scrollable'
 451       when element.tabIndex > -1 and
 452            not (element.nodeName.endsWith('box') and
 453                 element.nodeName != 'checkbox') and
 454            element.nodeName not in ['tabs', 'menuitem', 'menuseparator']
 455         'clickable'
 456     return unless type
 457     return unless shape = getElementShape(element)
 458     length = markerElements.push(element)
 459     return {type, semantic: true, shape, elementIndex: length - 1}
 460
 461   callback = (marker) ->
 462     element = markerElements[marker.wrapper.elementIndex]
 463     switch marker.wrapper.type
 464       when 'scrollable'
 465         utils.focusElement(element, {flag: 'FLAG_BYKEY'})
 466       when 'clickable'
 467         utils.focusElement(element)
 468         utils.simulateClick(element)
 469
 470   {wrappers, viewport} =
 471     hints.getMarkableElementsAndViewport(vim.window, filter)
 472
 473   if wrappers.length > 0
 474     markers = hints.injectHints(vim.window, wrappers, viewport, {
 475       hint_chars: vim.options.hint_chars
 476       ui: true
 477     })
 478     vim.enterMode('hints', markers, callback)
 479   else
 480     vim.notify(translate('notification.follow.none'))
 481
 482 helper_follow_pattern = (type, {vim}) ->
 483   options =
 484     pattern_selector: vim.options.pattern_selector
 485     pattern_attrs:    vim.options.pattern_attrs
 486     patterns:         vim.options["#{type}_patterns"]
 487   vim._run('follow_pattern', {type, options})
 488
 489 commands.follow_previous = helper_follow_pattern.bind(null, 'prev')
 490
 491 commands.follow_next     = helper_follow_pattern.bind(null, 'next')
 492
 493 commands.focus_text_input = ({vim, count}) ->
 494   vim.markPageInteraction()
 495   vim._run('focus_text_input', {count})
 496
 497
 498
 499 findStorage = {lastSearchString: ''}
 500
 501 helper_find = ({highlight, linksOnly = false}, {vim}) ->
 502   helpSearchInput = help.getSearchInput(vim.window)
 503   if helpSearchInput
 504     helpSearchInput.select()
 505     return
 506
 507   helper_mark_last_scroll_position(vim)
 508   findBar = vim.window.gBrowser.getFindBar()
 509
 510   mode = if linksOnly then findBar.FIND_LINKS else findBar.FIND_NORMAL
 511   findBar.startFind(mode)
 512   utils.focusElement(findBar._findField, {select: true})
 513
 514   return if linksOnly
 515   return unless highlightButton = findBar.getElement('highlight')
 516   if highlightButton.checked != highlight
 517     highlightButton.click()
 518
 519 commands.find = helper_find.bind(null, {highlight: false})
 520
 521 commands.find_highlight_all = helper_find.bind(null, {highlight: true})
 522
 523 commands.find_links_only = helper_find.bind(null, {linksOnly: true})
 524
 525 helper_find_again = (direction, {vim}) ->
 526   findBar = vim.window.gBrowser.getFindBar()
 527   if findStorage.lastSearchString.length == 0
 528     vim.notify(translate('notification.find_again.none'))
 529     return
 530   helper_mark_last_scroll_position(vim)
 531   findBar._findField.value = findStorage.lastSearchString
 532   findBar.onFindAgainCommand(direction)
 533   message = findBar._findStatusDesc.textContent
 534   vim.notify(message) if message
 535
 536 commands.find_next     = helper_find_again.bind(null, false)
 537
 538 commands.find_previous = helper_find_again.bind(null, true)
 539
 540
 541
 542 commands.window_new = ({vim}) ->
 543   vim.window.OpenBrowserWindow()
 544
 545 commands.window_new_private = ({vim}) ->
 546   vim.window.OpenBrowserWindow({private: true})
 547
 548 commands.enter_mode_ignore = ({vim}) ->
 549   vim.enterMode('ignore')
 550
 551 # Quote next keypress (pass it through to the page).
 552 commands.quote = ({vim, count = 1}) ->
 553   vim.enterMode('ignore', count)
 554
 555 commands.enter_reader_view = ({vim}) ->
 556   button = vim.window.document.getElementById('reader-mode-button')
 557   if not button?.hidden
 558     button.click()
 559   else
 560     vim.notify(translate('notification.enter_reader_view.none'))
 561
 562 commands.help = ({vim}) ->
 563   help.injectHelp(vim.window, vim._parent)
 564
 565 commands.dev = ({vim}) ->
 566   vim.window.DeveloperToolbar.show(true) # `true` to focus.
 567
 568 commands.esc = ({vim}) ->
 569   vim._run('esc')
 570   utils.blurActiveBrowserElement(vim)
 571   vim.window.DeveloperToolbar.hide()
 572   vim.window.gBrowser.getFindBar().close()
 573   # TODO: Remove when Tab Groups have been removed.
 574   vim.window.TabView?.hide()
 575   hints.removeHints(vim.window) # Better safe than sorry.
 576
 577   unless help.getSearchInput(vim.window)?.getAttribute('focused')
 578     help.removeHelp(vim.window)
 579
 580
 581
 582 module.exports = {
 583   commands
 584   findStorage
 585 }