extension/lib/utils.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014.
   4 # Copyright Wang Zhuochun 2013.
   5 #
   6 # This file is part of VimFx.
   7 #
   8 # VimFx is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # VimFx is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  20 ###
  21
  22 notation = require('vim-like-key-notation')
  23 { getPref
  24 , setPref
  25 } = require('./prefs')
  26
  27 ADDON_ID = 'VimFx@akhodakivskiy.github.com'
  28
  29 { classes: Cc, interfaces: Ci, utils: Cu } = Components
  30
  31 Window              = Ci.nsIDOMWindow
  32 ChromeWindow        = Ci.nsIDOMChromeWindow
  33 Element             = Ci.nsIDOMElement
  34 HTMLDocument        = Ci.nsIDOMHTMLDocument
  35 HTMLAnchorElement   = Ci.nsIDOMHTMLAnchorElement
  36 HTMLButtonElement   = Ci.nsIDOMHTMLButtonElement
  37 HTMLInputElement    = Ci.nsIDOMHTMLInputElement
  38 HTMLTextAreaElement = Ci.nsIDOMHTMLTextAreaElement
  39 HTMLSelectElement   = Ci.nsIDOMHTMLSelectElement
  40 XULDocument         = Ci.nsIDOMXULDocument
  41 XULButtonElement    = Ci.nsIDOMXULButtonElement
  42 XULControlElement   = Ci.nsIDOMXULControlElement
  43 XULMenuListElement  = Ci.nsIDOMXULMenuListElement
  44 XULTextBoxElement   = Ci.nsIDOMXULTextBoxElement
  45
  46 class Bucket
  47   constructor: (@newFunc) ->
  48     @bucket = new WeakMap()
  49
  50   get: (obj) ->
  51     if @bucket.has(obj)
  52       return @bucket.get(obj)
  53     else
  54       value = @newFunc(obj)
  55       @bucket.set(obj, value)
  56       return value
  57
  58   forget: (obj) ->
  59     @bucket.delete(obj)
  60
  61 getEventWindow = (event) ->
  62   if event.originalTarget instanceof Window
  63     return event.originalTarget
  64   else
  65     doc = event.originalTarget.ownerDocument or event.originalTarget
  66     if doc instanceof HTMLDocument or doc instanceof XULDocument
  67       return doc.defaultView
  68
  69 getEventRootWindow = (event) ->
  70   return unless window = getEventWindow(event)
  71   return getRootWindow(window)
  72
  73 getEventCurrentTabWindow = (event) ->
  74   return unless rootWindow = getEventRootWindow(event)
  75   return getCurrentTabWindow(rootWindow)
  76
  77 getRootWindow = (window) ->
  78   return window
  79     .QueryInterface(Ci.nsIInterfaceRequestor)
  80     .getInterface(Ci.nsIWebNavigation)
  81     .QueryInterface(Ci.nsIDocShellTreeItem)
  82     .rootTreeItem
  83     .QueryInterface(Ci.nsIInterfaceRequestor)
  84     .getInterface(Window)
  85
  86 getCurrentTabWindow = (window) ->
  87   return window.gBrowser.selectedTab.linkedBrowser.contentWindow
  88
  89 blurActiveElement = (window) ->
  90   # Only blur focusable elements, in order to interfere with the browser as
  91   # little as possible.
  92   { activeElement } = window.document
  93   if activeElement and activeElement.tabIndex > -1
  94     activeElement.blur()
  95
  96 isProperLink = (element) ->
  97   return element.hasAttribute('href') and
  98          (element instanceof HTMLAnchorElement or
  99           element.ownerDocument instanceof XULDocument) and
 100          not element.href.endsWith('#') and
 101          not element.href.startsWith('javascript:')
 102
 103 isTextInputElement = (element) ->
 104   return (element instanceof HTMLInputElement and element.type in [
 105            'text', 'search', 'tel', 'url', 'email', 'password', 'number'
 106          ]) or
 107          element instanceof HTMLTextAreaElement or
 108          # `<select>` elements can also receive text input: You may type the
 109          # text of an item to select it.
 110          element instanceof HTMLSelectElement or
 111          element instanceof XULMenuListElement or
 112          element instanceof XULTextBoxElement
 113
 114 isContentEditable = (element) ->
 115   return element.isContentEditable or
 116          isGoogleEditable(element)
 117
 118 isGoogleEditable = (element) ->
 119   # `g_editable` is a non-standard attribute commonly used by Google.
 120   return element.getAttribute?('g_editable') == 'true' or
 121          element.ownerDocument.body?.getAttribute('g_editable') == 'true'
 122
 123 isActivatable = (element) ->
 124   return element instanceof HTMLAnchorElement or
 125          element instanceof HTMLButtonElement or
 126          (element instanceof HTMLInputElement and element.type in [
 127            'button', 'submit', 'reset', 'image'
 128          ]) or
 129          element instanceof XULButtonElement
 130
 131 isAdjustable = (element) ->
 132   return element instanceof HTMLInputElement and element.type in [
 133            'checkbox', 'radio', 'file', 'color'
 134            'date', 'time', 'datetime', 'datetime-local', 'month', 'week'
 135          ] or
 136          element instanceof XULControlElement or
 137          # Youtube special case.
 138          element.classList?.contains('html5-video-player') or
 139          element.classList?.contains('ytp-button')
 140
 141 area = (element) ->
 142   return element.clientWidth * element.clientHeight
 143
 144 getSessionStore = ->
 145   Cc['@mozilla.org/browser/sessionstore;1'].getService(Ci.nsISessionStore)
 146
 147 loadCss = do ->
 148   sss = Cc['@mozilla.org/content/style-sheet-service;1']
 149     .getService(Ci.nsIStyleSheetService)
 150   return (name) ->
 151     uri = getResourceURI("resources/#{ name }.css")
 152     # `AGENT_SHEET` is used to override userContent.css and Stylish. Custom
 153     # website themes installed by users often make the hint markers unreadable,
 154     # for example. Just using `!important` in the CSS is not enough.
 155     unless sss.sheetRegistered(uri, sss.AGENT_SHEET)
 156       sss.loadAndRegisterSheet(uri, sss.AGENT_SHEET)
 157
 158     module.onShutdown(->
 159       sss.unregisterSheet(uri, sss.AGENT_SHEET)
 160     )
 161
 162 # Store events that we’ve simulated. A `WeakMap` is used in order not to leak
 163 # memory. This approach is better than for example setting `event.simulated =
 164 # true`, since that tells the sites that the click was simulated, and allows
 165 # sites to spoof it.
 166 simulated_events = new WeakMap()
 167
 168 # Simulate mouse click with a full chain of events. ('command' is for XUL
 169 # elements.)
 170 eventSequence = ['mouseover', 'mousedown', 'mouseup', 'click', 'command']
 171 simulateClick = (element) ->
 172   window = element.ownerDocument.defaultView
 173   for type in eventSequence
 174     mouseEvent = new window.MouseEvent(type, {
 175       # Let the event bubble in order to trigger delegated event listeners.
 176       bubbles: true
 177       # Make the event cancelable so that `<a href="#">` can be used as a
 178       # JavaScript-powered button without scrolling to the top of the page.
 179       cancelable: true
 180     })
 181     element.dispatchEvent(mouseEvent)
 182
 183 isEventSimulated = (event) ->
 184   return simulated_events.has(event)
 185
 186 WHEEL_MODE_PIXEL = Ci.nsIDOMWheelEvent.DOM_DELTA_PIXEL
 187 WHEEL_MODE_LINE  = Ci.nsIDOMWheelEvent.DOM_DELTA_LINE
 188 WHEEL_MODE_PAGE  = Ci.nsIDOMWheelEvent.DOM_DELTA_PAGE
 189
 190 # Simulate mouse scroll event by specific offsets given that mouse cursor is at
 191 # specified position.
 192 simulateWheel = (window, deltaX, deltaY, mode = WHEEL_MODE_PIXEL) ->
 193   windowUtils = window
 194     .QueryInterface(Ci.nsIInterfaceRequestor)
 195     .getInterface(Ci.nsIDOMWindowUtils)
 196
 197   [pX, pY] = [window.innerWidth / 2, window.innerHeight / 2]
 198   windowUtils.sendWheelEvent(
 199     pX, pY,             # Window offset (x, y) in pixels.
 200     deltaX, deltaY, 0,  # Deltas (x, y, z).
 201     mode,               # Mode (pixel, line, page).
 202     0,                  # Key Modifiers.
 203     0, 0,               # Line or Page deltas (x, y).
 204     0                   # Options.
 205   )
 206
 207 # Write a string to the system clipboard.
 208 writeToClipboard = (text) ->
 209   clipboardHelper = Cc['@mozilla.org/widget/clipboardhelper;1']
 210     .getService(Ci.nsIClipboardHelper)
 211   clipboardHelper.copyString(text)
 212
 213 # Executes function `func` and measures how much time it took.
 214 timeIt = (func, name) ->
 215   console.time(name)
 216   result = func()
 217   console.timeEnd(name)
 218   return result
 219
 220 isBlacklisted = (str) ->
 221   matchingRules = getMatchingBlacklistRules(str)
 222   return (matchingRules.length != 0)
 223
 224 # Returns all blacklisted keys in matching rules.
 225 getBlacklistedKeys = (str) ->
 226   matchingRules = getMatchingBlacklistRules(str)
 227   blacklistedKeys = []
 228   for rule in matchingRules when /##/.test(rule)
 229     blacklistedKeys.push(x) for x in rule.split('##')[1].split('#')
 230   return blacklistedKeys
 231
 232 # Returns all rules in the blacklist that match the provided string.
 233 getMatchingBlacklistRules = (str) ->
 234   return getBlacklist().filter((rule) ->
 235     /// ^#{ simpleWildcards(rule.split('##')[0]) }$ ///i.test(str)
 236   )
 237
 238 getBlacklist = ->
 239   return splitListString(getPref('black_list'))
 240
 241 setBlacklist = (blacklist) ->
 242   setPref('black_list', blacklist.join(','))
 243
 244 updateBlacklist = ({ add, remove } = {}) ->
 245   blacklist = getBlacklist()
 246
 247   if add
 248     blacklist.push(splitListString(add)...)
 249
 250   blacklist = blacklist.filter((rule) -> rule != '')
 251   blacklist = removeDuplicates(blacklist)
 252
 253   if remove
 254     for rule in splitListString(remove) when rule in blacklist
 255       blacklist.splice(blacklist.indexOf(rule), 1)
 256
 257   setBlacklist(blacklist)
 258
 259 # Splits a comma/space separated list into an array.
 260 splitListString = (str) ->
 261   return str.split(/\s*,[\s,]*/)
 262
 263 # Prepares a string to be used in a regexp, where "*" matches zero or more
 264 # characters and "!" matches one character.
 265 simpleWildcards = (string) ->
 266   return regexpEscape(string).replace(/\\\*/g, '.*').replace(/!/g, '.')
 267
 268 # Returns the first element that matches a pattern, favoring earlier patterns.
 269 # The patterns are case insensitive `simpleWildcards`s and must match either in
 270 # the beginning or at the end of a string. Moreover, a pattern does not match
 271 # in the middle of words, so "previous" does not match "previously". If that is
 272 # desired, a pattern such as "previous*" can be used instead. Note: We cannot
 273 # use `\b` word boundaries, because they don’t work well with non-English
 274 # characters. Instead we match a space as word boundary. Therefore we normalize
 275 # the whitespace and add spaces at the edges of the element text.
 276 getBestPatternMatch = (patterns, attrs, elements) ->
 277   regexps = []
 278   for pattern in patterns
 279     wildcarded = simpleWildcards(pattern)
 280     regexps.push(/// ^\s(?:#{ wildcarded })\s | \s(?:#{ wildcarded })\s$ ///i)
 281
 282   # Helper function that matches a string against all the patterns.
 283   matches = (text) ->
 284     normalizedText = " #{ text } ".replace(/\s+/g, ' ')
 285     for re in regexps
 286       if re.test(normalizedText)
 287         return true
 288     return false
 289
 290   # First search in attributes (favoring earlier attributes) as it's likely
 291   # that they are more specific than text contexts.
 292   for attr in attrs
 293     for element in elements
 294       if matches(element.getAttribute(attr))
 295         return element
 296
 297   # Then search in element contents.
 298   for element in elements
 299     if matches(element.textContent)
 300       return element
 301
 302   return null
 303
 304 # Get VimFx verion. AddonManager only provides async API to access addon data,
 305 # so it's a bit tricky...
 306 getVersion = do ->
 307   version = null
 308
 309   scope = {}
 310   Cu.import('resource://gre/modules/AddonManager.jsm', scope)
 311   scope.AddonManager.getAddonByID(ADDON_ID, (addon) -> version = addon.version)
 312
 313   return ->
 314     return version
 315
 316 parseHTML = (document, html) ->
 317   parser = Cc['@mozilla.org/parserutils;1'].getService(Ci.nsIParserUtils)
 318   flags = parser.SanitizerAllowStyle
 319   return parser.parseFragment(html, flags, false, null,
 320                               document.documentElement)
 321
 322 escapeHTML = (s) ->
 323   return s
 324     .replace(/&/g, '&amp;')
 325     .replace(/</g, '&lt;')
 326     .replace(/>/g, '&gt;')
 327     .replace(/"/g, '&quot;')
 328     .replace(/'/g, '&apos;')
 329
 330 createElement = (document, type, attributes = {}) ->
 331   element = document.createElement(type)
 332
 333   for attribute, value of attributes
 334     element.setAttribute(attribute, value)
 335
 336   if document instanceof HTMLDocument
 337     element.classList.add('VimFxReset')
 338
 339   return element
 340
 341 getAllElements = (document) -> switch
 342   when document instanceof HTMLDocument
 343     return document.getElementsByTagName('*')
 344   when document instanceof XULDocument
 345     elements = []
 346     getAllRegular = (element) ->
 347       for child in element.getElementsByTagName('*')
 348         elements.push(child)
 349         getAllAnonymous(child)
 350       return
 351     getAllAnonymous = (element) ->
 352       for child in document.getAnonymousNodes(element) or []
 353         continue unless child instanceof Element
 354         elements.push(child)
 355         getAllRegular(child)
 356       return
 357     getAllRegular(document.documentElement)
 358     return elements
 359
 360 isURL = (str) ->
 361   try
 362     url = Cc['@mozilla.org/network/io-service;1']
 363       .getService(Ci.nsIIOService)
 364       .newURI(str, null, null)
 365       .QueryInterface(Ci.nsIURL)
 366     return true
 367   catch err
 368     return false
 369
 370 # Use Firefox services to search for a given string.
 371 browserSearchSubmission = (str) ->
 372   ss = Cc['@mozilla.org/browser/search-service;1']
 373     .getService(Ci.nsIBrowserSearchService)
 374
 375   engine = ss.currentEngine or ss.defaultEngine
 376   return engine.getSubmission(str, null)
 377
 378 openTab = (rootWindow, url, options) ->
 379   { gBrowser } = rootWindow
 380   rootWindow.TreeStyleTabService?.readyToOpenChildTab(gBrowser.selectedTab)
 381   gBrowser.loadOneTab(url, options)
 382
 383 normalizedKey = (key) -> key.map(notation.normalize).join('')
 384
 385 # Get hint characters, convert them to lower case, and filter duplicates.
 386 getHintChars = ->
 387   hintChars = getPref('hint_chars')
 388   # Make sure that hint chars contain at least two characters.
 389   if not hintChars or hintChars.length < 2
 390     hintChars = 'fj'
 391
 392   return removeDuplicateCharacters(hintChars)
 393
 394 # Remove duplicate characters from string (case insensitive).
 395 removeDuplicateCharacters = (str) ->
 396   return removeDuplicates( str.toLowerCase().split('') ).join('')
 397
 398 # Return URI to some file in the extension packaged as resource.
 399 getResourceURI = do ->
 400   baseURI = Services.io.newURI(__SCRIPT_URI_SPEC__, null, null)
 401   return (path) -> return Services.io.newURI(path, null, baseURI)
 402
 403 # Escape a string to render it usable in regular expressions.
 404 regexpEscape = (s) -> s and s.replace(/[-\/\\^$*+?.()|[\]{}]/g, '\\$&')
 405
 406 removeDuplicates = (array) ->
 407   # coffeelint: disable=no_backticks
 408   return `[...new Set(array)]`
 409   # coffeelint: enable=no_backticks
 410
 411 exports.Bucket                    = Bucket
 412 exports.getEventWindow            = getEventWindow
 413 exports.getEventRootWindow        = getEventRootWindow
 414 exports.getEventCurrentTabWindow  = getEventCurrentTabWindow
 415 exports.getRootWindow             = getRootWindow
 416 exports.getCurrentTabWindow       = getCurrentTabWindow
 417
 418 exports.blurActiveElement         = blurActiveElement
 419 exports.isProperLink              = isProperLink
 420 exports.isTextInputElement        = isTextInputElement
 421 exports.isContentEditable         = isContentEditable
 422 exports.isActivatable             = isActivatable
 423 exports.isAdjustable              = isAdjustable
 424 exports.area                      = area
 425 exports.getSessionStore           = getSessionStore
 426
 427 exports.loadCss                   = loadCss
 428
 429 exports.simulateClick             = simulateClick
 430 exports.isEventSimulated          = isEventSimulated
 431 exports.simulateWheel             = simulateWheel
 432 exports.WHEEL_MODE_PIXEL          = WHEEL_MODE_PIXEL
 433 exports.WHEEL_MODE_LINE           = WHEEL_MODE_LINE
 434 exports.WHEEL_MODE_PAGE           = WHEEL_MODE_PAGE
 435 exports.writeToClipboard          = writeToClipboard
 436 exports.timeIt                    = timeIt
 437
 438 exports.getMatchingBlacklistRules = getMatchingBlacklistRules
 439 exports.isBlacklisted             = isBlacklisted
 440 exports.getBlacklistedKeys        = getBlacklistedKeys
 441 exports.updateBlacklist           = updateBlacklist
 442 exports.splitListString           = splitListString
 443 exports.getBestPatternMatch       = getBestPatternMatch
 444
 445 exports.getVersion                = getVersion
 446 exports.parseHTML                 = parseHTML
 447 exports.escapeHTML                = escapeHTML
 448 exports.createElement             = createElement
 449 exports.getAllElements            = getAllElements
 450 exports.isURL                     = isURL
 451 exports.browserSearchSubmission   = browserSearchSubmission
 452 exports.openTab                   = openTab
 453 exports.normalizedKey             = normalizedKey
 454 exports.getHintChars              = getHintChars
 455 exports.removeDuplicates          = removeDuplicates
 456 exports.removeDuplicateCharacters = removeDuplicateCharacters
 457 exports.getResourceURI            = getResourceURI
 458 exports.ADDON_ID                  = ADDON_ID