extension/lib/modes.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2013.
   3 # Copyright Simon Lydell 2013, 2014.
   4 # Copyright Wang Zhuochun 2014.
   5 #
   6 # This file is part of VimFx.
   7 #
   8 # VimFx is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # VimFx is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  20 ###
  21
  22 utils                   = require('./utils')
  23 { mode_hints }          = require('./mode-hints/mode-hints')
  24 { updateToolbarButton } = require('./button')
  25 { searchForMatchingCommand
  26 , isEscCommandKey
  27 , isReturnCommandKey
  28 , findStorage }         = require('./commands')
  29
  30 { interfaces: Ci } = Components
  31
  32 XULDocument = Ci.nsIDOMXULDocument
  33
  34 exports['normal'] =
  35   onEnter: (vim, storage) ->
  36     storage.keys ?= []
  37     storage.commands ?= {}
  38
  39   onLeave: (vim, storage) ->
  40     storage.keys.length = 0
  41
  42   onInput: (vim, storage, keyStr, event) ->
  43     isEditable = utils.isElementEditable(event.originalTarget)
  44     autoInsertMode = isEditable or vim.rootWindow.TabView.isVisible()
  45
  46     if autoInsertMode and not isEscCommandKey(keyStr)
  47       return false
  48
  49     storage.keys.push(keyStr)
  50
  51     { match, exact, command, count } = searchForMatchingCommand(storage.keys)
  52
  53     if match
  54       if exact
  55         command.func(vim, event, count)
  56         storage.keys.length = 0
  57
  58       # Esc key is not suppressed, and passed to the browser in normal mode.
  59       #
  60       # - It allows for stopping the loading of the page.
  61       # - It allows for closing many custom dialogs (and perhaps other things
  62       #   -- Esc is a very commonly used key).
  63       # - It is not passed if Esc is used for `command_Esc` and we’re blurring
  64       #   an element. That allows for blurring an input in a custom dialog
  65       #   without closing the dialog too.
  66       # - There are two reasons we might suppress it in other modes. If some
  67       #   custom dialog of a website is open, we should be able to cancel hint
  68       #   markers on it without closing it. Secondly, otherwise cancelling hint
  69       #   markers on Google causes its search bar to be focused.
  70       # - It may only be suppressed in web pages, not in browser chrome. That
  71       #   allows for reseting the location bar when blurring it, and closing
  72       #   dialogs such as the “bookmark this page” dialog (<c-d>).
  73       document = event.originalTarget.ownerDocument
  74       inBrowserChrome = (document instanceof XULDocument)
  75       if keyStr == 'Esc' and (not autoInsertMode or inBrowserChrome)
  76         return false
  77
  78       return true
  79
  80     else
  81       storage.keys.length = 0 unless /\d/.test(keyStr)
  82
  83       return false
  84
  85 exports['insert'] =
  86   onEnter: (vim) ->
  87     updateToolbarButton(vim.rootWindow, {insertMode: true})
  88   onLeave: (vim) ->
  89     updateToolbarButton(vim.rootWindow, {insertMode: false})
  90     utils.blurActiveElement(vim.window)
  91   onInput: (vim, storage, keyStr) ->
  92     if isEscCommandKey(keyStr)
  93       vim.enterMode('normal')
  94       return true
  95
  96 exports['find'] =
  97   onEnter: ->
  98
  99   onLeave: (vim) ->
 100     findBar = vim.rootWindow.gBrowser.getFindBar()
 101     findStorage.lastSearchString = findBar._findField.value
 102
 103   onInput: (vim, storage, keyStr) ->
 104     findBar = vim.rootWindow.gBrowser.getFindBar()
 105     if isEscCommandKey(keyStr) or keyStr == 'Return'
 106       findBar.close()
 107       return true
 108     return false
 109
 110 exports['hints'] = mode_hints