extension/lib/modes.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2013.
   3 # Copyright Simon Lydell 2013, 2014.
   4 # Copyright Wang Zhuochun 2014.
   5 #
   6 # This file is part of VimFx.
   7 #
   8 # VimFx is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # VimFx is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  20 ###
  21
  22 utils                   = require('./utils')
  23 { mode_hints }          = require('./mode-hints/mode-hints')
  24 { updateToolbarButton } = require('./button')
  25 { searchForMatchingCommand
  26 , isEscCommandKey
  27 , isReturnCommandKey
  28 , findStorage }         = require('./commands')
  29
  30 { interfaces: Ci } = Components
  31
  32 XULDocument = Ci.nsIDOMXULDocument
  33
  34 exports['normal'] =
  35   onEnter: (vim, storage) ->
  36     storage.keys ?= []
  37     storage.commands ?= {}
  38
  39   onLeave: (vim, storage) ->
  40     storage.keys.length = 0
  41
  42   onInput: (vim, storage, keyStr, event) ->
  43     isEditable = utils.isElementEditable(event.originalTarget)
  44     autoInsertMode = isEditable or vim.rootWindow.TabView.isVisible()
  45
  46     if autoInsertMode and not isEscCommandKey(keyStr)
  47       return false
  48
  49     storage.keys.push(keyStr)
  50
  51     { match, exact, command, count } = searchForMatchingCommand(storage.keys)
  52
  53     if vim.blacklistedKeys and storage.keys.join('') in vim.blacklistedKeys
  54       match = false
  55
  56     if match
  57       if exact
  58         command.func(vim, event, count)
  59         storage.keys.length = 0
  60
  61       # Esc key is not suppressed, and passed to the browser in normal mode.
  62       #
  63       # - It allows for stopping the loading of the page.
  64       # - It allows for closing many custom dialogs (and perhaps other things
  65       #   -- Esc is a very commonly used key).
  66       # - It is not passed if Esc is used for `command_Esc` and we’re blurring
  67       #   an element. That allows for blurring an input in a custom dialog
  68       #   without closing the dialog too.
  69       # - There are two reasons we might suppress it in other modes. If some
  70       #   custom dialog of a website is open, we should be able to cancel hint
  71       #   markers on it without closing it. Secondly, otherwise cancelling hint
  72       #   markers on Google causes its search bar to be focused.
  73       # - It may only be suppressed in web pages, not in browser chrome. That
  74       #   allows for reseting the location bar when blurring it, and closing
  75       #   dialogs such as the “bookmark this page” dialog (<c-d>).
  76       document = event.originalTarget.ownerDocument
  77       inBrowserChrome = (document instanceof XULDocument)
  78       if keyStr == 'Esc' and (not autoInsertMode or inBrowserChrome)
  79         return false
  80
  81       return true
  82
  83     else
  84       storage.keys.length = 0 unless /\d/.test(keyStr)
  85
  86       return false
  87
  88 exports['insert'] =
  89   onEnter: (vim) ->
  90     updateToolbarButton(vim.rootWindow, {insertMode: true})
  91   onLeave: (vim) ->
  92     updateToolbarButton(vim.rootWindow, {insertMode: false})
  93     utils.blurActiveElement(vim.window)
  94   onInput: (vim, storage, keyStr) ->
  95     if isEscCommandKey(keyStr)
  96       vim.enterMode('normal')
  97       return true
  98
  99 exports['find'] =
 100   onEnter: ->
 101
 102   onLeave: (vim) ->
 103     findBar = vim.rootWindow.gBrowser.getFindBar()
 104     findStorage.lastSearchString = findBar._findField.value
 105
 106   onInput: (vim, storage, keyStr) ->
 107     findBar = vim.rootWindow.gBrowser.getFindBar()
 108     if isEscCommandKey(keyStr) or keyStr == 'Return'
 109       findBar.close()
 110       return true
 111     return false
 112
 113 exports['hints'] = mode_hints