extension/lib/events.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file sets up all event listeners needed to power VimFx: To know when to
  22 # launch commands and to provide state to them. Events in web page content are
  23 # listened for in events-frame.coffee.
  24
  25 button = require('./button')
  26 utils  = require('./utils')
  27
  28 HELD_MODIFIERS_ATTRIBUTE = 'vimfx-held-modifiers'
  29
  30 class UIEventManager
  31   constructor: (@vimfx, @window) ->
  32     @listen = utils.listen.bind(null, @window)
  33     @listenOnce = utils.listenOnce.bind(null, @window)
  34
  35     # This flag controls whether to suppress the various key events or not.
  36     @suppress = false
  37
  38     # If a matched shortcut has the `<late>` special key, this flag is set to
  39     # `true`.
  40     @late = false
  41
  42     # When a menu or panel is shown VimFx should temporarily stop processing
  43     # keyboard input, allowing accesskeys to be used.
  44     @popupPassthrough = false
  45
  46   addListeners: ->
  47     checkPassthrough = (value, event) =>
  48       target = event.originalTarget
  49       if target.nodeName in ['menupopup', 'panel']
  50         @popupPassthrough = value
  51
  52     @listen('popupshown',  checkPassthrough.bind(null, true))
  53     @listen('popuphidden', checkPassthrough.bind(null, false))
  54
  55     @listen('keydown', (event) =>
  56       try
  57         # No matter what, always reset the `@suppress` flag, so we don't
  58         # suppress more than intended.
  59         @suppress = false
  60
  61         # Reset the `@late` flag, telling any late listeners for the previous
  62         # event not to run.
  63         @late = false
  64
  65         if @popupPassthrough
  66           # The `@popupPassthrough` flag is set a bit unreliably. Sometimes it
  67           # can be stuck as `true` even though no popup is shown, effectively
  68           # disabling the extension. Therefore we check if there actually _are_
  69           # any open popups before stopping processing keyboard input. This is
  70           # only done when popups (might) be open (not on every keystroke) of
  71           # performance reasons.
  72           #
  73           # The autocomplete popup in text inputs (for example) is technically a
  74           # panel, but it does not respond to key presses. Therefore
  75           # `[ignorekeys="true"]` is excluded.
  76           #
  77           # coffeelint: disable=max_line_length
  78           # <https://developer.mozilla.org/en-US/docs/Mozilla/Tech/XUL/PopupGuide/PopupKeys#Ignoring_Keys>
  79           # coffeelint: enable=max_line_length
  80           popups = @window.document.querySelectorAll(
  81             ':-moz-any(menupopup, panel):not([ignorekeys="true"])'
  82           )
  83           for popup in popups
  84             return if popup.state == 'open'
  85           @popupPassthrough = false # No popup was actually open.
  86
  87         return unless vim = @vimfx.getCurrentVim(@window)
  88
  89         if vim.isFrameEvent(event)
  90           vim._listenOnce('consumeKeyEvent', ({ focusType }) =>
  91             @consumeKeyEvent(vim, event, focusType, { isFrameEvent: true })
  92             return @suppress
  93           )
  94         else
  95           @consumeKeyEvent(vim, event, utils.getFocusType(event))
  96           # This also suppresses the 'keypress' event.
  97           utils.suppressEvent(event) if @suppress
  98
  99       catch error
 100         console.error(utils.formatError(error))
 101     )
 102
 103     @listen('keyup', (event) =>
 104       utils.suppressEvent(event) if @suppress
 105       @setHeldModifiers(event, {filterCurrentOnly: true})
 106     )
 107
 108     checkFindbar = (mode, event) =>
 109       target = event.originalTarget
 110       findBar = @window.gBrowser.getFindBar()
 111       if target == findBar._findField.mInputField
 112         return unless vim = @vimfx.getCurrentVim(@window)
 113         vim.enterMode(mode)
 114
 115     @listen('focus', checkFindbar.bind(null, 'find'))
 116     @listen('blur',  checkFindbar.bind(null, 'normal'))
 117
 118     @listen('click', (event) =>
 119       target = event.originalTarget
 120       return unless vim = @vimfx.getCurrentVim(@window)
 121
 122       # If the user clicks the reload button or a link when in hints mode, we’re
 123       # going to end up in hints mode without any markers. Or if the user clicks
 124       # a text input, then that input will be focused, but you can’t type in it
 125       # (instead markers will be matched). So if the user clicks anything in
 126       # hints mode it’s better to leave it.
 127       if vim.mode == 'hints' and not vim.isFrameEvent(event) and
 128          # Exclude the VimFx button, though, since clicking it returns to normal
 129          # mode. Otherwise we’d first return to normal mode and then the button
 130          # would open the help dialog.
 131          target != button.getButton(@window)
 132         vim.enterMode('normal')
 133     )
 134
 135     @listen('TabSelect', @vimfx.emit.bind(@vimfx, 'TabSelect'))
 136
 137     lastUrl = null
 138     progressListener =
 139       onLocationChange: (progress, request, location, flags) =>
 140         url     = location.spec
 141         refresh = (url == lastUrl)
 142         lastUrl = url
 143         unless flags & Ci.nsIWebProgressListener.LOCATION_CHANGE_SAME_DOCUMENT
 144           return unless vim = @vimfx.getCurrentVim(@window)
 145           vim._onLocationChange(url, {refresh})
 146
 147     @window.gBrowser.addProgressListener(progressListener)
 148     module.onShutdown(=>
 149       @window.gBrowser.removeProgressListener(progressListener)
 150     )
 151
 152   consumeKeyEvent: (vim, event, focusType, options = {}) ->
 153     match = vim._consumeKeyEvent(event, focusType)
 154     switch
 155       when not match
 156         @suppress = null
 157       when match.specialKeys['<late>']
 158         @suppress = false
 159         @consumeLateKeydown(vim, event, match, options)
 160       else
 161         @suppress = vim._onInput(match, options)
 162     @setHeldModifiers(event)
 163
 164   consumeLateKeydown: (vim, event, match, options) ->
 165     { isFrameEvent = false } = options
 166     @late = true
 167
 168     # The passed in `event` is the regular non-late browser UI keydown event.
 169     # It is only used to set held keys. This is easier than sending an event
 170     # subset from frame scripts.
 171     listener = ({ defaultPrevented }) =>
 172       # `@late` is reset on every keydown. If it is no longer `true`, it means
 173       # that the page called `event.stopPropagation()`, which prevented this
 174       # listener from running for that event.
 175       return unless @late
 176       @suppress =
 177         if defaultPrevented
 178           false
 179         else
 180           vim._onInput(match, options)
 181       @setHeldModifiers(event)
 182       return @suppress
 183
 184     if isFrameEvent
 185       vim._listenOnce('lateKeydown', listener)
 186     else
 187       @listenOnce('keydown', ((lateEvent) =>
 188         listener(lateEvent)
 189         if @suppress
 190           utils.suppressEvent(lateEvent)
 191           @listenOnce('keyup', utils.suppressEvent, false)
 192       ), false)
 193
 194   setHeldModifiers: (event, { filterCurrentOnly = false } = {}) ->
 195     mainWindow = @window.document.documentElement
 196     modifiers =
 197       if filterCurrentOnly
 198         mainWindow.getAttribute(HELD_MODIFIERS_ATTRIBUTE)
 199       else
 200         if @suppress == null then 'alt ctrl meta shift' else ''
 201     isHeld = (modifier) -> event["#{ modifier }Key"]
 202     mainWindow.setAttribute(HELD_MODIFIERS_ATTRIBUTE,
 203                             modifiers.split(' ').filter(isHeld).join(' '))
 204
 205 module.exports = UIEventManager