extension/lib/events-frame.coffee

   1 ###
   2 # Copyright Simon Lydell 2015.
   3 #
   4 # This file is part of VimFx.
   5 #
   6 # VimFx is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # VimFx is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  18 ###
  19
  20 # This file is the equivalent to events.coffee, but for frame scripts.
  21
  22 messageManager = require('./message-manager')
  23 utils          = require('./utils')
  24
  25 class FrameEventManager
  26   constructor: (@vim) ->
  27     @numFocusToSuppress = 0
  28
  29   listen: utils.listen.bind(null, FRAME_SCRIPT_ENVIRONMENT)
  30   listenOnce: utils.listenOnce.bind(null, FRAME_SCRIPT_ENVIRONMENT)
  31
  32   addListeners: ->
  33     messageManager.listen('locationChange', @vim.resetState.bind(@vim))
  34
  35     # If the page already was fully loaded when VimFx was initialized, send the
  36     # 'DOMWindowCreated' message straight away.
  37     if @vim.content.document.readyState == 'complete'
  38       messageManager.send('DOMWindowCreated')
  39     else
  40       @listen('DOMWindowCreated', (event) ->
  41         messageManager.send('DOMWindowCreated')
  42       )
  43
  44     @listen('click', (event) =>
  45       if @vim.mode == 'hints' and event.isTrusted
  46         messageManager.send('enterMode', {mode: 'normal'})
  47     )
  48
  49     @listen('overflow', (event) =>
  50       return unless computedStyle = @vim.content.getComputedStyle(event.target)
  51       return if computedStyle.getPropertyValue('overflow') == 'hidden'
  52       @vim.state.scrollableElements.add(event.target)
  53     )
  54
  55     @listen('underflow', (event) =>
  56       @vim.state.scrollableElements.delete(event.target)
  57     )
  58
  59     @listen('keydown', (event) =>
  60       suppress = @vim.onInput(event)
  61
  62       # This also suppresses the 'keypress' and 'keyup' events. (Yes, in frame
  63       # scripts, suppressing the 'keydown' events does seem to even suppress
  64       # the 'keyup' event!)
  65       utils.suppressEvent(event) if suppress
  66
  67       # From this line on, the rest of the code in `addListeners` is more or
  68       # less devoted to autofocus prevention. When enabled, focus events that
  69       # occur before the user has interacted with page are prevented.
  70       #
  71       # If this keydown event wasn’t suppressed (`not suppress`), it’s an
  72       # obvious interaction with the page. If it _was_ suppressed, though, it’s
  73       # an interaction depending on the command triggered; if it calls
  74       # `vim.markPageInteraction()` or not.
  75       @vim.markPageInteraction() unless suppress
  76     )
  77
  78     @listen('keydown', ((event) ->
  79       suppress = messageManager.get('lateKeydown', {
  80         defaultPrevented: event.defaultPrevented
  81       })
  82       utils.suppressEvent(event) if suppress
  83     ), false)
  84
  85     # Clicks are always counted as page interaction. Listen for 'mousedown'
  86     # instead of 'click' to mark the interaction as soon as possible.
  87     @listen('mousedown', (event) => @vim.markPageInteraction())
  88
  89     messageManager.listen('browserRefocus', =>
  90       # Suppress the next two focus events (for `document` and `window`; see
  91       # `blurActiveBrowserElement`).
  92       @numFocusToSuppress = 2
  93     )
  94
  95     @listen('focus', (event) =>
  96       target = event.originalTarget
  97
  98       if @numFocusToSuppress > 0
  99         utils.suppressEvent(event)
 100         @numFocusToSuppress--
 101         return
 102
 103       options = @vim.options(['prevent_autofocus', 'prevent_autofocus_modes'])
 104
 105       # Save the last focused text input regardless of whether that input might
 106       # be blurred because of autofocus prevention.
 107       if utils.isTextInputElement(target)
 108         @vim.state.lastFocusedTextInput = target
 109
 110       focusManager = Cc['@mozilla.org/focus-manager;1']
 111         .getService(Ci.nsIFocusManager)
 112
 113       # Blur the focus target, if autofocus prevention is enabled…
 114       if options.prevent_autofocus and
 115           @vim.mode in options.prevent_autofocus_modes and
 116           # …and the user has interacted with the page…
 117           not @vim.state.hasInteraction and
 118           # …and the event is programmatic (not caused by clicks or keypresses)…
 119           focusManager.getLastFocusMethod(null) == 0 and
 120           # …and the target may steal most keystrokes.
 121           (utils.isTextInputElement(target) or utils.isContentEditable(target))
 122         # Some sites (such as icloud.com) re-focuses inputs if they are blurred,
 123         # causing an infinite loop of autofocus prevention and re-focusing.
 124         # Therefore, blur events that happen just after an autofocus prevention
 125         # are suppressed.
 126         @listenOnce('blur', utils.suppressEvent)
 127         target.blur()
 128     )
 129
 130     @listen('blur', (event) =>
 131       target = event.originalTarget
 132
 133       # If a text input is blurred in a background tab, it most likely means
 134       # that the user switched tab, for example by pressing `<c-tab>`, while the
 135       # text input was focused. The 'TabSelect' event fires first, then the
 136       # 'blur' event. In this case, when switching back to that tab, the text
 137       # input will be re-focused (because it was focused when you left the tab).
 138       # This case is kept track of so that the autofocus prevention does not
 139       # catch it.
 140       if utils.isTextInputElement(target) or utils.isContentEditable(target)
 141         messageManager.send('vimMethod', {method: 'isCurrent'}, (isCurrent) =>
 142           @vim.state.shouldRefocus = not isCurrent
 143         )
 144     )
 145
 146     messageManager.listen('TabSelect', =>
 147       # Reset `hasInteraction` when (re-)selecting a tab, or coming back from
 148       # another window, in order to prevent the common “automatically re-focus
 149       # when switching back to the tab” behaviour many sites have, unless a text
 150       # input _should_ be re-focused when coming back to the tab (see above).
 151       if @vim.state.shouldRefocus
 152         @vim.state.hasInteraction = true
 153         @vim.state.shouldRefocus = false
 154       else
 155         @vim.state.hasInteraction = false
 156     )
 157
 158 module.exports = FrameEventManager