gulpfile.coffee

   1 fs = require('fs')
   2 path = require('path')
   3 gulp = require('gulp')
   4 coffee = require('gulp-coffee')
   5 coffeelint = require('gulp-coffeelint')
   6 git = require('gulp-git')
   7 header = require('gulp-header')
   8 mustache = require('gulp-mustache')
   9 preprocess = require('gulp-preprocess')
  10 sloc = require('gulp-sloc')
  11 tap = require('gulp-tap')
  12 zip = require('gulp-zip')
  13 marked = require('marked')
  14 merge = require('merge2')
  15 precompute = require('require-precompute')
  16 request = require('request')
  17 rimraf = require('rimraf')
  18 pkg = require('./package.json')
  19
  20 DEST = 'build'
  21 XPI = 'VimFx.xpi'
  22 LOCALE = 'extension/locale'
  23 TEST = 'extension/test'
  24
  25 BASE_LOCALE = 'en-US'
  26 UPDATE_ALL = /\s*UPDATE_ALL$/
  27
  28 ADDON_PATH = 'chrome://vimfx'
  29 BUILD_TIME = Date.now()
  30
  31 argv = process.argv.slice(2)
  32
  33 {join} = path
  34 read = (filepath) -> fs.readFileSync(filepath).toString()
  35 template = (data) -> mustache(data, {extension: ''})
  36
  37 gulp.task('clean', (callback) ->
  38   rimraf(DEST, callback)
  39 )
  40
  41 gulp.task('copy', ->
  42   gulp.src(['extension/**/!(*.coffee|*.tmpl)', 'LICENSE', 'LICENSE-MIT'])
  43     .pipe(gulp.dest(DEST))
  44 )
  45
  46 gulp.task('node_modules', ->
  47   dependencies = (name for name of pkg.dependencies)
  48   # Note: When installing or updating node modules, make sure that the following
  49   # glob does not include too much or too little!
  50   gulp.src(
  51     "node_modules/+(#{dependencies.join('|')})/\
  52      {LICENSE*,{,**/!(test|examples)/}!(*min|*test*|*bench*).js}"
  53   )
  54     .pipe(gulp.dest("#{DEST}/node_modules"))
  55 )
  56
  57 gulp.task('coffee', ->
  58   test = '--test' in argv or '-t' in argv
  59   gulp.src(
  60     [
  61       'extension/bootstrap.coffee'
  62       'extension/lib/**/*.coffee'
  63     ].concat(if test then 'extension/test/**/*.coffee' else []),
  64     {base: 'extension'}
  65   )
  66     .pipe(preprocess({context: {
  67       BUILD_TIME
  68       ADDON_PATH: JSON.stringify(ADDON_PATH)
  69       REQUIRE_DATA: JSON.stringify(precompute('.'), null, 2)
  70       TESTS:
  71         if test
  72           JSON.stringify(fs.readdirSync(TEST)
  73             .map((name) -> name.match(/^(test-.+)\.coffee$/)?[1])
  74             .filter(Boolean)
  75           )
  76         else
  77           null
  78     }}))
  79     .pipe(coffee({bare: true}))
  80     .pipe(gulp.dest(DEST))
  81 )
  82
  83 gulp.task('bootstrap-frame.js', ->
  84   gulp.src('extension/bootstrap-frame.js.tmpl')
  85     .pipe(mustache({ADDON_PATH}))
  86     .pipe(tap((file) ->
  87       file.path = file.path.replace(/\.js\.tmpl$/, "-#{BUILD_TIME}.js")
  88     ))
  89     .pipe(gulp.dest(DEST))
  90 )
  91
  92 gulp.task('chrome.manifest', ->
  93   gulp.src('extension/chrome.manifest.tmpl')
  94     .pipe(template({locales: fs.readdirSync(LOCALE).map((locale) -> {locale})}))
  95     .pipe(gulp.dest(DEST))
  96 )
  97
  98 gulp.task('install.rdf', ->
  99   [[{name: creator}], developers, contributors, translators] =
 100     read('PEOPLE.md').trim().replace(/^#.+\n|^\s*-\s*/mg, '').split('\n\n')
 101     .map((block) -> block.split('\n').map((name) -> {name}))
 102
 103   getDescription = (locale) -> read(join(LOCALE, locale, 'description')).trim()
 104
 105   descriptions = fs.readdirSync(LOCALE)
 106     .filter((locale) -> locale != BASE_LOCALE)
 107     .map((locale) -> {locale, description: getDescription(locale)})
 108
 109   gulp.src('extension/install.rdf.tmpl')
 110     .pipe(template({
 111       idSuffix: if '--unlisted' in argv or '-u' in argv then '-unlisted' else ''
 112       version: pkg.version
 113       minVersion: pkg.firefoxVersions.min
 114       maxVersion: pkg.firefoxVersions.max
 115       creator, developers, contributors, translators
 116       defaultDescription: getDescription(BASE_LOCALE)
 117       descriptions
 118     }))
 119     .pipe(gulp.dest(DEST))
 120 )
 121
 122 gulp.task('templates', gulp.parallel(
 123   'bootstrap-frame.js'
 124   'chrome.manifest'
 125   'install.rdf'
 126 ))
 127
 128 gulp.task('build', gulp.series(
 129   'clean',
 130   gulp.parallel('copy', 'node_modules', 'coffee', 'templates')
 131 ))
 132
 133 gulp.task('xpi-only', ->
 134   gulp.src("#{DEST}/**/*")
 135     .pipe(zip(XPI, {compress: false}))
 136     .pipe(gulp.dest(DEST))
 137 )
 138
 139 gulp.task('xpi', gulp.series('build', 'xpi-only'))
 140
 141 gulp.task('push-only', ->
 142   body = fs.readFileSync(join(DEST, XPI))
 143   request.post({url: 'http://localhost:8888', body})
 144 )
 145
 146 gulp.task('push', gulp.series('xpi', 'push-only'))
 147
 148 gulp.task('default', gulp.series('push'))
 149
 150 # coffeelint-forbidden-keywords has `require('coffee-script/register');` in its
 151 # index.js :(
 152 gulp.task('lint-workaround', ->
 153   gulp.src('node_modules/coffeescript/')
 154     .pipe(gulp.symlink('node_modules/coffee-script'))
 155 )
 156
 157 gulp.task('lint-only', ->
 158   gulp.src(['extension/**/*.coffee', 'gulpfile.coffee'])
 159     .pipe(coffeelint())
 160     .pipe(coffeelint.reporter())
 161 )
 162
 163 gulp.task('lint', gulp.series('lint-workaround', 'lint-only'))
 164
 165 gulp.task('sloc', ->
 166   gulp.src([
 167     'extension/bootstrap.coffee'
 168     'extension/lib/!(migrations|legacy).coffee'
 169   ])
 170     .pipe(sloc())
 171 )
 172
 173 gulp.task('release', (callback) ->
 174   {version} = pkg
 175   message = "VimFx v#{version}"
 176   today = new Date().toISOString()[...10]
 177   merge([
 178     gulp.src('package.json')
 179     gulp.src('CHANGELOG.md')
 180       .pipe(header("### #{version} (#{today})\n\n"))
 181       .pipe(gulp.dest('.'))
 182   ])
 183     .pipe(git.commit(message))
 184     .on('end', ->
 185       git.tag("v#{version}", message, callback)
 186     )
 187   return
 188 )
 189
 190 gulp.task('changelog', (callback) ->
 191   num = 1
 192   for arg in argv when /^-[1-9]$/.test(arg)
 193     num = Number(arg[1])
 194   entries = read('CHANGELOG.md').split(/^### .+/m)[1..num].join('')
 195   process.stdout.write(html(entries))
 196   callback()
 197 )
 198
 199 gulp.task('readme', (callback) ->
 200   process.stdout.write(html(read('README.md')))
 201   callback()
 202 )
 203
 204 # Reduce markdown to the small subset of HTML that AMO allows. Note that AMO
 205 # converts newlines to `<br>`.
 206 html = (string) ->
 207   return marked(string)
 208     .replace(/// <h\d [^>]*> ([^<>]+) </h\d> ///g, '\n\n<b>$1</b>')
 209     .replace(///\s* <p> ((?: [^<] | <(?!/p>) )+) </p>///g, (match, text) ->
 210       return "\n#{text.replace(/\s*\n\s*/g, ' ')}\n\n"
 211     )
 212     .replace(///<li> ((?: [^<] | <(?!/li>) )+) </li>///g, (match, text) ->
 213       return "<li>#{text.replace(/\s*\n\s*/g, ' ')}</li>"
 214     )
 215     .replace(/<br>/g, '\n')
 216     .replace(///<(/?)kbd>///g, '<$1code>')
 217     .replace(/<img[^>]*>\s*/g, '')
 218     .replace(/\n\s*\n/g, '\n\n')
 219     .trim() + '\n'
 220
 221 gulp.task('faster', ->
 222   gulp.src('gulpfile.coffee')
 223     .pipe(coffee({bare: true}))
 224     .pipe(gulp.dest('.'))
 225 )
 226
 227 gulp.task('sync-locales', (callback) ->
 228   baseLocale = BASE_LOCALE
 229   compareLocale = null
 230   for arg in argv when arg[...2] == '--'
 231     name = arg[2..]
 232     if name[-1..] == '?' then compareLocale = name[...-1] else baseLocale = name
 233
 234   results = fs.readdirSync(join(LOCALE, baseLocale))
 235     .filter((file) -> path.extname(file) == '.properties')
 236     .map(syncLocale.bind(null, baseLocale))
 237
 238   if baseLocale == BASE_LOCALE
 239     report = []
 240     for {fileName, untranslated, total} in results
 241       report.push("#{fileName}:")
 242       for localeName, strings of untranslated
 243         paddedName = "#{localeName}:   "[...6]
 244         percentage = Math.round((1 - strings.length / total) * 100)
 245         if localeName == compareLocale or compareLocale == null
 246           report.push("  #{paddedName} #{percentage}%")
 247         if localeName == compareLocale
 248           report.push(strings.map((string) -> "    #{string}")...)
 249     process.stdout.write(report.join('\n') + '\n')
 250
 251   callback()
 252 )
 253
 254 syncLocale = (baseLocaleName, fileName) ->
 255   basePath = join(LOCALE, baseLocaleName, fileName)
 256   base = parseLocaleFile(read(basePath))
 257   untranslated = {}
 258   for localeName in fs.readdirSync(LOCALE)
 259     localePath = join(LOCALE, localeName, fileName)
 260     locale = parseLocaleFile(read(localePath))
 261     untranslated[localeName] = []
 262     newLocale = base.template.map((line, index) ->
 263       if Array.isArray(line)
 264         [key] = line
 265         baseValue = base.keys[key]
 266         value =
 267           if UPDATE_ALL.test(baseValue) or key not of locale.keys
 268             baseValue.replace(UPDATE_ALL, '')
 269           else
 270             locale.keys[key]
 271         result = "#{key}=#{value}"
 272         if value == base.keys[key] and value != ''
 273           untranslated[localeName].push("#{index + 1}: #{result}")
 274         return result
 275       else
 276         return line
 277     )
 278     fs.writeFileSync(localePath, newLocale.join(base.newline))
 279   delete untranslated[baseLocaleName]
 280   return {fileName, untranslated, total: Object.keys(base.keys).length}
 281
 282 parseLocaleFile = (fileContents) ->
 283   keys = {}
 284   lines = []
 285   [newline] = fileContents.match(/\r?\n/)
 286   for line in fileContents.split(newline)
 287     line = line.trim()
 288     [match, key, value] = line.match(///^ ([^=]+) = (.*) $///) ? []
 289     if match
 290       keys[key] = value
 291       lines.push([key])
 292     else
 293       lines.push(line)
 294   return {keys, template: lines, newline}
 295
 296 generateHTMLTask = (filename, message) ->
 297   gulp.task(filename, (callback) ->
 298     unless fs.existsSync(filename)
 299       process.stdout.write(message(filename))
 300       callback()
 301       return
 302     gulp.src(filename)
 303       .pipe(tap((file) ->
 304         file.contents = new Buffer(generateTestHTML(file.contents.toString()))
 305       ))
 306       .pipe(gulp.dest('.'))
 307   )
 308
 309 generateHTMLTask('help.html', (filename) -> """
 310   First enable the “Copy to clipboard” line in help.coffee, show the help
 311   dialog and finally dump the clipboard into #{filename}.
 312 """)
 313
 314 generateHTMLTask('hints.html', (filename) -> """
 315   First enable the “Copy to clipboard” line in modes.coffee, show the
 316   hint markers, activate the “Increase count” command and finally dump the
 317   clipboard into #{filename}.
 318 """)
 319
 320 testHTMLPrelude = '''
 321   <!doctype html>
 322   <meta charset=utf-8>
 323   <title>VimFx test</title>
 324   <style>
 325     * {margin: 0;}
 326     body > :first-child {min-height: 100vh; width: 100vw;}
 327   </style>
 328   <link rel=stylesheet href=extension/skin/style.css>
 329 '''
 330
 331 generateTestHTML = (dumpedHTML) ->
 332   return testHTMLPrelude + dumpedHTML
 333     .replace(/^<\w+ xmlns="[^"]+"/, '<div')
 334     .replace(/\w+>$/, 'div>')
 335     .replace(/<(\w+)([^>]*)\/>/g, '<$1$2></$1>')