gulpfile.coffee

   1 fs = require('fs')
   2 path = require('path')
   3 gulp = require('gulp')
   4 coffee = require('gulp-coffee')
   5 coffeelint = require('gulp-coffeelint')
   6 git = require('gulp-git')
   7 header = require('gulp-header')
   8 mustache = require('gulp-mustache')
   9 preprocess = require('gulp-preprocess')
  10 sloc = require('gulp-sloc')
  11 tap = require('gulp-tap')
  12 zip = require('gulp-zip')
  13 marked = require('marked')
  14 merge = require('merge2')
  15 precompute = require('require-precompute')
  16 request = require('request')
  17 rimraf = require('rimraf')
  18 pkg = require('./package.json')
  19
  20 DEST = 'build'
  21 XPI = 'VimFx.xpi'
  22 LOCALE = 'extension/locale'
  23 TEST = 'extension/test'
  24
  25 BASE_LOCALE = 'en-US'
  26 UPDATE_ALL = /\s*UPDATE_ALL$/
  27
  28 ADDON_PATH = 'chrome://vimfx'
  29 BUILD_TIME = Date.now()
  30
  31 argv = process.argv.slice(2)
  32
  33 {join} = path
  34 read = (filepath) -> fs.readFileSync(filepath).toString()
  35 template = (data) -> mustache(data, {extension: ''})
  36
  37 gulp.task('clean', (callback) ->
  38   rimraf(DEST, callback)
  39 )
  40
  41 gulp.task('copy', ->
  42   gulp.src(['extension/**/!(*.coffee|*.tmpl)', 'LICENSE', 'LICENSE-MIT'])
  43     .pipe(gulp.dest(DEST))
  44 )
  45
  46 gulp.task('node_modules', ->
  47   dependencies = (name for name of pkg.dependencies)
  48   # Note: When installing or updating node modules, make sure that the following
  49   # glob does not include too much or too little!
  50   gulp.src(
  51     "node_modules/+(#{dependencies.join('|')})/\
  52      {LICENSE*,{,**/!(test|examples)/}!(*min|*test*|*bench*).js}"
  53   )
  54     .pipe(gulp.dest("#{DEST}/node_modules"))
  55 )
  56
  57 gulp.task('coffee', ->
  58   test = '--test' in argv or '-t' in argv
  59   gulp.src(
  60     [
  61       'extension/bootstrap.coffee'
  62       'extension/lib/**/*.coffee'
  63     ].concat(if test then 'extension/test/**/*.coffee' else []),
  64     {base: 'extension'}
  65   )
  66     .pipe(preprocess({context: {
  67       BUILD_TIME
  68       ADDON_PATH: JSON.stringify(ADDON_PATH)
  69       REQUIRE_DATA: JSON.stringify(precompute('.'), null, 2)
  70       TESTS:
  71         if test
  72           JSON.stringify(fs.readdirSync(TEST)
  73             .map((name) -> name.match(/^(test-.+)\.coffee$/)?[1])
  74             .filter(Boolean)
  75           )
  76         else
  77           null
  78     }}))
  79     .pipe(coffee({bare: true}))
  80     .pipe(gulp.dest(DEST))
  81 )
  82
  83 gulp.task('bootstrap-frame.js', ->
  84   gulp.src('extension/bootstrap-frame.js.tmpl')
  85     .pipe(mustache({ADDON_PATH}))
  86     .pipe(tap((file) ->
  87       file.path = file.path.replace(/\.js\.tmpl$/, "-#{BUILD_TIME}.js")
  88     ))
  89     .pipe(gulp.dest(DEST))
  90 )
  91
  92 gulp.task('chrome.manifest', ->
  93   gulp.src('extension/chrome.manifest.tmpl')
  94     .pipe(template({locales: fs.readdirSync(LOCALE).map((locale) -> {locale})}))
  95     .pipe(gulp.dest(DEST))
  96 )
  97
  98 gulp.task('install.rdf', ->
  99   [[{name: creator}], developers, contributors, translators] =
 100     read('PEOPLE.md').trim().replace(/^#.+\n|^\s*-\s*/mg, '').split('\n\n')
 101     .map((block) -> block.split('\n').map((name) -> {name}))
 102
 103   getDescription = (locale) -> read(join(LOCALE, locale, 'description')).trim()
 104
 105   descriptions = fs.readdirSync(LOCALE)
 106     .filter((locale) -> locale != BASE_LOCALE)
 107     .map((locale) -> {locale, description: getDescription(locale)})
 108
 109   gulp.src('extension/install.rdf.tmpl')
 110     .pipe(template({
 111       idSuffix: if '--unlisted' in argv or '-u' in argv then '-unlisted' else ''
 112       version: pkg.version
 113       minVersion: pkg.firefoxVersions.min
 114       maxVersion: pkg.firefoxVersions.max
 115       creator, developers, contributors, translators
 116       defaultDescription: getDescription(BASE_LOCALE)
 117       descriptions
 118     }))
 119     .pipe(gulp.dest(DEST))
 120 )
 121
 122 gulp.task('templates', gulp.parallel(
 123   'bootstrap-frame.js'
 124   'chrome.manifest'
 125   'install.rdf'
 126 ))
 127
 128 gulp.task('build', gulp.series(
 129   'clean',
 130   gulp.parallel('copy', 'node_modules', 'coffee', 'templates')
 131 ))
 132
 133 gulp.task('xpi', gulp.series('build', ->
 134   gulp.src("#{DEST}/**/*")
 135     .pipe(zip(XPI, {compress: false}))
 136     .pipe(gulp.dest(DEST))
 137 ))
 138
 139 gulp.task('push', gulp.series('xpi', ->
 140   body = fs.readFileSync(join(DEST, XPI))
 141   request.post({url: 'http://localhost:8888', body})
 142 ))
 143
 144 gulp.task('default', gulp.series('push'))
 145
 146 gulp.task('lint', ->
 147   gulp.src(['extension/**/*.coffee', 'gulpfile.coffee'])
 148     .pipe(coffeelint())
 149     .pipe(coffeelint.reporter())
 150 )
 151
 152 gulp.task('sloc', ->
 153   gulp.src([
 154     'extension/bootstrap.coffee'
 155     'extension/lib/!(migrations|legacy).coffee'
 156   ])
 157     .pipe(sloc())
 158 )
 159
 160 gulp.task('release', (callback) ->
 161   {version} = pkg
 162   message = "VimFx v#{version}"
 163   today = new Date().toISOString()[...10]
 164   merge([
 165     gulp.src('package.json')
 166     gulp.src('CHANGELOG.md')
 167       .pipe(header("### #{version} (#{today})\n\n"))
 168       .pipe(gulp.dest('.'))
 169   ])
 170     .pipe(git.commit(message))
 171     .on('end', ->
 172       git.tag("v#{version}", message, callback)
 173     )
 174   return
 175 )
 176
 177 gulp.task('changelog', (callback) ->
 178   num = 1
 179   for arg in argv when /^-[1-9]$/.test(arg)
 180     num = Number(arg[1])
 181   entries = read('CHANGELOG.md').split(/^### .+/m)[1..num].join('')
 182   process.stdout.write(html(entries))
 183   callback()
 184 )
 185
 186 gulp.task('readme', (callback) ->
 187   process.stdout.write(html(read('README.md')))
 188   callback()
 189 )
 190
 191 # Reduce markdown to the small subset of HTML that AMO allows. Note that AMO
 192 # converts newlines to `<br>`.
 193 html = (string) ->
 194   return marked(string)
 195     .replace(/// <h\d [^>]*> ([^<>]+) </h\d> ///g, '\n\n<b>$1</b>')
 196     .replace(///\s* <p> ((?: [^<] | <(?!/p>) )+) </p>///g, (match, text) ->
 197       return "\n#{text.replace(/\s*\n\s*/g, ' ')}\n\n"
 198     )
 199     .replace(///<li> ((?: [^<] | <(?!/li>) )+) </li>///g, (match, text) ->
 200       return "<li>#{text.replace(/\s*\n\s*/g, ' ')}</li>"
 201     )
 202     .replace(/<br>/g, '\n')
 203     .replace(///<(/?)kbd>///g, '<$1code>')
 204     .replace(/<img[^>]*>\s*/g, '')
 205     .replace(/\n\s*\n/g, '\n\n')
 206     .trim() + '\n'
 207
 208 gulp.task('faster', ->
 209   gulp.src('gulpfile.coffee')
 210     .pipe(coffee({bare: true}))
 211     .pipe(gulp.dest('.'))
 212 )
 213
 214 gulp.task('sync-locales', (callback) ->
 215   baseLocale = BASE_LOCALE
 216   compareLocale = null
 217   for arg in argv when arg[...2] == '--'
 218     name = arg[2..]
 219     if name[-1..] == '?' then compareLocale = name[...-1] else baseLocale = name
 220
 221   results = fs.readdirSync(join(LOCALE, baseLocale))
 222     .filter((file) -> path.extname(file) == '.properties')
 223     .map(syncLocale.bind(null, baseLocale))
 224
 225   if baseLocale == BASE_LOCALE
 226     report = []
 227     for {fileName, untranslated, total} in results
 228       report.push("#{fileName}:")
 229       for localeName, strings of untranslated
 230         paddedName = "#{localeName}:   "[...6]
 231         percentage = Math.round((1 - strings.length / total) * 100)
 232         if localeName == compareLocale or compareLocale == null
 233           report.push("  #{paddedName} #{percentage}%")
 234         if localeName == compareLocale
 235           report.push(strings.map((string) -> "    #{string}")...)
 236     process.stdout.write(report.join('\n') + '\n')
 237
 238   callback()
 239 )
 240
 241 syncLocale = (baseLocaleName, fileName) ->
 242   basePath = join(LOCALE, baseLocaleName, fileName)
 243   base = parseLocaleFile(read(basePath))
 244   untranslated = {}
 245   for localeName in fs.readdirSync(LOCALE)
 246     localePath = join(LOCALE, localeName, fileName)
 247     locale = parseLocaleFile(read(localePath))
 248     untranslated[localeName] = []
 249     newLocale = base.template.map((line, index) ->
 250       if Array.isArray(line)
 251         [key] = line
 252         baseValue = base.keys[key]
 253         value =
 254           if UPDATE_ALL.test(baseValue) or key not of locale.keys
 255             baseValue.replace(UPDATE_ALL, '')
 256           else
 257             locale.keys[key]
 258         result = "#{key}=#{value}"
 259         if value == base.keys[key] and value != ''
 260           untranslated[localeName].push("#{index + 1}: #{result}")
 261         return result
 262       else
 263         return line
 264     )
 265     fs.writeFileSync(localePath, newLocale.join(base.newline))
 266   delete untranslated[baseLocaleName]
 267   return {fileName, untranslated, total: Object.keys(base.keys).length}
 268
 269 parseLocaleFile = (fileContents) ->
 270   keys = {}
 271   lines = []
 272   [newline] = fileContents.match(/\r?\n/)
 273   for line in fileContents.split(newline)
 274     line = line.trim()
 275     [match, key, value] = line.match(///^ ([^=]+) = (.*) $///) ? []
 276     if match
 277       keys[key] = value
 278       lines.push([key])
 279     else
 280       lines.push(line)
 281   return {keys, template: lines, newline}
 282
 283 generateHTMLTask = (filename, message) ->
 284   gulp.task(filename, (callback) ->
 285     unless fs.existsSync(filename)
 286       process.stdout.write(message(filename))
 287       callback()
 288       return
 289     gulp.src(filename)
 290       .pipe(tap((file) ->
 291         file.contents = new Buffer(generateTestHTML(file.contents.toString()))
 292       ))
 293       .pipe(gulp.dest('.'))
 294   )
 295
 296 generateHTMLTask('help.html', (filename) -> """
 297   First enable the “Copy to clipboard” line in help.coffee, show the help
 298   dialog and finally dump the clipboard into #{filename}.
 299 """)
 300
 301 generateHTMLTask('hints.html', (filename) -> """
 302   First enable the “Copy to clipboard” line in modes.coffee, show the
 303   hint markers, activate the “Increase count” command and finally dump the
 304   clipboard into #{filename}.
 305 """)
 306
 307 testHTMLPrelude = '''
 308   <!doctype html>
 309   <meta charset=utf-8>
 310   <title>VimFx test</title>
 311   <style>
 312     * {margin: 0;}
 313     body > :first-child {min-height: 100vh; width: 100vw;}
 314   </style>
 315   <link rel=stylesheet href=extension/skin/style.css>
 316 '''
 317
 318 generateTestHTML = (dumpedHTML) ->
 319   return testHTMLPrelude + dumpedHTML
 320     .replace(/^<\w+ xmlns="[^"]+"/, '<div')
 321     .replace(/\w+>$/, 'div>')
 322     .replace(/<(\w+)([^>]*)\/>/g, '<$1$2></$1>')