extension/lib/events.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file sets up all event listeners needed to power VimFx: To know when to
  22 # launch commands and to provide state to them. Events in web page content are
  23 # listened for in events-frame.coffee.
  24
  25 button         = require('./button')
  26 messageManager = require('./message-manager')
  27 utils          = require('./utils')
  28
  29 HELD_MODIFIERS_ATTRIBUTE = 'vimfx-held-modifiers'
  30
  31 class UIEventManager
  32   constructor: (@vimfx, @window) ->
  33     @listen = utils.listen.bind(null, @window)
  34     @listenOnce = utils.listenOnce.bind(null, @window)
  35
  36     # This flag controls whether to suppress the various key events or not.
  37     @suppress = false
  38
  39     # If a matched shortcut has the `<late>` special key, this flag is set to
  40     # `true`.
  41     @late = false
  42
  43     # When a menu or panel is shown VimFx should temporarily stop processing
  44     # keyboard input, allowing accesskeys to be used.
  45     @popupPassthrough = false
  46
  47     @enteredKeys = new EnteredKeysManager(@window)
  48
  49   addListeners: ->
  50     checkPassthrough = (value, event) =>
  51       target = event.originalTarget
  52       if target.nodeName in ['menupopup', 'panel']
  53         @popupPassthrough = value
  54
  55     @listen('popupshown',  checkPassthrough.bind(null, true))
  56     @listen('popuphidden', checkPassthrough.bind(null, false))
  57
  58     @listen('keydown', (event) =>
  59       # No matter what, always reset the `@suppress` flag, so we don't
  60       # suppress more than intended.
  61       @suppress = false
  62
  63       # Reset the `@late` flag, telling any late listeners for the previous
  64       # event not to run.
  65       @late = false
  66
  67       if @popupPassthrough
  68         # The `@popupPassthrough` flag is set a bit unreliably. Sometimes it
  69         # can be stuck as `true` even though no popup is shown, effectively
  70         # disabling the extension. Therefore we check if there actually _are_
  71         # any open popups before stopping processing keyboard input. This is
  72         # only done when popups (might) be open (not on every keystroke) of
  73         # performance reasons.
  74         #
  75         # The autocomplete popup in text inputs (for example) is technically a
  76         # panel, but it does not respond to key presses. Therefore
  77         # `[ignorekeys="true"]` is excluded.
  78         #
  79         # coffeelint: disable=max_line_length
  80         # <https://developer.mozilla.org/en-US/docs/Mozilla/Tech/XUL/PopupGuide/PopupKeys#Ignoring_Keys>
  81         # coffeelint: enable=max_line_length
  82         popups = @window.document.querySelectorAll(
  83           ':-moz-any(menupopup, panel):not([ignorekeys="true"])'
  84         )
  85         for popup in popups
  86           return if popup.state == 'open'
  87         @popupPassthrough = false # No popup was actually open.
  88
  89       return unless vim = @vimfx.getCurrentVim(@window)
  90
  91       if vim.isUIEvent(event)
  92         focusType = utils.getFocusType(event.originalTarget)
  93         @consumeKeyEvent(vim, event, focusType, event)
  94         # This also suppresses the 'keypress' event.
  95         utils.suppressEvent(event) if @suppress
  96       else
  97         vim._listenOnce('consumeKeyEvent', ({focusType}) =>
  98           @consumeKeyEvent(vim, event, focusType)
  99           return @suppress
 100         )
 101     )
 102
 103     @listen('keyup', (event) =>
 104       utils.suppressEvent(event) if @suppress
 105       @setHeldModifiers(event, {filterCurrentOnly: true})
 106     )
 107
 108     handleFocusRelatedEvent = (options, event) =>
 109       target = event.originalTarget
 110       return unless vim = @vimfx.getCurrentVim(@window)
 111
 112       findBar = @window.gBrowser.getFindBar()
 113       if target == findBar._findField.mInputField
 114         vim.enterMode(options.mode)
 115
 116       if vim.isUIEvent(event)
 117         focusType = utils.getFocusType(utils.getActiveElement(@window))
 118         @vimfx.emit('focusTypeChange', {vim, focusType})
 119
 120     @listen('focus', handleFocusRelatedEvent.bind(null, {mode: 'find'}))
 121     @listen('blur',  handleFocusRelatedEvent.bind(null, {mode: 'normal'}))
 122
 123     @listen('click', (event) =>
 124       target = event.originalTarget
 125       return unless vim = @vimfx.getCurrentVim(@window)
 126
 127       # If the user clicks the reload button or a link when in hints mode, we’re
 128       # going to end up in hints mode without any markers. Or if the user clicks
 129       # a text input, then that input will be focused, but you can’t type in it
 130       # (instead markers will be matched). So if the user clicks anything in
 131       # hints mode it’s better to leave it.
 132       if vim.mode == 'hints' and vim.isUIEvent(event) and
 133          # Exclude the VimFx button, though, since clicking it returns to normal
 134          # mode. Otherwise we’d first return to normal mode and then the button
 135          # would open the help dialog.
 136          target != button.getButton(@window)
 137         vim.enterMode('normal')
 138     )
 139
 140     @listen('overflow', (event) =>
 141       target = event.originalTarget
 142       return unless vim = @vimfx.getCurrentVim(@window)
 143       vim._state.scrollableElements.addChecked(target)
 144     )
 145
 146     @listen('underflow', (event) =>
 147       target = event.originalTarget
 148       return unless vim = @vimfx.getCurrentVim(@window)
 149       vim._state.scrollableElements.deleteChecked(target)
 150     )
 151
 152     @listen('TabSelect', (event) =>
 153       @vimfx.emit('TabSelect', event)
 154
 155       return unless vim = @vimfx.getCurrentVim(@window)
 156       vim.hideNotification()
 157     )
 158
 159     @listen('TabClose', (event) =>
 160       browser = @window.gBrowser.getBrowserForTab(event.originalTarget)
 161       return unless vim = @vimfx.vims.get(browser)
 162       # Note: `lastClosedVim` must be stored so that any window can access it.
 163       @vimfx.lastClosedVim = vim
 164     )
 165
 166     messageManager.listen('cachedPageshow', ((data, args) =>
 167       {target: browser, callback} = args
 168       exit = (movedToNewTab) ->
 169         messageManager.send(callback, movedToNewTab) if callback
 170
 171       [oldVim, @vimfx.lastClosedVim] = [@vimfx.lastClosedVim, null]
 172       unless oldVim
 173         exit(false)
 174         return
 175
 176       if @vimfx.vims.has(browser)
 177         vim = @vimfx.vims.get(browser)
 178         if vim._messageManager == vim.browser.messageManager
 179           exit(false)
 180           return
 181
 182       # If we get here, it means that we’ve detected a tab dragged from one
 183       # window to another. If so, the `vim` object from the last closed tab (the
 184       # moved tab) should be re-used. See the commit message for commit bb70257d
 185       # for more details.
 186       oldVim._setBrowser(browser)
 187       @vimfx.vims.set(browser, oldVim)
 188       @vimfx.emit('modeChange', oldVim)
 189       exit(true)
 190     ), @window.messageManager)
 191
 192   consumeKeyEvent: (vim, event, focusType, uiEvent = false) ->
 193     match = vim._consumeKeyEvent(event, focusType)
 194
 195     if match
 196       if @vimfx.options.notify_entered_keys
 197         if match.type in ['none', 'full'] or match.focus != null
 198           @enteredKeys.clear(vim)
 199         else
 200           @enteredKeys.push(vim, match.keyStr, @vimfx.options.timeout)
 201       else
 202         vim.hideNotification()
 203
 204       if match.specialKeys['<late>']
 205         @suppress = false
 206         @consumeLateKeydown(vim, event, match, uiEvent)
 207       else
 208         @suppress = vim._onInput(match, uiEvent)
 209     else
 210       @suppress = null
 211     @setHeldModifiers(event)
 212
 213   consumeLateKeydown: (vim, event, match, uiEvent) ->
 214     @late = true
 215
 216     # The passed in `event` is the regular non-late browser UI keydown event.
 217     # It is only used to set held keys. This is easier than sending an event
 218     # subset from frame scripts.
 219     listener = ({defaultPrevented}) =>
 220       # `@late` is reset on every keydown. If it is no longer `true`, it means
 221       # that the page called `event.stopPropagation()`, which prevented this
 222       # listener from running for that event.
 223       return unless @late
 224       @suppress =
 225         if defaultPrevented
 226           false
 227         else
 228           vim._onInput(match, uiEvent)
 229       @setHeldModifiers(event)
 230       return @suppress
 231
 232     if uiEvent
 233       @listenOnce('keydown', ((lateEvent) =>
 234         listener(lateEvent)
 235         if @suppress
 236           utils.suppressEvent(lateEvent)
 237           @listenOnce('keyup', utils.suppressEvent, false)
 238       ), false)
 239     else
 240       vim._listenOnce('lateKeydown', listener)
 241
 242   setHeldModifiers: (event, {filterCurrentOnly = false} = {}) ->
 243     mainWindow = @window.document.documentElement
 244     modifiers =
 245       if filterCurrentOnly
 246         mainWindow.getAttribute(HELD_MODIFIERS_ATTRIBUTE)
 247       else
 248         if @suppress == null then 'alt ctrl meta shift' else ''
 249     isHeld = (modifier) -> event["#{modifier}Key"]
 250     mainWindow.setAttribute(HELD_MODIFIERS_ATTRIBUTE,
 251                             modifiers.split(' ').filter(isHeld).join(' '))
 252
 253 class EnteredKeysManager
 254   constructor: (@window) ->
 255     @keys = []
 256     @timeout = null
 257
 258   clear: (notifier) ->
 259     @keys = []
 260     @clearTimeout()
 261     notifier.hideNotification()
 262
 263   push: (notifier, keyStr, duration) ->
 264     @keys.push(keyStr)
 265     @clearTimeout()
 266     notifier.notify(@keys.join(''))
 267     @timeout = @window.setTimeout(@clear.bind(this, notifier), duration)
 268
 269   clearTimeout: ->
 270     @window.clearTimeout(@timeout) if @timeout?
 271     @timeout = null
 272
 273 module.exports = UIEventManager