extension/bootstrap.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file boots the main VimFx process, as well as each frame script. It tries
  22 # to do the minimum amount of things to run main.coffee, or main-frame.coffee
  23 # for frame scripts. It defines a few global variables, and sets up a
  24 # Node.js-style `require` module loader.
  25
  26 # `bootstrap.js` files of different add-ons do _not_ share scope. However, frame
  27 # scripts for the same `<browser>` but from different add-ons _do_ share scope.
  28 # In order not to pollute that global scope in frame scripts, everything is done
  29 # in an IIFE here, and the `global` variable is handled with care.
  30
  31 do (global = this) ->
  32
  33   {classes: Cc, interfaces: Ci, utils: Cu} = Components
  34   ADDON_PATH = 'chrome://vimfx'
  35   IS_FRAME_SCRIPT = (typeof content != 'undefined')
  36
  37   unless IS_FRAME_SCRIPT
  38     # Make `Services` and `console` available globally, just like they are in
  39     # frame scripts by default.
  40     Cu.import('resource://gre/modules/Services.jsm')
  41     try
  42       # TODO: Only use this path when Firefox 44 is released.
  43       Cu.import('resource://gre/modules/Console.jsm')
  44     catch
  45       Cu.import('resource://gre/modules/devtools/Console.jsm')
  46
  47   shutdownHandlers = []
  48
  49   dirname = (uri) -> uri.split('/')[...-1].join('/') or '.'
  50
  51   require = (path, moduleRoot = '.', dir = '.') ->
  52     unless path[0] == '.'
  53       # Allow `require('module/lib/foo')` in additon to `require('module')`.
  54       [match, name, subPath] = path.match(///^ ([^/]+) (?: /(.+) )? ///)
  55       base = require.data[moduleRoot]?[name] ? moduleRoot
  56       dir  = "#{base}/node_modules/#{name}"
  57       main = require.data[dir]?['']
  58       path = subPath ? main ? 'index'
  59       moduleRoot = dir
  60
  61     prefix = "#{ADDON_PATH}/content"
  62     uri = "#{prefix}/#{dir}/#{path}.js"
  63     normalizedUri = Services.io.newURI(uri, null, null).spec
  64     currentDir = dirname(".#{normalizedUri[prefix.length..]}")
  65
  66     unless require.scopes[normalizedUri]?
  67       module = {
  68         exports: {}
  69         onShutdown: (fn) -> shutdownHandlers.push(fn)
  70       }
  71       require.scopes[normalizedUri] = scope = {
  72         require: (path) -> require.call(null, path, moduleRoot, currentDir)
  73         module, exports: module.exports
  74         Cc, Ci, Cu
  75         ADDON_PATH
  76         IS_FRAME_SCRIPT
  77         FRAME_SCRIPT_ENVIRONMENT: if IS_FRAME_SCRIPT then global else null
  78       }
  79       Services.scriptloader.loadSubScript(normalizedUri, scope, 'UTF-8')
  80
  81     return require.scopes[normalizedUri].module.exports
  82
  83   require.scopes = {}
  84
  85   global.startup = (args...) ->
  86     # `require` cannot be used outside of `startup` (except for in frame
  87     # scripts), so wait setting `require.data` until here.
  88     require.data = require('./require-data')
  89
  90     main = if IS_FRAME_SCRIPT then './lib/main-frame' else './lib/main'
  91     require(main)(args...)
  92
  93   global.shutdown = ->
  94     require('./lib/message-manager').send('shutdown') unless IS_FRAME_SCRIPT
  95
  96     for shutdownHandler in shutdownHandlers
  97       try
  98         shutdownHandler()
  99       catch error
 100         Cu.reportError(error)
 101     shutdownHandlers = null
 102
 103     # Release everything in `require`d modules. This must be done _after_ all
 104     # shutdownHandlers, since they use variables in these scopes.
 105     for path, scope of require.scopes
 106       for name of scope
 107         scope[name] = null
 108     require.scopes = null
 109
 110   global.install = ->
 111
 112   global.uninstall = ->
 113
 114   if IS_FRAME_SCRIPT
 115     messageManager = require('./lib/message-manager')
 116
 117     # Tell the main process that this frame script was created, and ask if
 118     # anything should be done in this frame.
 119     messageManager.send('tabCreated', null, (ok) ->
 120       # After dragging a tab from one window to another, `content` might have
 121       # been set to `null` by Firefox when this runs. If so, simply return.
 122       return unless ok and content?
 123
 124       global.startup()
 125
 126       # When updating the add-on, the previous version is going to shut down at
 127       # the same time as the new version starts up. Add the shutdown listener in
 128       # the next tick to prevent the previous version from triggering it.
 129       content.setTimeout((->
 130         messageManager.listenOnce('shutdown', global.shutdown)
 131       ), 0)
 132     )