gulpfile.coffee

   1 fs = require('fs')
   2 path = require('path')
   3 gulp = require('gulp')
   4 coffee = require('gulp-coffee')
   5 coffeelint = require('gulp-coffeelint')
   6 git = require('gulp-git')
   7 header = require('gulp-header')
   8 mustache = require('gulp-mustache')
   9 preprocess = require('gulp-preprocess')
  10 sloc = require('gulp-sloc')
  11 tap = require('gulp-tap')
  12 zip = require('gulp-zip')
  13 marked = require('marked')
  14 merge = require('merge2')
  15 precompute = require('require-precompute')
  16 request = require('request')
  17 rimraf = require('rimraf')
  18 pkg = require('./package.json')
  19
  20 DEST = 'build'
  21 XPI = 'VimFx.xpi'
  22 LOCALE = 'extension/locale'
  23 TEST = 'extension/test'
  24
  25 BASE_LOCALE = 'en-US'
  26 UPDATE_ALL = /\s*UPDATE_ALL$/
  27
  28 ADDON_PATH = 'chrome://vimfx'
  29 BUILD_TIME = Date.now()
  30
  31 argv = process.argv.slice(2)
  32
  33 {join} = path
  34 read = (filepath) -> fs.readFileSync(filepath).toString()
  35 template = (data) -> mustache(data, {extension: ''})
  36
  37 gulp.task('clean', (callback) ->
  38   rimraf(DEST, callback)
  39 )
  40
  41 gulp.task('copy', ->
  42   gulp.src(['extension/**/!(*.coffee|*.tmpl)', 'LICENSE', 'LICENSE-MIT'])
  43     .pipe(gulp.dest(DEST))
  44 )
  45
  46 gulp.task('node_modules', ->
  47   dependencies = (name for name of pkg.dependencies)
  48   # Note: When installing or updating node modules, make sure that the following
  49   # glob does not include too much or too little!
  50   gulp.src(
  51     "node_modules/+(#{dependencies.join('|')})/\
  52      {LICENSE*,{,**/!(test|examples)/}!(*min|*test*|*bench*).js}"
  53   )
  54     .pipe(gulp.dest("#{DEST}/node_modules"))
  55 )
  56
  57 gulp.task('coffee', ->
  58   test = '--test' in argv or '-t' in argv
  59   gulp.src(
  60     [
  61       'extension/bootstrap.coffee'
  62       'extension/lib/**/*.coffee'
  63     ].concat(if test then 'extension/test/**/*.coffee' else []),
  64     {base: 'extension'}
  65   )
  66     .pipe(preprocess({context: {
  67       BUILD_TIME
  68       ADDON_PATH: JSON.stringify(ADDON_PATH)
  69       REQUIRE_DATA: JSON.stringify(precompute('.'), null, 2)
  70       TESTS:
  71         if test
  72           JSON.stringify(fs.readdirSync(TEST)
  73             .map((name) -> name.match(/^(test-.+)\.coffee$/)?[1])
  74             .filter(Boolean)
  75           )
  76         else
  77           null
  78     }}))
  79     .pipe(coffee({bare: true}))
  80     .pipe(gulp.dest(DEST))
  81 )
  82
  83 gulp.task('bootstrap-frame.js', ->
  84   gulp.src('extension/bootstrap-frame.js.tmpl')
  85     .pipe(mustache({ADDON_PATH}))
  86     .pipe(tap((file) ->
  87       file.path = file.path.replace(/\.js\.tmpl$/, "-#{BUILD_TIME}.js")
  88     ))
  89     .pipe(gulp.dest(DEST))
  90 )
  91
  92 gulp.task('chrome.manifest', ->
  93   gulp.src('extension/chrome.manifest.tmpl')
  94     .pipe(template({locales: fs.readdirSync(LOCALE).map((locale) -> {locale})}))
  95     .pipe(gulp.dest(DEST))
  96 )
  97
  98 gulp.task('install.rdf', ->
  99   [[{name: creator}], developers, contributors, translators] =
 100     read('PEOPLE.md').trim().replace(/^#.+\n|^\s*-\s*/mg, '').split('\n\n')
 101     .map((block) -> block.split('\n').map((name) -> {name}))
 102
 103   getDescription = (locale) -> read(join(LOCALE, locale, 'description')).trim()
 104
 105   descriptions = fs.readdirSync(LOCALE)
 106     .filter((locale) -> locale != BASE_LOCALE)
 107     .map((locale) -> {locale, description: getDescription(locale)})
 108
 109   gulp.src('extension/install.rdf.tmpl')
 110     .pipe(template({
 111       idSuffix: if '--unlisted' in argv or '-u' in argv then '-unlisted' else ''
 112       version: pkg.version
 113       minVersion: pkg.firefoxVersions.min
 114       maxVersion: pkg.firefoxVersions.max
 115       creator, developers, contributors, translators
 116       defaultDescription: getDescription(BASE_LOCALE)
 117       descriptions
 118     }))
 119     .pipe(gulp.dest(DEST))
 120 )
 121
 122 gulp.task('templates', gulp.parallel(
 123   'bootstrap-frame.js'
 124   'chrome.manifest'
 125   'install.rdf'
 126 ))
 127
 128 gulp.task('build', gulp.series(
 129   'clean',
 130   gulp.parallel('copy', 'node_modules', 'coffee', 'templates')
 131 ))
 132
 133 gulp.task('xpi-only', ->
 134   gulp.src("#{DEST}/**/*")
 135     .pipe(zip(XPI, {compress: false}))
 136     .pipe(gulp.dest(DEST))
 137 )
 138
 139 gulp.task('xpi', gulp.series('build', 'xpi-only'))
 140
 141 gulp.task('push-only', ->
 142   body = fs.readFileSync(join(DEST, XPI))
 143   request.post({url: 'http://localhost:8888', body})
 144 )
 145
 146 gulp.task('push', gulp.series('xpi', 'push-only'))
 147
 148 gulp.task('default', gulp.series('push'))
 149
 150 # coffeelint-forbidden-keywords has `require('coffee-script/register');` in its
 151 # index.js :(
 152 gulp.task('lint-workaround', ->
 153   gulp.src('node_modules/coffeescript/')
 154     .pipe(gulp.symlink('node_modules/coffee-script'))
 155 )
 156
 157 gulp.task('lint-only', ->
 158   gulp.src(['extension/**/*.coffee', 'gulpfile.coffee'])
 159     .pipe(coffeelint())
 160     .pipe(coffeelint.reporter())
 161     .pipe(coffeelint.reporter('fail'))
 162 )
 163
 164 gulp.task('lint', gulp.series('lint-workaround', 'lint-only'))
 165
 166 gulp.task('sloc', ->
 167   gulp.src([
 168     'extension/bootstrap.coffee'
 169     'extension/lib/!(migrations|legacy).coffee'
 170   ])
 171     .pipe(sloc())
 172 )
 173
 174 gulp.task('release', (callback) ->
 175   {version} = pkg
 176   message = "VimFx v#{version}"
 177   today = new Date().toISOString()[...10]
 178   merge([
 179     gulp.src('package.json')
 180     gulp.src('CHANGELOG.md')
 181       .pipe(header("### #{version} (#{today})\n\n"))
 182       .pipe(gulp.dest('.'))
 183   ])
 184     .pipe(git.commit(message))
 185     .on('end', ->
 186       git.tag("v#{version}", message, callback)
 187     )
 188   return
 189 )
 190
 191 gulp.task('changelog', (callback) ->
 192   num = 1
 193   for arg in argv when /^-[1-9]$/.test(arg)
 194     num = Number(arg[1])
 195   entries = read('CHANGELOG.md').split(/^### .+/m)[1..num].join('')
 196   process.stdout.write(html(entries))
 197   callback()
 198 )
 199
 200 gulp.task('readme', (callback) ->
 201   process.stdout.write(html(read('README.md')))
 202   callback()
 203 )
 204
 205 # Reduce markdown to the small subset of HTML that AMO allows. Note that AMO
 206 # converts newlines to `<br>`.
 207 html = (string) ->
 208   return marked(string)
 209     .replace(/// <h\d [^>]*> ([^<>]+) </h\d> ///g, '\n\n<b>$1</b>')
 210     .replace(///\s* <p> ((?: [^<] | <(?!/p>) )+) </p>///g, (match, text) ->
 211       return "\n#{text.replace(/\s*\n\s*/g, ' ')}\n\n"
 212     )
 213     .replace(///<li> ((?: [^<] | <(?!/li>) )+) </li>///g, (match, text) ->
 214       return "<li>#{text.replace(/\s*\n\s*/g, ' ')}</li>"
 215     )
 216     .replace(/<br>/g, '\n')
 217     .replace(///<(/?)kbd>///g, '<$1code>')
 218     .replace(/<img[^>]*>\s*/g, '')
 219     .replace(/\n\s*\n/g, '\n\n')
 220     .trim() + '\n'
 221
 222 gulp.task('faster', ->
 223   gulp.src('gulpfile.coffee')
 224     .pipe(coffee({bare: true}))
 225     .pipe(gulp.dest('.'))
 226 )
 227
 228 gulp.task('sync-locales', (callback) ->
 229   baseLocale = BASE_LOCALE
 230   compareLocale = null
 231   for arg in argv when arg[...2] == '--'
 232     name = arg[2..]
 233     if name[-1..] == '?' then compareLocale = name[...-1] else baseLocale = name
 234
 235   results = fs.readdirSync(join(LOCALE, baseLocale))
 236     .filter((file) -> path.extname(file) == '.properties')
 237     .map(syncLocale.bind(null, baseLocale))
 238
 239   if baseLocale == BASE_LOCALE
 240     report = []
 241     for {fileName, untranslated, total} in results
 242       report.push("#{fileName}:")
 243       for localeName, strings of untranslated
 244         paddedName = "#{localeName}:   "[...6]
 245         percentage = Math.round((1 - strings.length / total) * 100)
 246         if localeName == compareLocale or compareLocale == null
 247           report.push("  #{paddedName} #{percentage}%")
 248         if localeName == compareLocale
 249           report.push(strings.map((string) -> "    #{string}")...)
 250     process.stdout.write(report.join('\n') + '\n')
 251
 252   callback()
 253 )
 254
 255 syncLocale = (baseLocaleName, fileName) ->
 256   basePath = join(LOCALE, baseLocaleName, fileName)
 257   base = parseLocaleFile(read(basePath))
 258   untranslated = {}
 259   for localeName in fs.readdirSync(LOCALE)
 260     localePath = join(LOCALE, localeName, fileName)
 261     locale = parseLocaleFile(read(localePath))
 262     untranslated[localeName] = []
 263     newLocale = base.template.map((line, index) ->
 264       if Array.isArray(line)
 265         [key] = line
 266         baseValue = base.keys[key]
 267         value =
 268           if UPDATE_ALL.test(baseValue) or key not of locale.keys
 269             baseValue.replace(UPDATE_ALL, '')
 270           else
 271             locale.keys[key]
 272         result = "#{key}=#{value}"
 273         if value == base.keys[key] and value != ''
 274           untranslated[localeName].push("#{index + 1}: #{result}")
 275         return result
 276       else
 277         return line
 278     )
 279     fs.writeFileSync(localePath, newLocale.join(base.newline))
 280   delete untranslated[baseLocaleName]
 281   return {fileName, untranslated, total: Object.keys(base.keys).length}
 282
 283 parseLocaleFile = (fileContents) ->
 284   keys = {}
 285   lines = []
 286   [newline] = fileContents.match(/\r?\n/)
 287   for line in fileContents.split(newline)
 288     line = line.trim()
 289     [match, key, value] = line.match(///^ ([^=]+) = (.*) $///) ? []
 290     if match
 291       keys[key] = value
 292       lines.push([key])
 293     else
 294       lines.push(line)
 295   return {keys, template: lines, newline}
 296
 297 generateHTMLTask = (filename, message) ->
 298   gulp.task(filename, (callback) ->
 299     unless fs.existsSync(filename)
 300       process.stdout.write(message(filename))
 301       callback()
 302       return
 303     gulp.src(filename)
 304       .pipe(tap((file) ->
 305         file.contents = new Buffer(generateTestHTML(file.contents.toString()))
 306       ))
 307       .pipe(gulp.dest('.'))
 308   )
 309
 310 generateHTMLTask('help.html', (filename) -> """
 311   First enable the “Copy to clipboard” line in help.coffee, show the help
 312   dialog and finally dump the clipboard into #{filename}.
 313 """)
 314
 315 generateHTMLTask('hints.html', (filename) -> """
 316   First enable the “Copy to clipboard” line in modes.coffee, show the
 317   hint markers, activate the “Increase count” command and finally dump the
 318   clipboard into #{filename}.
 319 """)
 320
 321 testHTMLPrelude = '''
 322   <!doctype html>
 323   <meta charset=utf-8>
 324   <title>VimFx test</title>
 325   <style>
 326     * {margin: 0;}
 327     body > :first-child {min-height: 100vh; width: 100vw;}
 328   </style>
 329   <link rel=stylesheet href=extension/skin/style.css>
 330 '''
 331
 332 generateTestHTML = (dumpedHTML) ->
 333   return testHTMLPrelude + dumpedHTML
 334     .replace(/^<\w+ xmlns="[^"]+"/, '<div')
 335     .replace(/\w+>$/, 'div>')
 336     .replace(/<(\w+)([^>]*)\/>/g, '<$1$2></$1>')