extension/lib/vim-frame.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file is the equivalent to vim.coffee. `vim.window` is called
  22 # `vim.content` to be consistent with Firefox’s frame script terminology and to
  23 # avoid confusion about what it represents. There is one `VimFrame` instance for
  24 # each tab. It mostly tries to mimic the `Vim` class in vim.coffee, but also
  25 # keeps track of web page state. `VimFrame` is not part of the config file API.
  26
  27 messageManager = require('./message-manager')
  28 ScrollableElements = require('./scrollable-elements')
  29 utils = require('./utils')
  30
  31 class VimFrame
  32   constructor: (@content) ->
  33     @mode = 'normal'
  34     @hintMatcher = null
  35
  36     @resetState()
  37
  38     messageManager.listen('modeChange', ({mode}) =>
  39       @mode = mode
  40     )
  41
  42     messageManager.listen(
  43       'markPageInteraction', @markPageInteraction.bind(this)
  44     )
  45
  46     messageManager.listen('clearHover', @clearHover.bind(this))
  47
  48   # If the target is the topmost document, reset everything. Otherwise filter
  49   # out elements belonging to the target frame. On some sites, such as Gmail,
  50   # some elements might be dead at this point.
  51   resetState: (target = @content.document) ->
  52     if target == @content.document
  53       @state = {
  54         hasInteraction: false
  55         shouldRefocus: false
  56         marks: {}
  57         explicitBodyFocus: false
  58         hasFocusedTextInput: false
  59         lastFocusedTextInput: null
  60         lastHoveredElement: null
  61         scrollableElements: new ScrollableElements(@content)
  62         markerElements: []
  63         inputs: null
  64       }
  65
  66     else
  67       isDead = (element) ->
  68         return Cu.isDeadWrapper(element) or element.ownerDocument == target
  69       check = (prop) =>
  70         @state[prop] = null if @state[prop] and isDead(@state[prop])
  71
  72       check('lastFocusedTextInput')
  73       check('lastHoveredElement')
  74       @state.scrollableElements.reject(isDead)
  75       # `markerElements` and `inputs` could theoretically need to be filtered
  76       # too at this point. YAGNI until an issue arises from it.
  77
  78   options: (prefs) -> messageManager.get('options', {prefs})
  79
  80   _enterMode: (@mode, args...) ->
  81     messageManager.send('vimMethod', {
  82       method: '_enterMode'
  83       args: [@mode, args...]
  84     })
  85
  86   notify: (args...) ->
  87     messageManager.send('vimMethod', {method: 'notify', args})
  88
  89   hideNotification: ->
  90     messageManager.send('vimMethod', {method: 'hideNotification'})
  91
  92   markPageInteraction: (value = true) -> @state.hasInteraction = value
  93
  94   setHover: (element) ->
  95     utils.setHover(element, true)
  96     utils.simulateMouseEvents(element, 'hover-start')
  97     @state.lastHoveredElement = element
  98
  99   clearHover: ->
 100     if @state.lastHoveredElement
 101       utils.setHover(@state.lastHoveredElement, false)
 102       utils.simulateMouseEvents(@state.lastHoveredElement, 'hover-end')
 103     @state.lastHoveredElement = null
 104
 105 module.exports = VimFrame