extension/lib/commands.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 # Copyright Wang Zhuochun 2013, 2014.
   5 #
   6 # This file is part of VimFx.
   7 #
   8 # VimFx is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # VimFx is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  20 ###
  21
  22 # This file defines all Normal mode commands. Commands that need to interact
  23 # with web page content do so by running `vim._run(name)`, which invokes `name`
  24 # in commands-frame.coffee.
  25
  26 # NOTE: Most tab related commands need to do their actual tab manipulations in
  27 # the next tick (`utils.nextTick`) to work around bug 1200334.
  28
  29 config = require('./config')
  30 help = require('./help')
  31 hints = require('./hints')
  32 prefs = require('./prefs')
  33 translate = require('./l10n')
  34 utils = require('./utils')
  35
  36 commands = {}
  37
  38
  39
  40 commands.focus_location_bar = ({vim}) ->
  41   vim.window.focusAndSelectUrlBar()
  42
  43 commands.focus_search_bar = ({vim, count}) ->
  44   # The `.webSearch()` method opens a search engine in a tab if the search bar
  45   # has been removed. Therefore we first check if it exists.
  46   if vim.window.BrowserSearch.searchBar
  47     vim.window.BrowserSearch.webSearch()
  48
  49 helper_paste_and_go = (props, {vim}) ->
  50   {gURLBar} = vim.window
  51   gURLBar.value = vim.window.readFromClipboard()
  52   gURLBar.handleCommand(new vim.window.KeyboardEvent('keydown', props))
  53
  54 commands.paste_and_go = helper_paste_and_go.bind(null, null)
  55
  56 commands.paste_and_go_in_tab = helper_paste_and_go.bind(null, {altKey: true})
  57
  58 commands.copy_current_url = ({vim}) ->
  59   utils.writeToClipboard(vim.window.gBrowser.currentURI.spec)
  60   vim.notify(translate('notification.copy_current_url'))
  61
  62 commands.go_up_path = ({vim, count}) ->
  63   vim._run('go_up_path', {count})
  64
  65 commands.go_to_root = ({vim}) ->
  66   vim._run('go_to_root')
  67
  68 commands.go_home = ({vim}) ->
  69   vim.window.BrowserHome()
  70
  71 helper_go_history = (direction, {vim, count = 1}) ->
  72   {window} = vim
  73   {SessionStore, gBrowser} = window
  74
  75   if (direction == 'back'    and not gBrowser.canGoBack) or
  76      (direction == 'forward' and not gBrowser.canGoForward)
  77     vim.notify(translate("notification.history_#{direction}.limit"))
  78     return
  79
  80   # `SessionStore.getSessionHistory()` (used below to support counts) starts
  81   # lots of asynchronous tasks internally, which is a bit unreliable, it has
  82   # turned out. The primary use of the `history_back` and `history_forward`
  83   # commands is to go _one_ step back or forward, though, so those cases are
  84   # optimized to use more reliable ways of going back and forward. Also, some
  85   # extensions override the following functions, so calling them also gives
  86   # better interoperability.
  87   if count == 1
  88     if direction == 'back'
  89       window.BrowserBack()
  90     else
  91       window.BrowserForward()
  92     return
  93
  94   SessionStore.getSessionHistory(gBrowser.selectedTab, (sessionHistory) ->
  95     {index} = sessionHistory
  96     newIndex = index + count * (if direction == 'back' then -1 else 1)
  97     newIndex = Math.max(newIndex, 0)
  98     newIndex = Math.min(newIndex, sessionHistory.entries.length - 1)
  99     gBrowser.gotoIndex(newIndex)
 100   )
 101
 102 commands.history_back    = helper_go_history.bind(null, 'back')
 103
 104 commands.history_forward = helper_go_history.bind(null, 'forward')
 105
 106 commands.history_list = ({vim}) ->
 107   menu = vim.window.document.getElementById('backForwardMenu')
 108   utils.openPopup(menu)
 109   if menu.childElementCount == 0
 110     vim.notify(translate('notification.history_list.none'))
 111
 112 commands.reload = ({vim}) ->
 113   vim.window.BrowserReload()
 114
 115 commands.reload_force = ({vim}) ->
 116   vim.window.BrowserReloadSkipCache()
 117
 118 commands.reload_all = ({vim}) ->
 119   vim.window.gBrowser.reloadAllTabs()
 120
 121 commands.reload_all_force = ({vim}) ->
 122   for tab in vim.window.gBrowser.visibleTabs
 123     gBrowser = tab.linkedBrowser
 124     consts = gBrowser.webNavigation
 125     flags = consts.LOAD_FLAGS_BYPASS_PROXY | consts.LOAD_FLAGS_BYPASS_CACHE
 126     gBrowser.reload(flags)
 127   return
 128
 129 commands.stop = ({vim}) ->
 130   vim.window.BrowserStop()
 131
 132 commands.stop_all = ({vim}) ->
 133   for tab in vim.window.gBrowser.visibleTabs
 134     tab.linkedBrowser.stop()
 135   return
 136
 137
 138
 139 helper_scroll = (vim, uiEvent, args...) ->
 140   [
 141     method, type, directions, amounts
 142     properties = null, adjustment = 0, name = 'scroll'
 143   ] = args
 144   options = {
 145     method, type, directions, amounts, properties, adjustment
 146     smooth: (prefs.root.get('general.smoothScroll') and
 147              prefs.root.get("general.smoothScroll.#{type}"))
 148   }
 149   reset = prefs.root.tmp(
 150     'layout.css.scroll-behavior.spring-constant',
 151     vim.options["smoothScroll.#{type}.spring-constant"]
 152   )
 153
 154   helpScroll = help.getHelp(vim.window)?.querySelector('.wrapper')
 155   if uiEvent or helpScroll
 156     activeElement = helpScroll or utils.getActiveElement(vim.window)
 157     if vim._state.scrollableElements.has(activeElement) or helpScroll
 158       utils.scroll(activeElement, options)
 159       reset()
 160       return
 161
 162   vim._run(name, options, reset)
 163
 164
 165 helper_scrollByLinesX = (amount, {vim, uiEvent, count = 1}) ->
 166   distance = prefs.root.get('toolkit.scrollbox.horizontalScrollDistance')
 167   helper_scroll(vim, uiEvent, 'scrollBy', 'lines', ['left'],
 168                 [amount * distance * count * 5])
 169
 170 helper_scrollByLinesY = (amount, {vim, uiEvent, count = 1}) ->
 171   distance = prefs.root.get('toolkit.scrollbox.verticalScrollDistance')
 172   helper_scroll(vim, uiEvent, 'scrollBy', 'lines', ['top'],
 173                 [amount * distance * count * 20])
 174
 175 helper_scrollByPagesY = (amount, type, {vim, uiEvent, count = 1}) ->
 176   adjustment = vim.options["scroll.#{type}_page_adjustment"]
 177   helper_scroll(vim, uiEvent, 'scrollBy', 'pages', ['top'],
 178                 [amount * count], ['clientHeight'], adjustment)
 179
 180 helper_scrollToX = (amount, {vim, uiEvent}) ->
 181   helper_scroll(vim, uiEvent, 'scrollTo', 'other', ['left'],
 182                 [amount], ['scrollLeftMax'])
 183   helper_mark_last_scroll_position(vim)
 184
 185 helper_scrollToY = (amount, {vim, uiEvent}) ->
 186   helper_scroll(vim, uiEvent, 'scrollTo', 'other', ['top'],
 187                 [amount], ['scrollTopMax'])
 188   helper_mark_last_scroll_position(vim)
 189
 190 commands.scroll_left           = helper_scrollByLinesX.bind(null, -1)
 191 commands.scroll_right          = helper_scrollByLinesX.bind(null, +1)
 192 commands.scroll_down           = helper_scrollByLinesY.bind(null, +1)
 193 commands.scroll_up             = helper_scrollByLinesY.bind(null, -1)
 194 commands.scroll_page_down      = helper_scrollByPagesY.bind(null, +1,   'full')
 195 commands.scroll_page_up        = helper_scrollByPagesY.bind(null, -1,   'full')
 196 commands.scroll_half_page_down = helper_scrollByPagesY.bind(null, +0.5, 'half')
 197 commands.scroll_half_page_up   = helper_scrollByPagesY.bind(null, -0.5, 'half')
 198 commands.scroll_to_top         = helper_scrollToY.bind(null, 0)
 199 commands.scroll_to_bottom      = helper_scrollToY.bind(null, Infinity)
 200 commands.scroll_to_left        = helper_scrollToX.bind(null, 0)
 201 commands.scroll_to_right       = helper_scrollToX.bind(null, Infinity)
 202
 203 helper_mark_last_scroll_position = (vim) ->
 204   keyStr = vim.options['scroll.last_position_mark']
 205   vim._run('mark_scroll_position', {keyStr, notify: false})
 206
 207 commands.mark_scroll_position = ({vim}) ->
 208   vim.enterMode('marks', (keyStr) -> vim._run('mark_scroll_position', {keyStr}))
 209
 210 commands.scroll_to_mark = ({vim}) ->
 211   vim.enterMode('marks', (keyStr) ->
 212     unless keyStr == vim.options['scroll.last_position_mark']
 213       helper_mark_last_scroll_position(vim)
 214     helper_scroll(vim, null, 'scrollTo', 'other', ['top', 'left'], keyStr,
 215                   ['scrollTopMax', 'scrollLeftMax'], 0, 'scroll_to_mark')
 216   )
 217
 218
 219
 220 commands.tab_new = ({vim}) ->
 221   utils.nextTick(vim.window, ->
 222     vim.window.BrowserOpenTab()
 223   )
 224
 225 commands.tab_duplicate = ({vim}) ->
 226   {gBrowser} = vim.window
 227   utils.nextTick(vim.window, ->
 228     gBrowser.duplicateTab(gBrowser.selectedTab)
 229   )
 230
 231 absoluteTabIndex = (relativeIndex, gBrowser, {pinnedSeparate}) ->
 232   tabs = gBrowser.visibleTabs
 233   {selectedTab} = gBrowser
 234
 235   currentIndex = tabs.indexOf(selectedTab)
 236   absoluteIndex = currentIndex + relativeIndex
 237   numTabsTotal = tabs.length
 238   numPinnedTabs = gBrowser._numPinnedTabs
 239
 240   [numTabs, min] = switch
 241     when not pinnedSeparate
 242       [numTabsTotal,  0]
 243     when selectedTab.pinned
 244       [numPinnedTabs, 0]
 245     else
 246       [numTabsTotal - numPinnedTabs, numPinnedTabs]
 247
 248   # Wrap _once_ if at one of the ends of the tab bar and cannot move in the
 249   # current direction.
 250   if (relativeIndex < 0 and currentIndex == min) or
 251      (relativeIndex > 0 and currentIndex == min + numTabs - 1)
 252     if absoluteIndex < min
 253       absoluteIndex += numTabs
 254     else if absoluteIndex >= min + numTabs
 255       absoluteIndex -= numTabs
 256
 257   absoluteIndex = Math.max(min, absoluteIndex)
 258   absoluteIndex = Math.min(absoluteIndex, min + numTabs - 1)
 259
 260   return absoluteIndex
 261
 262 helper_switch_tab = (direction, {vim, count = 1}) ->
 263   {gBrowser} = vim.window
 264   index = absoluteTabIndex(direction * count, gBrowser, {pinnedSeparate: false})
 265   utils.nextTick(vim.window, ->
 266     gBrowser.selectTabAtIndex(index)
 267   )
 268
 269 commands.tab_select_previous = helper_switch_tab.bind(null, -1)
 270
 271 commands.tab_select_next     = helper_switch_tab.bind(null, +1)
 272
 273 helper_is_visited = (tab) ->
 274   return tab.getAttribute('VimFx-visited') or not tab.getAttribute('unread')
 275
 276 commands.tab_select_most_recent = ({vim, count = 1}) ->
 277   {gBrowser} = vim.window
 278   tabsSorted =
 279     Array.filter(
 280       gBrowser.tabs,
 281       (tab) -> not tab.closing and helper_is_visited(tab)
 282     ).sort((a, b) -> b.lastAccessed - a.lastAccessed)[1..] # Remove current tab.
 283   tab = tabsSorted[Math.min(count - 1, tabsSorted.length - 1)]
 284   if tab
 285     gBrowser.selectedTab = tab
 286   else
 287     vim.notify(translate('notification.tab_select_most_recent.none'))
 288
 289 commands.tab_select_oldest_unvisited = ({vim, count = 1}) ->
 290   {gBrowser} = vim.window
 291   tabsSorted =
 292     Array.filter(
 293       gBrowser.tabs,
 294       (tab) -> not tab.closing and not helper_is_visited(tab)
 295     ).sort((a, b) -> a.lastAccessed - b.lastAccessed)
 296   tab = tabsSorted[Math.min(count - 1, tabsSorted.length - 1)]
 297   if tab
 298     gBrowser.selectedTab = tab
 299   else
 300     vim.notify(translate('notification.tab_select_oldest_unvisited.none'))
 301
 302 helper_move_tab = (direction, {vim, count = 1}) ->
 303   {gBrowser} = vim.window
 304   index = absoluteTabIndex(direction * count, gBrowser, {pinnedSeparate: true})
 305   utils.nextTick(vim.window, ->
 306     gBrowser.moveTabTo(gBrowser.selectedTab, index)
 307   )
 308
 309 commands.tab_move_backward = helper_move_tab.bind(null, -1)
 310
 311 commands.tab_move_forward  = helper_move_tab.bind(null, +1)
 312
 313 commands.tab_move_to_window = ({vim}) ->
 314   {gBrowser} = vim.window
 315   gBrowser.replaceTabWithWindow(gBrowser.selectedTab)
 316
 317 commands.tab_select_first = ({vim, count = 1}) ->
 318   utils.nextTick(vim.window, ->
 319     vim.window.gBrowser.selectTabAtIndex(count - 1)
 320   )
 321
 322 commands.tab_select_first_non_pinned = ({vim, count = 1}) ->
 323   firstNonPinned = vim.window.gBrowser._numPinnedTabs
 324   utils.nextTick(vim.window, ->
 325     vim.window.gBrowser.selectTabAtIndex(firstNonPinned + count - 1)
 326   )
 327
 328 commands.tab_select_last = ({vim, count = 1}) ->
 329   utils.nextTick(vim.window, ->
 330     vim.window.gBrowser.selectTabAtIndex(-count)
 331   )
 332
 333 commands.tab_toggle_pinned = ({vim}) ->
 334   currentTab = vim.window.gBrowser.selectedTab
 335   if currentTab.pinned
 336     vim.window.gBrowser.unpinTab(currentTab)
 337   else
 338     vim.window.gBrowser.pinTab(currentTab)
 339
 340 commands.tab_close = ({vim, count = 1}) ->
 341   {gBrowser} = vim.window
 342   return if gBrowser.selectedTab.pinned
 343   currentIndex = gBrowser.visibleTabs.indexOf(gBrowser.selectedTab)
 344   utils.nextTick(vim.window, ->
 345     for tab in gBrowser.visibleTabs[currentIndex...(currentIndex + count)]
 346       gBrowser.removeTab(tab)
 347     return
 348   )
 349
 350 commands.tab_restore = ({vim, count = 1}) ->
 351   utils.nextTick(vim.window, ->
 352     for index in [0...count] by 1
 353       restoredTab = vim.window.undoCloseTab()
 354       if not restoredTab and index == 0
 355         vim.notify(translate('notification.tab_restore.none'))
 356         break
 357     return
 358   )
 359
 360 commands.tab_restore_list = ({vim}) ->
 361   {window} = vim
 362   fragment = window.RecentlyClosedTabsAndWindowsMenuUtils.getTabsFragment(
 363     window, 'menuitem'
 364   )
 365   if fragment.childElementCount == 0
 366     vim.notify(translate('notification.tab_restore.none'))
 367   else
 368     utils.openPopup(utils.injectTemporaryPopup(window.document, fragment))
 369
 370 commands.tab_close_to_end = ({vim}) ->
 371   {gBrowser} = vim.window
 372   gBrowser.removeTabsToTheEndFrom(gBrowser.selectedTab)
 373
 374 commands.tab_close_other = ({vim}) ->
 375   {gBrowser} = vim.window
 376   gBrowser.removeAllTabsBut(gBrowser.selectedTab)
 377
 378
 379
 380 helper_follow = (name, vim, callback, count = null) ->
 381   vim.markPageInteraction()
 382   help.removeHelp(vim.window)
 383
 384   # Enter hints mode immediately, with an empty set of markers. The user might
 385   # press keys before the `vim._run` callback is invoked. Those key presses
 386   # should be handled in hints mode, not normal mode.
 387   initialMarkers = []
 388   storage = vim.enterMode('hints', initialMarkers, callback, count,
 389                           vim.options.hints_sleep)
 390
 391   vim._run(name, null, ({wrappers, viewport}) ->
 392     # The user might have exited hints mode (and perhaps even entered it again)
 393     # before this callback is invoked. If so, `storage.markers` has been
 394     # cleared, or set to a new value. Only proceed if it is unchanged.
 395     return unless storage.markers == initialMarkers
 396
 397     if wrappers.length > 0
 398       {markers, markerMap} = hints.injectHints(vim.window, wrappers, viewport,
 399                                                vim.options)
 400       storage.markers = markers
 401       storage.markerMap = markerMap
 402     else
 403       vim.notify(translate('notification.follow.none'))
 404       vim.enterMode('normal')
 405   )
 406
 407 helper_follow_clickable = ({inTab, inBackground}, {vim, count = 1}) ->
 408   callback = (marker, timesLeft, keyStr) ->
 409     {type, elementIndex} = marker.wrapper
 410     isLast = (timesLeft == 1)
 411     isLink = (type == 'link')
 412
 413     switch
 414       when keyStr.startsWith(vim.options.hints_toggle_in_tab)
 415         inTab = not inTab
 416       when keyStr.startsWith(vim.options.hints_toggle_in_background)
 417         inTab = true
 418         inBackground = not inBackground
 419       else
 420         unless isLast
 421           inTab = true
 422           inBackground = true
 423
 424     inTab = false unless isLink
 425
 426     if type == 'text' or (isLink and not (inTab and inBackground))
 427       isLast = true
 428
 429     vim._focusMarkerElement(elementIndex)
 430
 431     if inTab
 432       utils.nextTick(vim.window, ->
 433         utils.openTab(vim.window, marker.wrapper.href, {
 434           inBackground
 435           relatedToCurrent: true
 436         })
 437       )
 438     else
 439       vim._run('click_marker_element', {
 440         elementIndex, type
 441         preventTargetBlank: vim.options.prevent_target_blank
 442       })
 443
 444     return not isLast
 445
 446   name = if inTab then 'follow_in_tab' else 'follow'
 447   helper_follow(name, vim, callback, count)
 448
 449 commands.follow =
 450   helper_follow_clickable.bind(null, {inTab: false, inBackground: true})
 451
 452 commands.follow_in_tab =
 453   helper_follow_clickable.bind(null, {inTab: true, inBackground: true})
 454
 455 commands.follow_in_focused_tab =
 456   helper_follow_clickable.bind(null, {inTab: true, inBackground: false})
 457
 458 commands.follow_in_window = ({vim}) ->
 459   callback = (marker) ->
 460     vim._focusMarkerElement(marker.wrapper.elementIndex)
 461     vim.window.openLinkIn(marker.wrapper.href, 'window', {})
 462   helper_follow('follow_in_tab', vim, callback)
 463
 464 commands.follow_multiple = (args) ->
 465   args.count = Infinity
 466   commands.follow(args)
 467
 468 commands.follow_copy = ({vim}) ->
 469   callback = (marker) ->
 470     {elementIndex} = marker.wrapper
 471     property = switch marker.wrapper.type
 472       when 'link'
 473         'href'
 474       when 'text'
 475         'value'
 476       when 'contenteditable'
 477         'textContent'
 478     vim._run('copy_marker_element', {elementIndex, property})
 479   helper_follow('follow_copy', vim, callback)
 480
 481 commands.follow_focus = ({vim}) ->
 482   callback = (marker) ->
 483     vim._focusMarkerElement(marker.wrapper.elementIndex, {select: true})
 484   return helper_follow('follow_focus', vim, callback)
 485
 486 commands.click_browser_element = ({vim}) ->
 487   markerElements = []
 488
 489   filter = (element, getElementShape) ->
 490     document = element.ownerDocument
 491     type = switch
 492       when vim._state.scrollableElements.has(element)
 493         'scrollable'
 494       when (element.tabIndex > -1 and
 495             not (element.localName?.endsWith('box') and
 496                  element.localName != 'checkbox') and
 497             element.localName not in ['tabs', 'menuitem', 'menuseparator']) or
 498            element.onclick
 499         'clickable'
 500     return unless type
 501     return unless shape = getElementShape(element)
 502     length = markerElements.push(element)
 503     return {type, semantic: true, shape, elementIndex: length - 1}
 504
 505   callback = (marker) ->
 506     element = markerElements[marker.wrapper.elementIndex]
 507     switch marker.wrapper.type
 508       when 'scrollable'
 509         utils.focusElement(element, {flag: 'FLAG_BYKEY'})
 510       when 'clickable'
 511         utils.focusElement(element)
 512         utils.simulateMouseEvents(element, 'click')
 513
 514   {wrappers, viewport} =
 515     hints.getMarkableElementsAndViewport(vim.window, filter)
 516
 517   if wrappers.length > 0
 518     {markers} = hints.injectHints(vim.window, wrappers, viewport, {
 519       hint_chars: vim.options.hint_chars
 520       ui: true
 521     })
 522     vim.enterMode('hints', markers, callback)
 523   else
 524     vim.notify(translate('notification.follow.none'))
 525
 526 helper_follow_pattern = (type, {vim}) ->
 527   options = {
 528     pattern_selector: vim.options.pattern_selector
 529     pattern_attrs: vim.options.pattern_attrs
 530     patterns: vim.options["#{type}_patterns"]
 531   }
 532   vim._run('follow_pattern', {type, options})
 533
 534 commands.follow_previous = helper_follow_pattern.bind(null, 'prev')
 535
 536 commands.follow_next     = helper_follow_pattern.bind(null, 'next')
 537
 538 commands.focus_text_input = ({vim, count}) ->
 539   vim.markPageInteraction()
 540   vim._run('focus_text_input', {count})
 541
 542
 543
 544 findStorage = {lastSearchString: ''}
 545
 546 helper_find = ({highlight, linksOnly = false}, {vim}) ->
 547   helpSearchInput = help.getSearchInput(vim.window)
 548   if helpSearchInput
 549     helpSearchInput.select()
 550     return
 551
 552   helper_mark_last_scroll_position(vim)
 553   findBar = vim.window.gBrowser.getFindBar()
 554
 555   mode = if linksOnly then findBar.FIND_LINKS else findBar.FIND_NORMAL
 556   findBar.startFind(mode)
 557   utils.focusElement(findBar._findField, {select: true})
 558
 559   return if linksOnly
 560   return unless highlightButton = findBar.getElement('highlight')
 561   if highlightButton.checked != highlight
 562     highlightButton.click()
 563
 564 commands.find = helper_find.bind(null, {highlight: false})
 565
 566 commands.find_highlight_all = helper_find.bind(null, {highlight: true})
 567
 568 commands.find_links_only = helper_find.bind(null, {linksOnly: true})
 569
 570 helper_find_again = (direction, {vim}) ->
 571   findBar = vim.window.gBrowser.getFindBar()
 572   if findStorage.lastSearchString.length == 0
 573     vim.notify(translate('notification.find_again.none'))
 574     return
 575   helper_mark_last_scroll_position(vim)
 576   findBar._findField.value = findStorage.lastSearchString
 577   findBar.onFindAgainCommand(direction)
 578   message = findBar._findStatusDesc.textContent
 579   vim.notify(message) if message
 580
 581 commands.find_next     = helper_find_again.bind(null, false)
 582
 583 commands.find_previous = helper_find_again.bind(null, true)
 584
 585
 586
 587 commands.window_new = ({vim}) ->
 588   vim.window.OpenBrowserWindow()
 589
 590 commands.window_new_private = ({vim}) ->
 591   vim.window.OpenBrowserWindow({private: true})
 592
 593 commands.enter_mode_ignore = ({vim}) ->
 594   vim.enterMode('ignore', {type: 'explicit'})
 595
 596 # Quote next keypress (pass it through to the page).
 597 commands.quote = ({vim, count = 1}) ->
 598   vim.enterMode('ignore', {type: 'explicit', count})
 599
 600 commands.enter_reader_view = ({vim}) ->
 601   button = vim.window.document.getElementById('reader-mode-button')
 602   if not button?.hidden
 603     button.click()
 604   else
 605     vim.notify(translate('notification.enter_reader_view.none'))
 606
 607 commands.reload_config_file = ({vim}) ->
 608   vim._parent.emit('shutdown')
 609   config.load(vim._parent, (status) -> switch status
 610     when null
 611       vim.notify(translate('notification.reload_config_file.none'))
 612     when true
 613       vim.notify(translate('notification.reload_config_file.success'))
 614     else
 615       vim.notify(translate('notification.reload_config_file.failure'))
 616   )
 617
 618 commands.help = ({vim}) ->
 619   help.injectHelp(vim.window, vim._parent)
 620
 621 commands.dev = ({vim}) ->
 622   vim.window.DeveloperToolbar.show(true) # `true` to focus.
 623
 624 commands.esc = ({vim}) ->
 625   vim._run('esc')
 626   utils.blurActiveBrowserElement(vim)
 627   vim.window.DeveloperToolbar.hide()
 628   vim.window.gBrowser.getFindBar().close()
 629   # TODO: Remove when Tab Groups have been removed.
 630   vim.window.TabView?.hide()
 631   hints.removeHints(vim.window) # Better safe than sorry.
 632
 633   unless help.getSearchInput(vim.window)?.getAttribute('focused')
 634     help.removeHelp(vim.window)
 635
 636
 637
 638 module.exports = {
 639   commands
 640   findStorage
 641 }