extension/lib/main-frame.coffee

   1 ###
   2 # Copyright Simon Lydell 2015, 2016.
   3 #
   4 # This file is part of VimFx.
   5 #
   6 # VimFx is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # VimFx is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  18 ###
  19
  20 # This file is the equivalent of main.coffee, but for frame scripts.
  21
  22 commands = require('./commands-frame')
  23 config = require('./config')
  24 createConfigAPI = require('./api-frame')
  25 FrameEventManager = require('./events-frame')
  26 messageManager = require('./message-manager')
  27 prefs = require('./prefs')
  28 VimFrame = require('./vim-frame')
  29 # @if TESTS
  30 test = require('../test/index')
  31 # @endif
  32
  33 module.exports = ->
  34   {content} = FRAME_SCRIPT_ENVIRONMENT
  35   vim = new VimFrame(content)
  36
  37   eventManager = new FrameEventManager(vim)
  38   eventManager.addListeners()
  39   eventManager.sendFocusType({ignore: ['none']})
  40
  41   messageManager.listen('runCommand', ({name, data}, callback) ->
  42     result = commands[name](Object.assign({vim}, data))
  43     callback?(result)
  44   )
  45
  46   shutdownHandlers = []
  47   onShutdown = (fn) -> shutdownHandlers.push(fn)
  48
  49   loadConfig = ->
  50     configDir = prefs.get('config_file_directory')
  51     scope = {vimfx: createConfigAPI(vim, onShutdown)}
  52     error = config.loadFile(configDir, 'frame.js', scope)
  53     return error
  54
  55   # main.coffee cannot know when the 'loadConfig' listener below is ready, so
  56   # run `loadConfig` manually on startup.
  57   loadConfig()
  58
  59   messageManager.listen('loadConfig', (data, callback) ->
  60     error = loadConfig()
  61     callback(not error)
  62   )
  63
  64   messageManager.listen('unloadConfig', ->
  65     for shutdownHandler in shutdownHandlers
  66       try
  67         shutdownHandler()
  68       catch error
  69         console.error("VimFx: `vimfx.on('shutdown')` error in frame.js", error)
  70     shutdownHandlers = []
  71   )
  72
  73   # @if TESTS
  74   messageManager.send('runTests', null, (ok) -> test(vim) if ok)
  75   # @endif