extension/packages/utils.coffee

   1 { unload } = require 'unload'
   2 { getPref
   3 , setPref
   4 } = require 'prefs'
   5
   6 ADDON_ID = 'VimFx@akhodakivskiy.github.com'
   7
   8 { classes: Cc, interfaces: Ci, utils: Cu } = Components
   9
  10 HTMLInputElement    = Ci.nsIDOMHTMLInputElement
  11 HTMLTextAreaElement = Ci.nsIDOMHTMLTextAreaElement
  12 HTMLSelectElement   = Ci.nsIDOMHTMLSelectElement
  13 XULMenuListElement  = Ci.nsIDOMXULMenuListElement
  14 XULDocument         = Ci.nsIDOMXULDocument
  15 XULElement          = Ci.nsIDOMXULElement
  16 XPathResult         = Ci.nsIDOMXPathResult
  17 HTMLDocument        = Ci.nsIDOMHTMLDocument
  18 HTMLElement         = Ci.nsIDOMHTMLElement
  19 Window              = Ci.nsIDOMWindow
  20 ChromeWindow        = Ci.nsIDOMChromeWindow
  21
  22 _clip = Cc['@mozilla.org/widget/clipboard;1'].getService(Ci.nsIClipboard)
  23
  24 class Bucket
  25   constructor: (@idFunc, @newFunc) ->
  26     @bucket = {}
  27
  28   get: (obj) ->
  29     id = @idFunc(obj)
  30     if container = @bucket[id]
  31       return container
  32     else
  33       return @bucket[id] = @newFunc(obj)
  34
  35   forget: (obj) ->
  36     delete @bucket[id] if id = @idFunc(obj)
  37
  38 getEventWindow = (event) ->
  39   if event.originalTarget instanceof Window
  40     return event.originalTarget
  41   else
  42     doc = event.originalTarget.ownerDocument or event.originalTarget
  43     if doc instanceof HTMLDocument or doc instanceof XULDocument
  44       return doc.defaultView
  45
  46 getEventRootWindow = (event) ->
  47   return unless window = getEventWindow(event)
  48   return getRootWindow(window)
  49
  50 getEventCurrentTabWindow = (event) ->
  51   return unless rootWindow = getEventRootWindow(event)
  52   return getCurrentTabWindow(rootWindow)
  53
  54 getRootWindow = (window) ->
  55   return window
  56     .QueryInterface(Ci.nsIInterfaceRequestor)
  57     .getInterface(Ci.nsIWebNavigation)
  58     .QueryInterface(Ci.nsIDocShellTreeItem)
  59     .rootTreeItem
  60     .QueryInterface(Ci.nsIInterfaceRequestor)
  61     .getInterface(Window)
  62
  63 getCurrentTabWindow = (window) ->
  64   return window.gBrowser.selectedTab.linkedBrowser.contentWindow
  65
  66 blurActiveElement = (window) ->
  67   # Only blur editable elements, in order not to interfere with the browser too much. TODO: Is that
  68   # really needed? What if a website has made more elements focusable -- shouldn't those also be
  69   # blurred?
  70   { activeElement } = window.document
  71   if activeElement and isElementEditable(activeElement)
  72     activeElement.blur()
  73
  74 isTextInputElement = (element) ->
  75   return element instanceof HTMLInputElement or \
  76          element instanceof HTMLTextAreaElement
  77
  78 isElementEditable = (element) ->
  79   return element.isContentEditable or \
  80          element instanceof HTMLInputElement or \
  81          element instanceof HTMLTextAreaElement or \
  82          element instanceof HTMLSelectElement or \
  83          element instanceof XULMenuListElement or \
  84          element.ownerDocument?.designMode?.toLowerCase() == 'on' or \
  85          element.getAttribute?('g_editable') == 'true' or \
  86          element.getAttribute?('contenteditable')?.toLowerCase() == 'true' or \
  87          element.ownerDocument?.designMode?.toLowerCase() == 'on'
  88
  89 isElementVisible = (element) ->
  90   document = element.ownerDocument
  91   window   = document.defaultView
  92   if computedStyle = window.getComputedStyle(element, null)
  93     return computedStyle.getPropertyValue('visibility') == 'visible' and \
  94       computedStyle.getPropertyValue('display') != 'none' and \
  95       computedStyle.getPropertyValue('opacity') != '0'
  96
  97 getWindowId = (window) ->
  98   return window
  99     .QueryInterface(Components.interfaces.nsIInterfaceRequestor)
 100     .getInterface(Components.interfaces.nsIDOMWindowUtils)
 101     .outerWindowID
 102
 103 getSessionStore = ->
 104   Cc['@mozilla.org/browser/sessionstore;1'].getService(Ci.nsISessionStore)
 105
 106 # Function that returns a URI to the css file that's part of the extension
 107 cssUri = do ->
 108   (name) ->
 109     baseURI = Services.io.newURI(__SCRIPT_URI_SPEC__, null, null)
 110     uri = Services.io.newURI("resources/#{ name }.css", null, baseURI)
 111     return uri
 112
 113 # Loads the css identified by the name in the StyleSheetService as User Stylesheet
 114 # The stylesheet is then appended to every document, but it can be overwritten by
 115 # any user css
 116 loadCss = do ->
 117   sss = Cc['@mozilla.org/content/style-sheet-service;1'].getService(Ci.nsIStyleSheetService)
 118   return (name) ->
 119     uri = cssUri(name)
 120     # `AGENT_SHEET` is used to override userContent.css and Stylish. Custom website themes installed
 121     # by users often make the hint markers unreadable, for example. Just using `!important` in the
 122     # CSS is not enough.
 123     if !sss.sheetRegistered(uri, sss.AGENT_SHEET)
 124       sss.loadAndRegisterSheet(uri, sss.AGENT_SHEET)
 125
 126     unload ->
 127       sss.unregisterSheet(uri, sss.AGENT_SHEET)
 128
 129 # Simulate mouse click with full chain of event
 130 # Copied from Vimium codebase
 131 simulateClick = (element, modifiers = {}) ->
 132   document = element.ownerDocument
 133   window = document.defaultView
 134
 135   eventSequence = ['mouseover', 'mousedown', 'mouseup', 'click']
 136   for event in eventSequence
 137     mouseEvent = document.createEvent('MouseEvents')
 138     mouseEvent.initMouseEvent(event, true, true, window, 1, 0, 0, 0, 0, modifiers.ctrlKey, false, false,
 139         modifiers.metaKey, 0, null)
 140     # Debugging note: Firefox will not execute the element's default action if we dispatch this click event,
 141     # but Webkit will. Dispatching a click on an input box does not seem to focus it; we do that separately
 142     element.dispatchEvent(mouseEvent)
 143
 144 WHEEL_MODE_PIXEL = Ci.nsIDOMWheelEvent.DOM_DELTA_PIXEL
 145 WHEEL_MODE_LINE = Ci.nsIDOMWheelEvent.DOM_DELTA_LINE
 146 WHEEL_MODE_PAGE = Ci.nsIDOMWheelEvent.DOM_DELTA_PAGE
 147
 148 # Simulate mouse scroll event by specific offsets given
 149 # that mouse cursor is at specified position
 150 simulateWheel = (window, deltaX, deltaY, mode = WHEEL_MODE_PIXEL) ->
 151   windowUtils = window
 152     .QueryInterface(Ci.nsIInterfaceRequestor)
 153     .getInterface(Ci.nsIDOMWindowUtils)
 154
 155   [pX, pY] = [window.innerWidth / 2, window.innerHeight / 2]
 156   windowUtils.sendWheelEvent(
 157     pX, pY,             # Window offset (x, y) in pixels
 158     deltaX, deltaY, 0,  # Deltas (x, y, z)
 159     mode,               # Mode (pixel, line, page)
 160     0,                  # Key Modifiers
 161     0, 0,               # Line or Page deltas (x, y)
 162     0                   # Options
 163   )
 164
 165 # Write a string into system clipboard
 166 writeToClipboard = (window, text) ->
 167   str = Cc['@mozilla.org/supports-string;1'].createInstance(Ci.nsISupportsString)
 168   str.data = text
 169
 170   trans = Cc['@mozilla.org/widget/transferable;1'].createInstance(Ci.nsITransferable)
 171
 172   if trans.init
 173     privacyContext = window
 174       .QueryInterface(Ci.nsIInterfaceRequestor)
 175       .getInterface(Ci.nsIWebNavigation)
 176       .QueryInterface(Ci.nsILoadContext)
 177     trans.init(privacyContext)
 178
 179   trans.addDataFlavor('text/unicode')
 180   trans.setTransferData('text/unicode', str, text.length * 2)
 181
 182   _clip.setData(trans, null, Ci.nsIClipboard.kGlobalClipboard)
 183
 184 # Write a string into system clipboard
 185 readFromClipboard = (window) ->
 186   trans = Cc['@mozilla.org/widget/transferable;1'].createInstance(Ci.nsITransferable)
 187
 188   if trans.init
 189     privacyContext = window
 190       .QueryInterface(Ci.nsIInterfaceRequestor)
 191       .getInterface(Ci.nsIWebNavigation)
 192       .QueryInterface(Ci.nsILoadContext)
 193     trans.init(privacyContext)
 194
 195   trans.addDataFlavor('text/unicode')
 196
 197   _clip.getData(trans, Ci.nsIClipboard.kGlobalClipboard)
 198
 199   str = {}
 200   strLength = {}
 201
 202   trans.getTransferData('text/unicode', str, strLength)
 203
 204   if str
 205     str = str.value.QueryInterface(Ci.nsISupportsString)
 206     return str.data.substring(0, strLength.value / 2)
 207
 208   return undefined
 209
 210 # Executes function `func` and mearues how much time it took
 211 timeIt = (func, msg) ->
 212   start = new Date().getTime()
 213   result = func()
 214   end = new Date().getTime()
 215
 216   console.log(msg, end - start)
 217   return result
 218
 219 isBlacklisted = (str) ->
 220   matchingRules = getMatchingBlacklistRules(str)
 221   return (matchingRules.length != 0)
 222
 223 # Returns all rules in the blacklist that match the provided string
 224 getMatchingBlacklistRules = (str) ->
 225   return getBlacklist().filter((rule) -> /// ^#{ simpleWildcards(rule) }$ ///i.test(str))
 226
 227 getBlacklist = ->
 228   return splitListString(getPref('black_list'))
 229
 230 setBlacklist = (blacklist) ->
 231   setPref('black_list', blacklist.join(','))
 232
 233 updateBlacklist = ({ add, remove } = {}) ->
 234   blacklist = getBlacklist()
 235
 236   if add
 237     blacklist.push(splitListString(add)...)
 238
 239   blacklist = blacklist.filter((rule) -> rule != '')
 240   blacklist = removeDuplicates(blacklist)
 241
 242   if remove
 243     for rule in splitListString(remove) when rule in blacklist
 244       blacklist.splice(blacklist.indexOf(rule), 1)
 245
 246   setBlacklist(blacklist)
 247
 248 # Splits a comma/space separated list into an array
 249 splitListString = (str) ->
 250   return str.split(/\s*,[\s,]*/)
 251
 252 # Prepares a string to be used in a regexp, where "*" matches zero or more characters
 253 # and "!" matches one character.
 254 simpleWildcards = (string) ->
 255   return regexpEscape(string).replace(/\\\*/g, '.*').replace(/!/g, '.')
 256
 257 # Returns the first element that matches a pattern, favoring earlier patterns.
 258 # The patterns are `simpleWildcards`s and must match either in the beginning or
 259 # at the end of the text of the element. Moreover, a pattern does not match in
 260 # the middle of words, so "previous" does not match "previously". If that is
 261 # desired, a pattern such as "previous*" can be used instead.
 262 # Note: We cannot use `\b` word boundaries, because they don’t work well with
 263 # non-English characters. Instead we match a space as word boundary. Therefore
 264 # we normalize the whitespace and add spaces at the edges of the element text.
 265 getBestPatternMatch = (patterns, elements) ->
 266   for pattern in patterns
 267     wildcarded = simpleWildcards(pattern)
 268     regexp = /// ^\s(?:#{ wildcarded })\s | \s(?:#{ wildcarded })\s$ ///i
 269     for element in elements
 270       text = " #{ element.textContent } ".replace(/\s+/g, ' ')
 271       if regexp.test(text)
 272         return element
 273
 274   return null
 275
 276 # Gets VimFx verions. AddonManager only provides async API to access addon data, so it's a bit tricky...
 277 getVersion = do ->
 278   version = null
 279
 280   if version == null
 281     scope = {}
 282     Cu.import('resource://gre/modules/AddonManager.jsm', scope)
 283     scope.AddonManager.getAddonByID(ADDON_ID, (addon) -> version = addon.version)
 284
 285   return ->
 286     return version
 287
 288 parseHTML = (document, html) ->
 289   parser = Cc['@mozilla.org/parserutils;1'].getService(Ci.nsIParserUtils)
 290   flags = parser.SanitizerAllowStyle
 291   return parser.parseFragment(html, flags, false, null, document.documentElement)
 292
 293 createElement = (document, type, attributes = {}) ->
 294   element = document.createElement(type)
 295
 296   for attribute, value of attributes
 297     element.setAttribute(attribute, value)
 298
 299   if document instanceof HTMLDocument
 300     element.classList.add('VimFxReset')
 301
 302   return element
 303
 304 # Uses nsIIOService to parse a string as a URL and find out if it is a URL
 305 isURL = (str) ->
 306   try
 307     url = Cc['@mozilla.org/network/io-service;1']
 308       .getService(Ci.nsIIOService)
 309       .newURI(str, null, null)
 310       .QueryInterface(Ci.nsIURL)
 311     return true
 312   catch err
 313     return false
 314
 315 # Use Firefox services to search for a given string
 316 browserSearchSubmission = (str) ->
 317   ss = Cc['@mozilla.org/browser/search-service;1']
 318     .getService(Ci.nsIBrowserSearchService)
 319
 320   engine = ss.currentEngine or ss.defaultEngine
 321   return engine.getSubmission(str, null)
 322
 323 # Get hint characters, convert them to lower case, and filter duplicates
 324 getHintChars = ->
 325   hintChars = getPref('hint_chars')
 326   # Make sure that hint chars contain at least two characters
 327   if hintChars.length < 2
 328     hintChars = 'fj'
 329
 330   return removeDuplicateCharacters(hintChars)
 331
 332 # Remove duplicate characters from string (case insensitive)
 333 removeDuplicateCharacters = (str) ->
 334   return removeDuplicates( str.toLowerCase().split('') ).join('')
 335
 336 # Return URI to some file in the extension packaged as resource
 337 getResourceURI = do ->
 338   baseURI = Services.io.newURI(__SCRIPT_URI_SPEC__, null, null)
 339   return (path) -> return Services.io.newURI(path, null, baseURI)
 340
 341 # Escape string to render it usable in regular expressions
 342 regexpEscape = (s) -> s and s.replace(/[-\/\\^$*+?.()|[\]{}]/g, '\\$&')
 343
 344 removeDuplicates = (array) ->
 345   seen = {}
 346   return array.filter((item) -> if seen[item] then false else (seen[item] = true))
 347
 348 ACTION_ELEMENT_TAGS = [
 349   "a"
 350   "area[@href]"
 351   "button"
 352 ]
 353
 354 ACTION_ELEMENT_PROPERTIES = [
 355   "@onclick"
 356   "@onmousedown"
 357   "@onmouseup"
 358   "@oncommand"
 359   "@role='link'"
 360   "@role='button'"
 361   "contains(@class, 'button')"
 362   "contains(@class, 'js-new-tweets-bar')"
 363 ]
 364
 365 EDITABLE_ELEMENT_TAGS = [
 366   "textarea"
 367   "select"
 368   "input[not(@type='hidden' or @disabled)]"
 369 ]
 370
 371 EDITABLE_ELEMENT_PROPERTIES = [
 372   "@contenteditable=''"
 373   "translate(@contenteditable, 'TRUE', 'true')='true'"
 374 ]
 375
 376 FOCUSABLE_ELEMENT_TAGS = [
 377   "iframe"
 378   "embed"
 379   "object"
 380 ]
 381
 382 FOCUSABLE_ELEMENT_PROPERTIES = [
 383   "@tabindex"
 384 ]
 385
 386 getMarkableElements = do ->
 387   xpathify = (tags, properties)->
 388     return tags
 389       .concat("*[#{ properties.join(' or ') }]")
 390       .map((rule) -> "//#{ rule } | //xhtml:#{ rule }")
 391       .join(" | ")
 392
 393   xpaths =
 394     action:    xpathify(ACTION_ELEMENT_TAGS,    ACTION_ELEMENT_PROPERTIES   )
 395     editable:  xpathify(EDITABLE_ELEMENT_TAGS,  EDITABLE_ELEMENT_PROPERTIES )
 396     focusable: xpathify(FOCUSABLE_ELEMENT_TAGS, FOCUSABLE_ELEMENT_PROPERTIES)
 397     all: xpathify(
 398       [ACTION_ELEMENT_TAGS...,       EDITABLE_ELEMENT_TAGS...,       FOCUSABLE_ELEMENT_TAGS...      ],
 399       [ACTION_ELEMENT_PROPERTIES..., EDITABLE_ELEMENT_PROPERTIES..., FOCUSABLE_ELEMENT_PROPERTIES...]
 400     )
 401
 402   namespaceResolver = (namespace) ->
 403     if namespace == 'xhtml' then 'http://www.w3.org/1999/xhtml' else null
 404
 405   # The actual function that will return the desired elements
 406   return (document, { type }, resultType = XPathResult.ORDERED_NODE_SNAPSHOT_TYPE) ->
 407     result = document.evaluate(xpaths[type], document.documentElement, namespaceResolver, resultType, null)
 408     return (result.snapshotItem(i) for i in [0...result.snapshotLength] by 1)
 409
 410
 411 exports.Bucket                    = Bucket
 412 exports.getEventWindow            = getEventWindow
 413 exports.getEventRootWindow        = getEventRootWindow
 414 exports.getEventCurrentTabWindow  = getEventCurrentTabWindow
 415 exports.getRootWindow             = getRootWindow
 416 exports.getCurrentTabWindow       = getCurrentTabWindow
 417
 418 exports.getWindowId               = getWindowId
 419 exports.blurActiveElement         = blurActiveElement
 420 exports.isTextInputElement        = isTextInputElement
 421 exports.isElementEditable         = isElementEditable
 422 exports.isElementVisible          = isElementVisible
 423 exports.getSessionStore           = getSessionStore
 424
 425 exports.loadCss                   = loadCss
 426
 427 exports.simulateClick             = simulateClick
 428 exports.simulateWheel             = simulateWheel
 429 exports.WHEEL_MODE_PIXEL          = WHEEL_MODE_PIXEL
 430 exports.WHEEL_MODE_LINE           = WHEEL_MODE_LINE
 431 exports.WHEEL_MODE_PAGE           = WHEEL_MODE_PAGE
 432 exports.readFromClipboard         = readFromClipboard
 433 exports.writeToClipboard          = writeToClipboard
 434 exports.timeIt                    = timeIt
 435
 436 exports.getMatchingBlacklistRules = getMatchingBlacklistRules
 437 exports.isBlacklisted             = isBlacklisted
 438 exports.updateBlacklist           = updateBlacklist
 439 exports.splitListString           = splitListString
 440 exports.getBestPatternMatch       = getBestPatternMatch
 441
 442 exports.getVersion                = getVersion
 443 exports.parseHTML                 = parseHTML
 444 exports.createElement             = createElement
 445 exports.isURL                     = isURL
 446 exports.browserSearchSubmission   = browserSearchSubmission
 447 exports.getHintChars              = getHintChars
 448 exports.removeDuplicates          = removeDuplicates
 449 exports.removeDuplicateCharacters = removeDuplicateCharacters
 450 exports.getResourceURI            = getResourceURI
 451 exports.getMarkableElements       = getMarkableElements
 452 exports.ADDON_ID                  = ADDON_ID