extension/bootstrap.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file boots the main VimFx process, as well as each frame script. It tries
  22 # to do the minimum amount of things to run main.coffee, or main-frame.coffee
  23 # for frame scripts. It defines a few global variables, and sets up a
  24 # Node.js-style `require` module loader.
  25
  26 # `bootstrap.js` files of different add-ons do _not_ share scope. However, frame
  27 # scripts for the same `<browser>` but from different add-ons _do_ share scope.
  28 # In order not to pollute that global scope in frame scripts, everything is done
  29 # in an IIFE here, and the `global` variable is handled with care.
  30
  31 do (global = this) ->
  32
  33   {classes: Cc, interfaces: Ci, utils: Cu} = Components
  34   ADDON_PATH = 'chrome://vimfx'
  35   IS_FRAME_SCRIPT = (typeof content != 'undefined')
  36   BUILD_TIME = do -> # @echo BUILD_TIME
  37   REQUIRE_DATA = do -> # @echo REQUIRE_DATA
  38
  39   unless IS_FRAME_SCRIPT
  40     # Make `Services` and `console` available globally, just like they are in
  41     # frame scripts by default.
  42     Cu.import('resource://gre/modules/Services.jsm')
  43     Cu.import('resource://gre/modules/Console.jsm')
  44
  45   shutdownHandlers = []
  46
  47   dirname = (uri) -> uri.split('/')[...-1].join('/') or '.'
  48
  49   require = (path, moduleRoot = '.', dir = '.') ->
  50     unless path[0] == '.'
  51       # Allow `require('module/lib/foo')` in additon to `require('module')`.
  52       [match, name, subPath] = path.match(///^ ([^/]+) (?: /(.+) )? ///)
  53       base = REQUIRE_DATA[moduleRoot]?[name] ? moduleRoot
  54       dir  = "#{base}/node_modules/#{name}"
  55       main = REQUIRE_DATA[dir]?['']
  56       path = subPath ? main ? 'index'
  57       moduleRoot = dir
  58
  59     prefix = "#{ADDON_PATH}/content"
  60     uri = "#{prefix}/#{dir}/#{path}.js"
  61     normalizedUri = Services.io.newURI(uri, null, null).spec
  62     currentDir = dirname(".#{normalizedUri[prefix.length..]}")
  63
  64     unless require.scopes[normalizedUri]?
  65       module = {
  66         exports: {}
  67         onShutdown: (fn) -> shutdownHandlers.push(fn)
  68       }
  69       require.scopes[normalizedUri] = scope = {
  70         require: (path) -> require.call(null, path, moduleRoot, currentDir)
  71         module, exports: module.exports
  72         Cc, Ci, Cu
  73         ADDON_PATH, BUILD_TIME
  74         IS_FRAME_SCRIPT
  75         FRAME_SCRIPT_ENVIRONMENT: if IS_FRAME_SCRIPT then global else null
  76       }
  77       Services.scriptloader.loadSubScript(normalizedUri, scope, 'UTF-8')
  78
  79     return require.scopes[normalizedUri].module.exports
  80
  81   require.scopes = {}
  82
  83   startup = (args...) ->
  84     main = if IS_FRAME_SCRIPT then './lib/main-frame' else './lib/main'
  85     require(main)(args...)
  86
  87   shutdown = ->
  88     for shutdownHandler in shutdownHandlers
  89       try
  90         shutdownHandler()
  91       catch error
  92         Cu.reportError(error)
  93     shutdownHandlers = []
  94
  95     # Release everything in `require`d modules. This must be done _after_ all
  96     # shutdownHandlers, since they use variables in these scopes.
  97     for path, scope of require.scopes
  98       for name of scope
  99         scope[name] = null
 100     require.scopes = {}
 101
 102   if IS_FRAME_SCRIPT
 103     messageManager = require('./lib/message-manager')
 104
 105     # Tell the main process that this frame script was created, and ask if
 106     # anything should be done in this frame.
 107     messageManager.send('tabCreated', null, (ok) ->
 108       # After dragging a tab from one window to another, `content` might have
 109       # been set to `null` by Firefox when this runs. If so, simply return.
 110       return unless ok and content?
 111
 112       startup()
 113
 114       messageManager.listenOnce('shutdown', shutdown)
 115     )
 116   else
 117     global.startup = startup
 118     global.shutdown = shutdown
 119     global.install = ->
 120     global.uninstall = ->