extension/lib/vim-frame.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file is the equivalent to vim.coffee. `vim.window` is called
  22 # `vim.content` to be consistent with Firefox’s frame script terminology and to
  23 # avoid confusion about what it represents. There is one `VimFrame` instance for
  24 # each tab. It mostly tries to mimic the `Vim` class in vim.coffee, but also
  25 # keeps track of web page state. `VimFrame` is not part of the config file API.
  26
  27 messageManager = require('./message-manager')
  28 ScrollableElements = require('./scrollable-elements')
  29 utils = require('./utils')
  30
  31 class VimFrame
  32   constructor: (@content) ->
  33     @mode = 'normal'
  34     @hintMatcher = null
  35
  36     @resetState()
  37
  38     messageManager.listen('modeChange', ({mode}) =>
  39       @mode = mode
  40     )
  41
  42     messageManager.listen(
  43       'markPageInteraction', @markPageInteraction.bind(this)
  44     )
  45
  46     messageManager.listen('clearHover', @clearHover.bind(this))
  47
  48   # If the target is the topmost document, reset everything. Otherwise filter
  49   # out elements belonging to the target frame. On some sites, such as Gmail,
  50   # some elements might be dead at this point.
  51   resetState: (target = @content.document) ->
  52     if target == @content.document
  53       @state = {
  54         hasInteraction: false
  55         shouldRefocus: false
  56         marks: {}
  57         explicitBodyFocus: false
  58         hasFocusedTextInput: false
  59         lastFocusedTextInput: null
  60         lastHover: {
  61           element: null
  62           browserOffset: {x: 0, y: 0}
  63         }
  64         scrollableElements: new ScrollableElements(@content)
  65         markerElements: []
  66         inputs: null
  67       }
  68
  69     else
  70       isDead = (element) ->
  71         return Cu.isDeadWrapper(element) or element.ownerDocument == target
  72       check = (obj, prop) ->
  73         obj[prop] = null if obj[prop] and isDead(obj[prop])
  74
  75       check(@state, 'lastFocusedTextInput')
  76       check(@state.lastHover, 'element')
  77       @state.scrollableElements.reject(isDead)
  78       # `markerElements` and `inputs` could theoretically need to be filtered
  79       # too at this point. YAGNI until an issue arises from it.
  80
  81   options: (prefs) -> messageManager.get('options', {prefs})
  82
  83   _enterMode: (@mode, args...) ->
  84     messageManager.send('vimMethod', {
  85       method: '_enterMode'
  86       args: [@mode, args...]
  87     })
  88
  89   notify: (args...) ->
  90     messageManager.send('vimMethod', {method: 'notify', args})
  91
  92   hideNotification: ->
  93     messageManager.send('vimMethod', {method: 'hideNotification'})
  94
  95   markPageInteraction: (value = true) -> @state.hasInteraction = value
  96
  97   setHover: (element, browserOffset) ->
  98     utils.setHover(element, true)
  99     utils.simulateMouseEvents(element, 'hover-start', browserOffset)
 100     @state.lastHover.element = element
 101     @state.lastHover.browserOffset = browserOffset
 102
 103   clearHover: ->
 104     if @state.lastHover.element
 105       {element, browserOffset} = @state.lastHover
 106       utils.setHover(element, false)
 107       utils.simulateMouseEvents(element, 'hover-end', browserOffset)
 108     @state.lastHover.element = null
 109
 110 module.exports = VimFrame