extension/packages/commands.coffee

   1 utils = require 'utils'
   2 help  = require 'help'
   3 { _ } = require 'l10n'
   4 { getPref
   5 , setPref
   6 , isPrefSet
   7 , getFirefoxPref } = require 'prefs'
   8
   9 { classes: Cc, interfaces: Ci, utils: Cu } = Components
  10
  11 # Open developer toolbar (Default shotrcut: Shift-F2)
  12 command_dev = (vim) ->
  13   if chromeWindow = utils.getRootWindow vim.window
  14     chromeWindow.DeveloperToolbar.show(true)
  15     chromeWindow.DeveloperToolbar.focus()
  16
  17 # Focus the Address Bar
  18 command_focus = (vim) ->
  19   if chromeWindow = utils.getRootWindow(vim.window)
  20     chromeWindow.focusAndSelectUrlBar()
  21
  22 # Focus the Search Bar
  23 command_focus_search = (vim) ->
  24   if chromeWindow = utils.getRootWindow(vim.window)
  25     if searchBar = chromeWindow.document.getElementById("searchbar")
  26       searchBar.select()
  27
  28 # Navigate to the address that is currently stored in the system clipboard
  29 command_paste = (vim) ->
  30   url = utils.readFromClipboard(vim.window)
  31   postData = null
  32   if not utils.isURL(url) and submission = utils.browserSearchSubmission(url)
  33     url = submission.uri.spec
  34     { postData } = submission
  35
  36   if chromeWindow = utils.getRootWindow(vim.window)
  37     chromeWindow.gBrowser.loadURIWithFlags(url, null, null, null, postData)
  38
  39 # Open new tab and navigate to the address that is currently stored in the system clipboard
  40 command_paste_tab = (vim) ->
  41   url = utils.readFromClipboard(vim.window)
  42   postData = null
  43   if not utils.isURL(url) and submission = utils.browserSearchSubmission(url)
  44     url = submission.uri.spec
  45     { postData } = submission
  46
  47   if chromeWindow = utils.getRootWindow vim.window
  48     chromeWindow.gBrowser.selectedTab = chromeWindow.gBrowser.addTab(url, null, null, postData, null, false)
  49
  50 # Open new tab and focus the address bar
  51 command_open_tab = (vim) ->
  52   if chromeWindow = utils.getRootWindow(vim.window)
  53     chromeWindow.BrowserOpenTab()
  54
  55 # Copy element URL to the clipboard
  56 command_marker_yank = (vim) ->
  57   callback = (marker) ->
  58     if url = marker.element.href
  59       marker.element.focus()
  60       utils.writeToClipboard(vim.window, url)
  61     else if utils.isTextInputElement(marker.element)
  62       utils.writeToClipboard(vim.window, marker.element.value)
  63
  64   vim.enterMode('hints', [callback])
  65
  66 # Focus element
  67 command_marker_focus = (vim) ->
  68   callback = (marker) -> marker.element.focus()
  69
  70   vim.enterMode('hints', [callback])
  71
  72 # Copy current URL to the clipboard
  73 command_yank = (vim) ->
  74   utils.writeToClipboard(vim.window, vim.window.location.toString())
  75
  76 # Reload the page, possibly from cache
  77 command_reload = (vim) ->
  78   vim.window.location.reload(false)
  79
  80 # Reload the page from the server
  81 command_reload_force = (vim) ->
  82   vim.window.location.reload(true)
  83
  84 # Reload the page, possibly from cache
  85 command_reload_all = (vim) ->
  86   if rootWindow = utils.getRootWindow(vim.window)
  87     if tabs = rootWindow.gBrowser.tabContainer
  88       for i in [0...tabs.itemCount]
  89         window = tabs.getItemAtIndex(i).linkedBrowser.contentWindow
  90         window.location.reload(false)
  91
  92 # Reload the page from the server
  93 command_reload_all_force = (vim) ->
  94   if rootWindow = utils.getRootWindow(vim.window)
  95     if tabs = rootWindow.gBrowser.tabContainer
  96       for i in [0...tabs.itemCount]
  97         window = tabs.getItemAtIndex(i).linkedBrowser.contentWindow
  98         window.location.reload(true)
  99
 100 command_stop = (vim) ->
 101   vim.window.stop()
 102
 103 command_stop_all = (vim) ->
 104   if rootWindow = utils.getRootWindow(vim.window)
 105     if tabs = rootWindow.gBrowser.tabContainer
 106       for i in [0...tabs.itemCount]
 107         window = tabs.getItemAtIndex(i).linkedBrowser.contentWindow
 108         window.stop()
 109
 110 # Scroll to the top of the page
 111 command_scroll_to_top = (vim) ->
 112   for i in [0...1000]
 113     utils.simulateWheel(vim.window, 0, -1, utils.WHEEL_MODE_PAGE)
 114
 115 # Scroll to the bottom of the page
 116 command_scroll_to_bottom = (vim) ->
 117   for i in [0...1000]
 118     utils.simulateWheel(vim.window, 0, 1, utils.WHEEL_MODE_PAGE)
 119
 120 # Scroll down a bit
 121 command_scroll_down = (vim) ->
 122   utils.simulateWheel(vim.window, 0, getPref('scroll_step_lines'), utils.WHEEL_MODE_LINE)
 123
 124 # Scroll up a bit
 125 command_scroll_up = (vim) ->
 126   utils.simulateWheel(vim.window, 0, -getPref('scroll_step_lines'), utils.WHEEL_MODE_LINE)
 127
 128 # Scroll left a bit
 129 command_scroll_left = (vim) ->
 130   utils.simulateWheel(vim.window, -getPref('scroll_step_lines'), 0, utils.WHEEL_MODE_LINE)
 131
 132 # Scroll right a bit
 133 command_scroll_right = (vim) ->
 134   utils.simulateWheel(vim.window, getPref('scroll_step_lines'), 0, utils.WHEEL_MODE_LINE)
 135
 136 # Scroll down half a page
 137 command_scroll_half_page_down = (vim) ->
 138   utils.simulateWheel(vim.window, 0, 0.5, utils.WHEEL_MODE_PAGE)
 139
 140 # Scroll up half a page
 141 command_scroll_half_page_up = (vim) ->
 142   utils.simulateWheel(vim.window, 0, -0.5, utils.WHEEL_MODE_PAGE)
 143
 144 # Scroll down full a page
 145 command_scroll_page_down = (vim) ->
 146   utils.simulateWheel(vim.window, 0, 1, utils.WHEEL_MODE_PAGE)
 147
 148 # Scroll up full a page
 149 command_scroll_page_up = (vim) ->
 150   utils.simulateWheel(vim.window, 0, -1, utils.WHEEL_MODE_PAGE)
 151
 152 # Activate previous tab
 153 command_tab_prev = (vim) ->
 154   if rootWindow = utils.getRootWindow(vim.window)
 155     rootWindow.gBrowser.tabContainer.advanceSelectedTab(-1, true)
 156
 157 # Activate next tab
 158 command_tab_next = (vim) ->
 159   if rootWindow = utils.getRootWindow(vim.window)
 160     rootWindow.gBrowser.tabContainer.advanceSelectedTab(1, true)
 161
 162 command_home = (vim) ->
 163   url = getFirefoxPref('browser.startup.homepage')
 164   if chromeWindow = utils.getRootWindow(vim.window)
 165     chromeWindow.gBrowser.loadURIWithFlags(url, null, null, null, null)
 166
 167 # Go to the first tab
 168 command_tab_first = (vim) ->
 169   if rootWindow = utils.getRootWindow(vim.window)
 170     rootWindow.gBrowser.tabContainer.selectedIndex = 0
 171
 172 # Go to the last tab
 173 command_tab_last = (vim) ->
 174   if rootWindow = utils.getRootWindow(vim.window)
 175     itemCount = rootWindow.gBrowser.tabContainer.itemCount
 176     rootWindow.gBrowser.tabContainer.selectedIndex = itemCount - 1
 177
 178 # Go back in history
 179 command_back = (vim) ->
 180   vim.window.history.back()
 181
 182 # Go forward in history
 183 command_forward = (vim) ->
 184   vim.window.history.forward()
 185
 186 # Close current tab
 187 command_close_tab = (vim) ->
 188   if rootWindow = utils.getRootWindow(vim.window)
 189     unless rootWindow.gBrowser.selectedTab.pinned
 190       rootWindow.gBrowser.removeCurrentTab()
 191
 192 # Restore last closed tab
 193 command_restore_tab = (vim) ->
 194   if rootWindow = utils.getRootWindow(vim.window)
 195     ss = utils.getSessionStore()
 196     if ss and ss.getClosedTabCount(rootWindow) > 0
 197       ss.undoCloseTab(rootWindow, 0)
 198
 199 helper_follow = ({ inTab, multiple }, vim) ->
 200   callback = (matchedMarker, markers) ->
 201     matchedMarker.element.focus()
 202     utils.simulateClick(matchedMarker.element, {metaKey: inTab, ctrlKey: inTab})
 203     isEditable = utils.isElementEditable(matchedMarker.element)
 204     if multiple and not isEditable
 205       # By not resetting immediately one is able to see the last char being matched, which gives
 206       # some nice visual feedback that you've typed the right char.
 207       vim.window.setTimeout((-> marker.reset() for marker in markers), 100)
 208       return true
 209
 210   vim.enterMode('hints', [callback])
 211
 212 # Follow links with hint markers
 213 command_follow = helper_follow.bind(undefined, {inTab: false})
 214
 215 # Follow links in a new Tab with hint markers
 216 command_follow_in_tab = helper_follow.bind(undefined, {inTab: true})
 217
 218 # Follow multiple links with hint markers
 219 command_follow_multiple = helper_follow.bind(undefined, {inTab: true, multiple: true})
 220
 221 # Move current tab to the left
 222 command_tab_move_left = (vim) ->
 223   if gBrowser = utils.getRootWindow(vim.window)?.gBrowser
 224     if tab = gBrowser.selectedTab
 225       index = gBrowser.tabContainer.selectedIndex
 226       total = gBrowser.tabContainer.itemCount
 227
 228       # `total` is added to deal with negative offset
 229       gBrowser.moveTabTo(tab, (total + index - 1) % total)
 230
 231 # Move current tab to the right
 232 command_tab_move_right = (vim) ->
 233   if gBrowser = utils.getRootWindow(vim.window)?.gBrowser
 234     if tab = gBrowser.selectedTab
 235       index = gBrowser.tabContainer.selectedIndex
 236       total = gBrowser.tabContainer.itemCount
 237
 238       gBrowser.moveTabTo(tab, (index + 1) % total)
 239
 240 # Display the Help Dialog
 241 command_help = (vim) ->
 242   help.injectHelp(vim.window.document, commands)
 243
 244 # Switch into find mode
 245 command_find = (vim, storage) ->
 246   vim.enterMode('find', { highlight: false })
 247
 248 # Switch into find mode with highlighting
 249 command_find_hl = (vim, storage) ->
 250   vim.enterMode('find', { highlight: true })
 251
 252 # Search for the last pattern
 253 command_find_next = (vim, storage) ->
 254   if findBar = utils.getRootWindow(vim.window).gBrowser.getFindBar()
 255     if findBar._findField.value.length > 0
 256       findBar.onFindAgainCommand(false)
 257
 258 # Search for the last pattern backwards
 259 command_find_prev = (vim, storage) ->
 260   if findBar = utils.getRootWindow(vim.window).gBrowser.getFindBar()
 261     if findBar._findField.value.length > 0
 262       findBar.onFindAgainCommand(true)
 263
 264 command_insert_mode = (vim) ->
 265   vim.enterMode('insert')
 266
 267 command_Esc = (vim, storage, event) ->
 268   utils.blurActiveElement(vim.window)
 269
 270   # Blur active XUL control
 271   callback = -> event.originalTarget?.ownerDocument?.activeElement?.blur()
 272   vim.window.setTimeout(callback, 0)
 273
 274   help.removeHelp(vim.window.document)
 275
 276   if rootWindow = utils.getRootWindow(vim.window)
 277     rootWindow.DeveloperToolbar.hide()
 278
 279   if findBar = utils.getRootWindow(vim.window).gBrowser.getFindBar()
 280     findBar.close()
 281
 282
 283 class Command
 284   constructor: (@group, @name, @func, keys) ->
 285     @defaultKeys = keys
 286     if isPrefSet(@prefName('keys'))
 287       try @keyValues = JSON.parse(getPref(@prefName('keys')))
 288     else
 289       @keyValues = keys
 290
 291   # Name of the preference for a given property
 292   prefName: (value) -> "commands.#{ @name }.#{ value }"
 293
 294   keys: (value) ->
 295     if value is undefined
 296       return @keyValues
 297     else
 298       @keyValues = value or @defaultKeyValues
 299       setPref(@prefName('keys'), value and JSON.stringify(value))
 300
 301   help: -> _("help_command_#{ @name }")
 302
 303 commands = [
 304   new Command('urls',   'focus',                  command_focus,                  ['o'])
 305   new Command('urls',   'focus_search',           command_focus_search,           ['O'])
 306   new Command('urls',   'paste',                  command_paste,                  ['p'])
 307   new Command('urls',   'paste_tab',              command_paste_tab,              ['P'])
 308   new Command('urls',   'marker_yank',            command_marker_yank,            ['y,f'])
 309   new Command('urls',   'marker_focus',           command_marker_focus,           ['v,f'])
 310   new Command('urls',   'yank',                   command_yank,                   ['y,y'])
 311   new Command('urls',   'reload',                 command_reload,                 ['r'])
 312   new Command('urls',   'reload_force',           command_reload_force,           ['R'])
 313   new Command('urls',   'reload_all',             command_reload_all,             ['a,r'])
 314   new Command('urls',   'reload_all_force',       command_reload_all_force,       ['a,R'])
 315   new Command('urls',   'stop',                   command_stop,                   ['s'])
 316   new Command('urls',   'stop_all',               command_stop_all,               ['a,s'])
 317
 318   new Command('nav',    'scroll_to_top',          command_scroll_to_top ,         ['g,g'])
 319   new Command('nav',    'scroll_to_bottom',       command_scroll_to_bottom,       ['G'])
 320   new Command('nav',    'scroll_down',            command_scroll_down,            ['j', 'c-e'])
 321   new Command('nav',    'scroll_up',              command_scroll_up,              ['k', 'c-y'])
 322   new Command('nav',    'scroll_left',            command_scroll_left,            ['h'])
 323   new Command('nav',    'scroll_right',           command_scroll_right ,          ['l'])
 324   new Command('nav',    'scroll_half_page_down',  command_scroll_half_page_down,  ['d'])
 325   new Command('nav',    'scroll_half_page_up',    command_scroll_half_page_up,    ['u'])
 326   new Command('nav',    'scroll_page_down',       command_scroll_page_down,       ['c-f'])
 327   new Command('nav',    'scroll_page_up',         command_scroll_page_up,         ['c-b'])
 328
 329   new Command('tabs',   'open_tab',               command_open_tab,               ['t'])
 330   new Command('tabs',   'tab_prev',               command_tab_prev,               ['J', 'g,T'])
 331   new Command('tabs',   'tab_next',               command_tab_next,               ['K', 'g,t'])
 332   new Command('tabs',   'tab_move_left',          command_tab_move_left,          ['c-J'])
 333   new Command('tabs',   'tab_move_right',         command_tab_move_right,         ['c-K'])
 334   new Command('tabs',   'home',                   command_home,                   ['g,h'])
 335   new Command('tabs',   'tab_first',              command_tab_first,              ['g,H', 'g,^'])
 336   new Command('tabs',   'tab_last',               command_tab_last,               ['g,L', 'g,$'])
 337   new Command('tabs',   'close_tab',              command_close_tab,              ['x'])
 338   new Command('tabs',   'restore_tab',            command_restore_tab,            ['X'])
 339
 340   new Command('browse', 'follow',                 command_follow,                 ['f'])
 341   new Command('browse', 'follow_in_tab',          command_follow_in_tab,          ['F'])
 342   new Command('browse', 'follow_multiple',        command_follow_multiple,        ['a,f'])
 343   new Command('browse', 'back',                   command_back,                   ['H'])
 344   new Command('browse', 'forward',                command_forward,                ['L'])
 345
 346   new Command('misc',   'find',                   command_find,                   ['/'])
 347   new Command('misc',   'find_hl',                command_find_hl,                ['a,/'])
 348   new Command('misc',   'find_next',              command_find_next,              ['n'])
 349   new Command('misc',   'find_prev',              command_find_prev,              ['N'])
 350   new Command('misc',   'insert_mode',            command_insert_mode,            ['i'])
 351   new Command('misc',   'help',                   command_help,                   ['?'])
 352   new Command('misc',   'dev',                    command_dev,                    [':'])
 353
 354   escapeCommand =
 355   new Command('misc',   'Esc',                    command_Esc,                    ['Esc'])
 356 ]
 357
 358 searchForMatchingCommand = (keys) ->
 359   for index in [0...keys.length] by 1
 360     str = keys[index..].join(',')
 361     for command in commands
 362       for key in command.keys()
 363         if key.startsWith(str)
 364           return {match: true, exact: (key == str), command}
 365
 366   return {match: false}
 367
 368 isEscCommandKey = (keyStr) -> keyStr in escapeCommand.keys()
 369
 370 isReturnCommandKey = (keyStr) -> keyStr.contains('Return')
 371
 372 exports.commands                  = commands
 373 exports.searchForMatchingCommand  = searchForMatchingCommand
 374 exports.isEscCommandKey           = isEscCommandKey
 375 exports.isReturnCommandKey        = isReturnCommandKey