extension/lib/events.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file sets up all event listeners needed to power VimFx: To know when to
  22 # launch commands and to provide state to them. Events in web page content are
  23 # listened for in events-frame.coffee.
  24
  25 button = require('./button')
  26 messageManager = require('./message-manager')
  27 prefs = require('./prefs')
  28 utils = require('./utils')
  29
  30 HELD_MODIFIERS_ATTRIBUTE = 'vimfx-held-modifiers'
  31
  32 class UIEventManager
  33   constructor: (@vimfx, @window) ->
  34     @listen = utils.listen.bind(null, @window)
  35     @listenOnce = utils.listenOnce.bind(null, @window)
  36
  37     # This flag controls whether to suppress the various key events or not.
  38     @suppress = false
  39
  40     # If a matched shortcut has the `<late>` special key, this flag is set to
  41     # `true`.
  42     @late = false
  43
  44     # When a menu or panel is shown VimFx should temporarily stop processing
  45     # keyboard input, allowing accesskeys to be used.
  46     @popupPassthrough = false
  47
  48     @enteredKeys = new EnteredKeysManager(@window)
  49
  50   addListeners: ->
  51     checkPassthrough = (value, event) =>
  52       target = event.originalTarget
  53       if target.localName in ['menupopup', 'panel'] and
  54          # Don’t set `@popupPassthrough` to `false` if there actually are popups
  55          # open. This is the case when a sub-menu closes.
  56          (value or not @anyPopupsOpen())
  57         @popupPassthrough = value
  58
  59     @listen('popupshown',  checkPassthrough.bind(null, true))
  60     @listen('popuphidden', checkPassthrough.bind(null, false))
  61
  62     @listen('keydown', (event) =>
  63       # No matter what, always reset the `@suppress` flag, so we don't
  64       # suppress more than intended.
  65       @suppress = false
  66
  67       # Reset the `@late` flag, telling any late listeners for the previous
  68       # event not to run. Also reset the `late` pref, telling frame scripts not
  69       # to do synchronous message passing on every keydown.
  70       @late = false
  71       prefs.set('late', false)
  72
  73       if @popupPassthrough
  74         # The `@popupPassthrough` flag is set a bit unreliably. Sometimes it
  75         # can be stuck as `true` even though no popup is shown, effectively
  76         # disabling the extension. Therefore we check if there actually _are_
  77         # any open popups before stopping processing keyboard input. This is
  78         # only done when popups (might) be open (not on every keystroke) for
  79         # performance reasons.
  80         return if @anyPopupsOpen()
  81         @popupPassthrough = false # No popup was actually open.
  82
  83       return unless vim = @vimfx.getCurrentVim(@window)
  84
  85       @consumeKeyEvent(vim, event)
  86       if @suppress
  87         utils.suppressEvent(event) # This also suppresses the 'keypress' event.
  88       else
  89         # If this keydown event wasn’t suppressed, it’s an obvious interaction
  90         # with the page. If it _was_ suppressed, though, it’s an interaction
  91         # depending on the command triggered; if _it_ calls
  92         # `vim.markPageInteraction()` or not.
  93         vim.markPageInteraction() if vim.isUIEvent(event)
  94     )
  95
  96     @listen('keyup', (event) =>
  97       utils.suppressEvent(event) if @suppress
  98       @setHeldModifiers(event, {filterCurrentOnly: true})
  99     )
 100
 101     handleFocusRelatedEvent = (event) =>
 102       target = event.originalTarget
 103       return unless vim = @vimfx.getCurrentVim(@window)
 104
 105       if vim.isUIEvent(event)
 106         focusType = utils.getFocusType(utils.getActiveElement(@window))
 107         vim._setFocusType(focusType)
 108
 109     @listen('focus', handleFocusRelatedEvent)
 110     @listen('blur',  handleFocusRelatedEvent)
 111
 112     @listen('click', (event) =>
 113       target = event.originalTarget
 114       return unless vim = @vimfx.getCurrentVim(@window)
 115
 116       # In multi-process, clicks simulated by VimFx cannot be caught here. In
 117       # non-multi-process, they unfortunately can. This hack should be
 118       # sufficient for that case until non-multi-process is removed from
 119       # Firefox.
 120       isVimFxGeneratedEvent = (
 121         event.layerX == 0 and event.layerY == 0 and
 122         event.movementX == 0 and event.movementY == 0
 123       )
 124
 125       # If the user clicks the reload button or a link when in hints mode, we’re
 126       # going to end up in hints mode without any markers. Or if the user clicks
 127       # a text input, then that input will be focused, but you can’t type in it
 128       # (instead markers will be matched). So if the user clicks anything in
 129       # hints mode it’s better to leave it.
 130       if vim.mode == 'hints' and not isVimFxGeneratedEvent and
 131          # Exclude the VimFx button, though, since clicking it returns to normal
 132          # mode. Otherwise we’d first return to normal mode and then the button
 133          # would open the help dialog.
 134          target != button.getButton(@window)
 135         vim.enterMode('normal')
 136
 137       vim._send('clearHover') unless isVimFxGeneratedEvent
 138     )
 139
 140     @listen('overflow', (event) =>
 141       target = event.originalTarget
 142       return unless vim = @vimfx.getCurrentVim(@window)
 143       if vim._isUIElement(target)
 144         vim._state.scrollableElements.addChecked(target)
 145     )
 146
 147     @listen('underflow', (event) =>
 148       target = event.originalTarget
 149       return unless vim = @vimfx.getCurrentVim(@window)
 150       if vim._isUIElement(target)
 151         vim._state.scrollableElements.deleteChecked(target)
 152     )
 153
 154     @listen('TabSelect', (event) =>
 155       target = event.originalTarget
 156       target.setAttribute('VimFx-visited', 'true')
 157       @vimfx.emit('TabSelect', {event})
 158
 159       return unless vim = @vimfx.getCurrentVim(@window)
 160       vim.hideNotification()
 161     )
 162
 163     @listen('TabClose', (event) =>
 164       browser = @window.gBrowser.getBrowserForTab(event.originalTarget)
 165       return unless vim = @vimfx.vims.get(browser)
 166       # Note: `lastClosedVim` must be stored so that any window can access it.
 167       @vimfx.lastClosedVim = vim
 168     )
 169
 170     messageManager.listen('cachedPageshow', ((data, callback, browser) =>
 171       [oldVim, @vimfx.lastClosedVim] = [@vimfx.lastClosedVim, null]
 172       unless oldVim
 173         callback(false)
 174         return
 175
 176       if @vimfx.vims.has(browser)
 177         vim = @vimfx.vims.get(browser)
 178         if vim._messageManager == vim.browser.messageManager
 179           callback(false)
 180           return
 181
 182       # If we get here, it means that we’ve detected a tab dragged from one
 183       # window to another. If so, the `vim` object from the last closed tab (the
 184       # moved tab) should be re-used. See the commit message for commit bb70257d
 185       # for more details.
 186       oldVim._setBrowser(browser)
 187       @vimfx.vims.set(browser, oldVim)
 188       @vimfx.emit('modeChange', {vim: oldVim})
 189       callback(true)
 190     ), {messageManager: @window.messageManager})
 191
 192   consumeKeyEvent: (vim, event) ->
 193     match = vim._consumeKeyEvent(event)
 194
 195     if match
 196       if @vimfx.options.notify_entered_keys
 197         if match.type in ['none', 'full'] or match.likelyConflict
 198           @enteredKeys.clear(vim)
 199         else
 200           @enteredKeys.push(vim, match.keyStr, @vimfx.options.timeout)
 201       else
 202         vim.hideNotification()
 203
 204       if match.specialKeys['<late>']
 205         @suppress = false
 206         @consumeLateKeydown(vim, event, match)
 207       else
 208         @suppress = vim._onInput(match, event)
 209     else
 210       @suppress = null
 211     @setHeldModifiers(event)
 212
 213   consumeLateKeydown: (vim, event, match) ->
 214     @late = true
 215
 216     # The passed in `event` is the regular non-late browser UI keydown event.
 217     # It is only used to set held keys. This is easier than sending an event
 218     # subset from frame scripts.
 219     listener = ({defaultPrevented}) =>
 220       # `@late` is reset on every keydown. If it is no longer `true`, it means
 221       # that the page called `event.stopPropagation()`, which prevented this
 222       # listener from running for that event.
 223       return unless @late
 224       @suppress =
 225         if defaultPrevented
 226           false
 227         else
 228           vim._onInput(match, event)
 229       @setHeldModifiers(event)
 230       return @suppress
 231
 232     if vim.isUIEvent(event)
 233       @listenOnce('keydown', ((lateEvent) =>
 234         listener(lateEvent)
 235         if @suppress
 236           utils.suppressEvent(lateEvent)
 237           @listenOnce('keyup', utils.suppressEvent, false)
 238       ), false)
 239     else
 240       # Hack to avoid synchronous messages on every keydown (see
 241       # events-frame.coffee).
 242       prefs.set('late', true)
 243       vim._listenOnce('lateKeydown', listener)
 244
 245   setHeldModifiers: (event, {filterCurrentOnly = false} = {}) ->
 246     mainWindow = @window.document.documentElement
 247     modifiers =
 248       if filterCurrentOnly
 249         mainWindow.getAttribute(HELD_MODIFIERS_ATTRIBUTE)
 250       else
 251         if @suppress == null then 'alt ctrl meta shift' else ''
 252     isHeld = (modifier) -> event["#{modifier}Key"]
 253     mainWindow.setAttribute(HELD_MODIFIERS_ATTRIBUTE,
 254                             modifiers.split(' ').filter(isHeld).join(' '))
 255
 256   anyPopupsOpen: ->
 257     # The autocomplete popup in text inputs (for example) is technically a
 258     # panel, but it does not respond to key presses. Therefore
 259     # `[ignorekeys="true"]` is excluded.
 260     #
 261     # coffeelint: disable=max_line_length
 262     # <https://developer.mozilla.org/en-US/docs/Mozilla/Tech/XUL/PopupGuide/PopupKeys#Ignoring_Keys>
 263     # coffeelint: enable=max_line_length
 264     popups = utils.querySelectorAllDeep(
 265       @window, ':-moz-any(menupopup, panel):not([ignorekeys="true"])'
 266     )
 267     for popup in popups
 268       return true if popup.state == 'open'
 269     return false
 270
 271 class EnteredKeysManager
 272   constructor: (@window) ->
 273     @keys = []
 274     @timeout = null
 275
 276   clear: (notifier) ->
 277     @keys = []
 278     @clearTimeout()
 279     notifier.hideNotification()
 280
 281   push: (notifier, keyStr, duration) ->
 282     @keys.push(keyStr)
 283     @clearTimeout()
 284     notifier.notify(@keys.join(''))
 285     clear = @clear.bind(this)
 286     @timeout = @window.setTimeout((-> clear(notifier)), duration)
 287
 288   clearTimeout: ->
 289     @window.clearTimeout(@timeout) if @timeout?
 290     @timeout = null
 291
 292 module.exports = UIEventManager