extension/lib/vim-frame.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013.
   3 # Copyright Simon Lydell 2013, 2014, 2015.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file is the equivalent to vim.coffee. `vim.window` is called
  22 # `vim.content` to be consistent with Firefox’s frame script terminology and to
  23 # avoid confusion about what it represents. There is one `VimFrame` instance for
  24 # each tab. It mostly tries to mimic the `Vim` class in vim.coffee, but also
  25 # keeps track of web page state. `VimFrame` is not part of the public API.
  26
  27 messageManager     = require('./message-manager')
  28 ScrollableElements = require('./scrollable-elements')
  29 utils              = require('./utils')
  30
  31 class VimFrame
  32   constructor: (@content) ->
  33     @mode = 'normal'
  34
  35     @resetState()
  36
  37     messageManager.listen('modeChange', ({mode}) =>
  38       @mode = mode
  39     )
  40
  41     messageManager.listen('markPageInteraction',
  42                           @markPageInteraction.bind(this))
  43
  44   # If the target is the topmost document, reset everything. Otherwise filter
  45   # out elements belonging to the target frame. On some sites, such as Gmail,
  46   # some elements might be dead at this point.
  47   resetState: (target = @content.document) ->
  48     if target == @content.document
  49       @state =
  50         hasInteraction:       false
  51         shouldRefocus:        false
  52         marks:                {}
  53         explicitBodyFocus:    false
  54         hasFocusedTextInput:  false
  55         lastFocusedTextInput: null
  56         scrollableElements:   new ScrollableElements(@content)
  57         markerElements:       []
  58         inputs:               null
  59
  60     else
  61       isDead = (element) ->
  62         return Cu.isDeadWrapper(element) or element.ownerDocument == target
  63       check = (prop) =>
  64         @state[prop] = null if @state[prop] and isDead(@state[prop])
  65
  66       check('lastFocusedTextInput')
  67       @state.scrollableElements.reject(isDead)
  68       # `markerElements` and `inputs` could theoretically need to be filtered
  69       # too at this point. YAGNI until an issue arises from it.
  70
  71   options: (prefs) -> messageManager.get('options', {prefs})
  72
  73   enterMode: (@mode, args...) ->
  74     messageManager.send('vimMethod', {
  75       method: 'enterMode'
  76       args: [@mode, args...]
  77     })
  78
  79   onInput: (event) ->
  80     focusType = utils.getFocusType(event.originalTarget)
  81     suppress = messageManager.get('consumeKeyEvent', {focusType})
  82     return suppress
  83
  84   notify: (args...) ->
  85     messageManager.send('vimMethod', {method: 'notify', args})
  86
  87   markPageInteraction: -> @state.hasInteraction = true
  88
  89 module.exports = VimFrame