extension/lib/vim-frame.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file is the equivalent to vim.coffee. `vim.window` is called
  22 # `vim.content` to be consistent with Firefox’s frame script terminology and to
  23 # avoid confusion about what it represents. There is one `VimFrame` instance for
  24 # each tab. It mostly tries to mimic the `Vim` class in vim.coffee, but also
  25 # keeps track of web page state. `VimFrame` is not part of the public API.
  26
  27 messageManager     = require('./message-manager')
  28 ScrollableElements = require('./scrollable-elements')
  29 utils              = require('./utils')
  30
  31 class VimFrame
  32   constructor: (@content) ->
  33     @mode = 'normal'
  34
  35     @resetState()
  36
  37     messageManager.listen('modeChange', ({mode}) =>
  38       @mode = mode
  39     )
  40
  41     messageManager.listen('markPageInteraction',
  42                           @markPageInteraction.bind(this))
  43
  44     messageManager.listen('clearHover', @clearHover.bind(this))
  45
  46   # If the target is the topmost document, reset everything. Otherwise filter
  47   # out elements belonging to the target frame. On some sites, such as Gmail,
  48   # some elements might be dead at this point.
  49   resetState: (target = @content.document) ->
  50     if target == @content.document
  51       @state =
  52         hasInteraction:       false
  53         shouldRefocus:        false
  54         marks:                {}
  55         explicitBodyFocus:    false
  56         hasFocusedTextInput:  false
  57         lastFocusedTextInput: null
  58         lastHoveredElement:   null
  59         scrollableElements:   new ScrollableElements(@content)
  60         markerElements:       []
  61         inputs:               null
  62
  63     else
  64       isDead = (element) ->
  65         return Cu.isDeadWrapper(element) or element.ownerDocument == target
  66       check = (prop) =>
  67         @state[prop] = null if @state[prop] and isDead(@state[prop])
  68
  69       check('lastFocusedTextInput')
  70       check('lastHoveredElement')
  71       @state.scrollableElements.reject(isDead)
  72       # `markerElements` and `inputs` could theoretically need to be filtered
  73       # too at this point. YAGNI until an issue arises from it.
  74
  75   options: (prefs) -> messageManager.get('options', {prefs})
  76
  77   enterMode: (@mode, args...) ->
  78     messageManager.send('vimMethod', {
  79       method: 'enterMode'
  80       args: [@mode, args...]
  81     })
  82
  83   onInput: (event) ->
  84     focusType = utils.getFocusType(event.originalTarget)
  85     suppress = messageManager.get('consumeKeyEvent', {focusType})
  86     return suppress
  87
  88   notify: (args...) ->
  89     messageManager.send('vimMethod', {method: 'notify', args})
  90
  91   markPageInteraction: (value = true) -> @state.hasInteraction = value
  92
  93   setHover: (element) ->
  94     utils.setHover(element, true)
  95     utils.simulateMouseEvents(element, 'hover-start')
  96     @state.lastHoveredElement = element
  97
  98   clearHover: ->
  99     if @state.lastHoveredElement
 100       utils.setHover(@state.lastHoveredElement, false)
 101       utils.simulateMouseEvents(@state.lastHoveredElement, 'hover-end')
 102     @state.lastHoveredElement = null
 103
 104 module.exports = VimFrame