extension/lib/modes.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 # Copyright Wang Zhuochun 2014.
   5 #
   6 # This file is part of VimFx.
   7 #
   8 # VimFx is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # VimFx is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  20 ###
  21
  22 # This file defines VimFx’s modes, and their respective commands. The Normal
  23 # mode commands are defined in commands.coffee, though.
  24
  25 {commands, findStorage} = require('./commands')
  26 defaults = require('./defaults')
  27 help = require('./help')
  28 hints = require('./hints')
  29 translate = require('./l10n')
  30 {rotateOverlappingMarkers} = require('./marker')
  31 utils = require('./utils')
  32
  33 # Helper to create modes in a DRY way.
  34 mode = (modeName, obj, commands = null) ->
  35   obj.name = translate("mode.#{modeName}")
  36   obj.order = defaults.mode_order[modeName]
  37   obj.commands = {}
  38   for commandName, fn of commands
  39     pref = "mode.#{modeName}.#{commandName}"
  40     obj.commands[commandName] = {
  41       pref: defaults.BRANCH + pref
  42       run: fn
  43       category: defaults.categoryMap[pref]
  44       description: translate(pref)
  45       order: defaults.command_order[pref]
  46     }
  47   exports[modeName] = obj
  48
  49
  50
  51 mode('normal', {
  52   onEnter: ({vim, storage}, options = {}) ->
  53     if options.returnTo
  54       storage.returnTo = options.returnTo
  55     else if storage.returnTo
  56       vim.enterMode(storage.returnTo)
  57       storage.returnTo = null
  58
  59   onLeave: ({vim}) ->
  60     vim._run('clear_inputs')
  61
  62   onInput: (args, match) ->
  63     {vim, storage, uiEvent} = args
  64     {keyStr} = match
  65
  66     if match.type == 'none' or
  67        (match.likelyConflict and not match.specialKeys['<force>'])
  68       match.discard()
  69       if storage.returnTo
  70         vim.enterMode(storage.returnTo)
  71         storage.returnTo = null
  72       # If you press `aa` (and `a` is a prefix key, but there’s no `aa`
  73       # shortcut), don’t pass the second `a` to the page.
  74       return not match.toplevel
  75
  76     if match.type == 'full'
  77       match.command.run(args)
  78
  79       # If the command changed the mode, wait until coming back from that mode
  80       # before switching to `storage.returnTo` if any (see `onEnter` above).
  81       if storage.returnTo and vim.mode == 'normal'
  82         vim.enterMode(storage.returnTo)
  83         storage.returnTo = null
  84
  85     # At this point the match is either full, partial or part of a count. Then
  86     # we always want to suppress, except for one case: The Escape key.
  87     return true unless keyStr == '<escape>'
  88
  89     # Passing Escape through allows for stopping the loading of the page and
  90     # closing many custom dialogs (and perhaps other things; Escape is a very
  91     # commonly used key).
  92     if uiEvent
  93       # In browser UI the biggest reasons are allowing to reset the location bar
  94       # when blurring it, and closing dialogs such as the “bookmark this page”
  95       # dialog (<c-d>). However, an exception is made for the devtools (<c-K>).
  96       # There, trying to unfocus the devtools using Escape would annoyingly
  97       # open the split console.
  98       return uiEvent.originalTarget.ownerGlobal.DevTools?
  99     else
 100       # In web pages content, an exception is made if an element that VimFx
 101       # cares about is focused. That allows for blurring an input in a custom
 102       # dialog without closing the dialog too.
 103       return vim.focusType != 'none'
 104
 105     # Note that this special handling of Escape is only used in Normal mode.
 106     # There are two reasons we might suppress it in other modes. If some custom
 107     # dialog of a website is open, we should be able to cancel hint markers on
 108     # it without closing it. Secondly, otherwise cancelling hint markers on
 109     # Google causes its search bar to be focused.
 110
 111 }, commands)
 112
 113
 114
 115 mode('hints', {
 116   onEnter: ({vim, storage}, markers, callback, count = 1, sleep = -1) ->
 117     storage.markers = markers
 118     storage.markerMap = null
 119     storage.callback = callback
 120     storage.count = count
 121     storage.numEnteredChars = 0
 122
 123     if sleep >= 0
 124       storage.clearInterval = utils.interval(vim.window, sleep, (next) ->
 125         unless storage.markerMap
 126           next()
 127           return
 128         vim._send('getMarkableElementsMovements', null, (diffs) ->
 129           for {dx, dy}, index in diffs when not (dx == 0 and dy == 0)
 130             storage.markerMap[index].updatePosition(dx, dy)
 131           next()
 132         )
 133       )
 134
 135     # Expose the storage so asynchronously computed markers can be set
 136     # retroactively.
 137     return storage
 138
 139   onLeave: ({vim, storage}) ->
 140     # When clicking VimFx’s disable button in the Add-ons Manager, `hints` will
 141     # have been `null`ed out when the timeout has passed.
 142     vim.window.setTimeout((-> hints?.removeHints(vim.window)),
 143                           vim.options.hints_timeout)
 144     storage.clearInterval?()
 145     for key of storage
 146       storage[key] = null
 147     return
 148
 149   onInput: (args, match) ->
 150     {vim, storage} = args
 151     {markers, callback} = storage
 152
 153     if match.type == 'full'
 154       match.command.run(args)
 155     else if match.unmodifiedKey in vim.options.hint_chars and markers.length > 0
 156       matchedMarkers = []
 157
 158       for marker in markers when marker.hintIndex == storage.numEnteredChars
 159         matched = marker.matchHintChar(match.unmodifiedKey)
 160         marker.hide() unless matched
 161         if marker.isMatched()
 162           marker.markMatched(true)
 163           matchedMarkers.push(marker)
 164
 165       if matchedMarkers.length > 0
 166         again = callback(matchedMarkers[0], storage.count, match.keyStr)
 167         storage.count -= 1
 168         if again
 169           vim.window.setTimeout((->
 170             marker.markMatched(false) for marker in matchedMarkers
 171             return
 172           ), vim.options.hints_timeout)
 173           marker.reset() for marker in markers
 174           storage.numEnteredChars = 0
 175         else
 176           vim.enterMode('normal')
 177       else
 178         storage.numEnteredChars += 1
 179
 180     return true
 181
 182 }, {
 183   exit: ({vim, storage}) ->
 184     # The hints are removed automatically when leaving the mode, but after a
 185     # timeout. When aborting the mode we should remove the hints immediately.
 186     hints.removeHints(vim.window)
 187     vim.enterMode('normal')
 188
 189   rotate_markers_forward: ({storage}) ->
 190     rotateOverlappingMarkers(storage.markers, true)
 191
 192   rotate_markers_backward: ({storage}) ->
 193     rotateOverlappingMarkers(storage.markers, false)
 194
 195   delete_hint_char: ({storage}) ->
 196     for marker in storage.markers
 197       switch marker.hintIndex - storage.numEnteredChars
 198         when 0
 199           marker.deleteHintChar()
 200         when -1
 201           marker.show()
 202     storage.numEnteredChars -= 1 unless storage.numEnteredChars == 0
 203
 204   increase_count: ({storage}) -> storage.count += 1
 205 })
 206
 207
 208
 209 mode('ignore', {
 210   onEnter: ({vim, storage}, {count = null, type = null} = {}) ->
 211     storage.count = count
 212
 213     # Keep last `.type` if no type was given. This is useful when returning to
 214     # Ignore mode after runnning the `unquote` command.
 215     if type
 216       storage.type = type
 217     else
 218       storage.type ?= 'explicit'
 219
 220   onLeave: ({vim, storage}) ->
 221     unless storage.count? or storage.type == 'focusType'
 222       vim._run('blur_active_element')
 223
 224   onInput: (args, match) ->
 225     {vim, storage} = args
 226     switch storage.count
 227       when null
 228         if match.type == 'full'
 229           match.command.run(args)
 230           return true
 231       when 1
 232         vim.enterMode('normal')
 233       else
 234         storage.count -= 1
 235     return false
 236
 237 }, {
 238   exit: ({vim, storage}) ->
 239     storage.type = null
 240     vim.enterMode('normal')
 241   unquote: ({vim}) ->
 242     vim.enterMode('normal', {returnTo: 'ignore'})
 243 })
 244
 245
 246
 247 mode('find', {
 248   onEnter: ->
 249
 250   onLeave: ({vim}) ->
 251     findBar = vim.window.gBrowser.getFindBar()
 252     findStorage.lastSearchString = findBar._findField.value
 253
 254   onInput: (args, match) ->
 255     args.findBar = args.vim.window.gBrowser.getFindBar()
 256     if match.type == 'full'
 257       match.command.run(args)
 258       return true
 259     return false
 260
 261 }, {
 262   exit: ({findBar}) -> findBar.close()
 263 })
 264
 265
 266
 267 mode('marks', {
 268   onEnter: ({storage}, callback) ->
 269     storage.callback = callback
 270
 271   onLeave: ({storage}) ->
 272     storage.callback = null
 273
 274   onInput: (args, match) ->
 275     {vim, storage} = args
 276     storage.callback(match.keyStr)
 277     vim.enterMode('normal')
 278     return true
 279 })