extension/lib/utils.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014.
   4 # Copyright Wang Zhuochun 2013.
   5 #
   6 # This file is part of VimFx.
   7 #
   8 # VimFx is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # VimFx is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  20 ###
  21
  22 notation = require('vim-like-key-notation')
  23 { getPref
  24 , setPref
  25 } = require('./prefs')
  26
  27 ADDON_ID = 'VimFx@akhodakivskiy.github.com'
  28
  29 { classes: Cc, interfaces: Ci, utils: Cu } = Components
  30
  31 Window              = Ci.nsIDOMWindow
  32 ChromeWindow        = Ci.nsIDOMChromeWindow
  33 Element             = Ci.nsIDOMElement
  34 HTMLDocument        = Ci.nsIDOMHTMLDocument
  35 HTMLAnchorElement   = Ci.nsIDOMHTMLAnchorElement
  36 HTMLButtonElement   = Ci.nsIDOMHTMLButtonElement
  37 HTMLInputElement    = Ci.nsIDOMHTMLInputElement
  38 HTMLTextAreaElement = Ci.nsIDOMHTMLTextAreaElement
  39 HTMLSelectElement   = Ci.nsIDOMHTMLSelectElement
  40 XULDocument         = Ci.nsIDOMXULDocument
  41 XULButtonElement    = Ci.nsIDOMXULButtonElement
  42 XULControlElement   = Ci.nsIDOMXULControlElement
  43 XULMenuListElement  = Ci.nsIDOMXULMenuListElement
  44 XULTextBoxElement   = Ci.nsIDOMXULTextBoxElement
  45
  46 class Bucket
  47   constructor: (@newFunc) ->
  48     @bucket = new WeakMap()
  49
  50   get: (obj) ->
  51     if @bucket.has(obj)
  52       return @bucket.get(obj)
  53     else
  54       value = @newFunc(obj)
  55       @bucket.set(obj, value)
  56       return value
  57
  58   forget: (obj) ->
  59     @bucket.delete(obj)
  60
  61 getEventWindow = (event) ->
  62   if event.originalTarget instanceof Window
  63     return event.originalTarget
  64   else
  65     doc = event.originalTarget.ownerDocument or event.originalTarget
  66     if doc instanceof HTMLDocument or doc instanceof XULDocument
  67       return doc.defaultView
  68
  69 getEventRootWindow = (event) ->
  70   return unless window = getEventWindow(event)
  71   return getRootWindow(window)
  72
  73 getEventCurrentTabWindow = (event) ->
  74   return unless rootWindow = getEventRootWindow(event)
  75   return getCurrentTabWindow(rootWindow)
  76
  77 getRootWindow = (window) ->
  78   return window
  79     .QueryInterface(Ci.nsIInterfaceRequestor)
  80     .getInterface(Ci.nsIWebNavigation)
  81     .QueryInterface(Ci.nsIDocShellTreeItem)
  82     .rootTreeItem
  83     .QueryInterface(Ci.nsIInterfaceRequestor)
  84     .getInterface(Window)
  85
  86 getCurrentTabWindow = (window) ->
  87   return window.gBrowser.selectedTab.linkedBrowser.contentWindow
  88
  89 blurActiveElement = (window) ->
  90   # Only blur focusable elements, in order to interfere with the browser as
  91   # little as possible.
  92   { activeElement } = window.document
  93   if activeElement and activeElement.tabIndex > -1
  94     activeElement.blur()
  95
  96 isProperLink = (element) ->
  97   return (element instanceof HTMLAnchorElement or
  98           (element.ownerDocument instanceof XULDocument and
  99            element.hasAttribute('href'))) and
 100          not element.href.endsWith('#') and
 101          not element.href.startsWith('javascript:')
 102
 103 isTextInputElement = (element) ->
 104   return (element instanceof HTMLInputElement and element.type in [
 105            'text', 'search', 'tel', 'url', 'email', 'password', 'number'
 106          ]) or
 107          element instanceof HTMLTextAreaElement or
 108          # `<select>` elements can also receive text input: You may type the
 109          # text of an item to select it.
 110          element instanceof HTMLSelectElement or
 111          element instanceof XULMenuListElement or
 112          element instanceof XULTextBoxElement
 113
 114 isContentEditable = (element) ->
 115   return element.isContentEditable or
 116          isGoogleEditable(element)
 117
 118 isGoogleEditable = (element) ->
 119   # `g_editable` is a non-standard attribute commonly used by Google.
 120   return element.getAttribute?('g_editable') == 'true' or
 121          element.ownerDocument.body?.getAttribute('g_editable') == 'true'
 122
 123 isActivatable = (element) ->
 124   return element instanceof HTMLAnchorElement or
 125          element instanceof HTMLButtonElement or
 126          (element instanceof HTMLInputElement and element.type in [
 127            'button', 'submit', 'reset', 'image'
 128          ]) or
 129          element instanceof XULButtonElement
 130
 131 isAdjustable = (element) ->
 132   return element instanceof HTMLInputElement and element.type in [
 133            'checkbox', 'radio', 'file', 'color'
 134            'date', 'time', 'datetime', 'datetime-local', 'month', 'week'
 135          ] or
 136          element instanceof XULControlElement
 137
 138 getSessionStore = ->
 139   Cc['@mozilla.org/browser/sessionstore;1'].getService(Ci.nsISessionStore)
 140
 141 loadCss = do ->
 142   sss = Cc['@mozilla.org/content/style-sheet-service;1']
 143     .getService(Ci.nsIStyleSheetService)
 144   return (name) ->
 145     uri = getResourceURI("resources/#{ name }.css")
 146     # `AGENT_SHEET` is used to override userContent.css and Stylish. Custom
 147     # website themes installed by users often make the hint markers unreadable,
 148     # for example. Just using `!important` in the CSS is not enough.
 149     unless sss.sheetRegistered(uri, sss.AGENT_SHEET)
 150       sss.loadAndRegisterSheet(uri, sss.AGENT_SHEET)
 151
 152     module.onShutdown(->
 153       sss.unregisterSheet(uri, sss.AGENT_SHEET)
 154     )
 155
 156 # Store events that we’ve simulated. A `WeakMap` is used in order not to leak
 157 # memory. This approach is better than for example setting `event.simulated =
 158 # true`, since that tells the sites that the click was simulated, and allows
 159 # sites to spoof it.
 160 simulated_events = new WeakMap()
 161
 162 # Simulate mouse click with a full chain of events. ('command' is for XUL
 163 # elements.)
 164 eventSequence = ['mouseover', 'mousedown', 'mouseup', 'click', 'command']
 165 simulateClick = (element) ->
 166   window = element.ownerDocument.defaultView
 167   for type in eventSequence
 168     mouseEvent = new window.MouseEvent(type)
 169     element.dispatchEvent(mouseEvent)
 170
 171 isEventSimulated = (event) ->
 172   return simulated_events.has(event)
 173
 174 WHEEL_MODE_PIXEL = Ci.nsIDOMWheelEvent.DOM_DELTA_PIXEL
 175 WHEEL_MODE_LINE  = Ci.nsIDOMWheelEvent.DOM_DELTA_LINE
 176 WHEEL_MODE_PAGE  = Ci.nsIDOMWheelEvent.DOM_DELTA_PAGE
 177
 178 # Simulate mouse scroll event by specific offsets given that mouse cursor is at
 179 # specified position.
 180 simulateWheel = (window, deltaX, deltaY, mode = WHEEL_MODE_PIXEL) ->
 181   windowUtils = window
 182     .QueryInterface(Ci.nsIInterfaceRequestor)
 183     .getInterface(Ci.nsIDOMWindowUtils)
 184
 185   [pX, pY] = [window.innerWidth / 2, window.innerHeight / 2]
 186   windowUtils.sendWheelEvent(
 187     pX, pY,             # Window offset (x, y) in pixels.
 188     deltaX, deltaY, 0,  # Deltas (x, y, z).
 189     mode,               # Mode (pixel, line, page).
 190     0,                  # Key Modifiers.
 191     0, 0,               # Line or Page deltas (x, y).
 192     0                   # Options.
 193   )
 194
 195 # Write a string to the system clipboard.
 196 writeToClipboard = (text) ->
 197   clipboardHelper = Cc['@mozilla.org/widget/clipboardhelper;1']
 198     .getService(Ci.nsIClipboardHelper)
 199   clipboardHelper.copyString(text)
 200
 201 # Executes function `func` and mearues how much time it took.
 202 timeIt = (func, name) ->
 203   console.time(name)
 204   result = func()
 205   console.timeEnd(name)
 206   return result
 207
 208 isBlacklisted = (str) ->
 209   matchingRules = getMatchingBlacklistRules(str)
 210   return (matchingRules.length != 0)
 211
 212 # Returns all blacklisted keys in matching rules.
 213 getBlacklistedKeys = (str) ->
 214   matchingRules = getMatchingBlacklistRules(str)
 215   blacklistedKeys = []
 216   for rule in matchingRules when /##/.test(rule)
 217     blacklistedKeys.push(x) for x in rule.split('##')[1].split('#')
 218   return blacklistedKeys
 219
 220 # Returns all rules in the blacklist that match the provided string.
 221 getMatchingBlacklistRules = (str) ->
 222   return getBlacklist().filter((rule) ->
 223     /// ^#{ simpleWildcards(rule.split('##')[0]) }$ ///i.test(str)
 224   )
 225
 226 getBlacklist = ->
 227   return splitListString(getPref('black_list'))
 228
 229 setBlacklist = (blacklist) ->
 230   setPref('black_list', blacklist.join(','))
 231
 232 updateBlacklist = ({ add, remove } = {}) ->
 233   blacklist = getBlacklist()
 234
 235   if add
 236     blacklist.push(splitListString(add)...)
 237
 238   blacklist = blacklist.filter((rule) -> rule != '')
 239   blacklist = removeDuplicates(blacklist)
 240
 241   if remove
 242     for rule in splitListString(remove) when rule in blacklist
 243       blacklist.splice(blacklist.indexOf(rule), 1)
 244
 245   setBlacklist(blacklist)
 246
 247 # Splits a comma/space separated list into an array.
 248 splitListString = (str) ->
 249   return str.split(/\s*,[\s,]*/)
 250
 251 # Prepares a string to be used in a regexp, where "*" matches zero or more
 252 # characters and "!" matches one character.
 253 simpleWildcards = (string) ->
 254   return regexpEscape(string).replace(/\\\*/g, '.*').replace(/!/g, '.')
 255
 256 # Returns the first element that matches a pattern, favoring earlier patterns.
 257 # The patterns are case insensitive `simpleWildcards`s and must match either in
 258 # the beginning or at the end of a string. Moreover, a pattern does not match
 259 # in the middle of words, so "previous" does not match "previously". If that is
 260 # desired, a pattern such as "previous*" can be used instead. Note: We cannot
 261 # use `\b` word boundaries, because they don’t work well with non-English
 262 # characters. Instead we match a space as word boundary. Therefore we normalize
 263 # the whitespace and add spaces at the edges of the element text.
 264 getBestPatternMatch = (patterns, attrs, elements) ->
 265   regexps = []
 266   for pattern in patterns
 267     wildcarded = simpleWildcards(pattern)
 268     regexps.push(/// ^\s(?:#{ wildcarded })\s | \s(?:#{ wildcarded })\s$ ///i)
 269
 270   # Helper function that matches a string against all the patterns.
 271   matches = (text) ->
 272     normalizedText = " #{ text } ".replace(/\s+/g, ' ')
 273     for re in regexps
 274       if re.test(normalizedText)
 275         return true
 276     return false
 277
 278   # First search in attributes (favoring earlier attributes) as it's likely
 279   # that they are more specific than text contexts.
 280   for attr in attrs
 281     for element in elements
 282       if matches(element.getAttribute(attr))
 283         return element
 284
 285   # Then search in element contents.
 286   for element in elements
 287     if matches(element.textContent)
 288       return element
 289
 290   return null
 291
 292 # Get VimFx verion. AddonManager only provides async API to access addon data,
 293 # so it's a bit tricky...
 294 getVersion = do ->
 295   version = null
 296
 297   scope = {}
 298   Cu.import('resource://gre/modules/AddonManager.jsm', scope)
 299   scope.AddonManager.getAddonByID(ADDON_ID, (addon) -> version = addon.version)
 300
 301   return ->
 302     return version
 303
 304 parseHTML = (document, html) ->
 305   parser = Cc['@mozilla.org/parserutils;1'].getService(Ci.nsIParserUtils)
 306   flags = parser.SanitizerAllowStyle
 307   return parser.parseFragment(html, flags, false, null,
 308                               document.documentElement)
 309
 310 escapeHTML = (s) ->
 311   return s
 312     .replace(/&/g, '&amp;')
 313     .replace(/</g, '&lt;')
 314     .replace(/>/g, '&gt;')
 315     .replace(/"/g, '&quot;')
 316     .replace(/'/g, '&apos;')
 317
 318 createElement = (document, type, attributes = {}) ->
 319   element = document.createElement(type)
 320
 321   for attribute, value of attributes
 322     element.setAttribute(attribute, value)
 323
 324   if document instanceof HTMLDocument
 325     element.classList.add('VimFxReset')
 326
 327   return element
 328
 329 getAllElements = (document) -> switch
 330   when document instanceof HTMLDocument
 331     return document.getElementsByTagName('*')
 332   when document instanceof XULDocument
 333     elements = []
 334     getAllRegular = (element) ->
 335       for child in element.getElementsByTagName('*')
 336         elements.push(child)
 337         getAllAnonymous(child)
 338       return
 339     getAllAnonymous = (element) ->
 340       for child in document.getAnonymousNodes(element) or []
 341         continue unless child instanceof Element
 342         elements.push(child)
 343         getAllRegular(child)
 344       return
 345     getAllRegular(document.documentElement)
 346     return elements
 347
 348 isURL = (str) ->
 349   try
 350     url = Cc['@mozilla.org/network/io-service;1']
 351       .getService(Ci.nsIIOService)
 352       .newURI(str, null, null)
 353       .QueryInterface(Ci.nsIURL)
 354     return true
 355   catch err
 356     return false
 357
 358 # Use Firefox services to search for a given string.
 359 browserSearchSubmission = (str) ->
 360   ss = Cc['@mozilla.org/browser/search-service;1']
 361     .getService(Ci.nsIBrowserSearchService)
 362
 363   engine = ss.currentEngine or ss.defaultEngine
 364   return engine.getSubmission(str, null)
 365
 366 normalizedKey = (key) -> key.map(notation.normalize).join('')
 367
 368 # Get hint characters, convert them to lower case, and filter duplicates.
 369 getHintChars = ->
 370   hintChars = getPref('hint_chars')
 371   # Make sure that hint chars contain at least two characters.
 372   if not hintChars or hintChars.length < 2
 373     hintChars = 'fj'
 374
 375   return removeDuplicateCharacters(hintChars)
 376
 377 # Remove duplicate characters from string (case insensitive).
 378 removeDuplicateCharacters = (str) ->
 379   return removeDuplicates( str.toLowerCase().split('') ).join('')
 380
 381 # Return URI to some file in the extension packaged as resource.
 382 getResourceURI = do ->
 383   baseURI = Services.io.newURI(__SCRIPT_URI_SPEC__, null, null)
 384   return (path) -> return Services.io.newURI(path, null, baseURI)
 385
 386 # Escape a string to render it usable in regular expressions.
 387 regexpEscape = (s) -> s and s.replace(/[-\/\\^$*+?.()|[\]{}]/g, '\\$&')
 388
 389 removeDuplicates = (array) ->
 390   # coffeelint: disable=no_backticks
 391   return `[...new Set(array)]`
 392   # coffeelint: enable=no_backticks
 393
 394 exports.Bucket                    = Bucket
 395 exports.getEventWindow            = getEventWindow
 396 exports.getEventRootWindow        = getEventRootWindow
 397 exports.getEventCurrentTabWindow  = getEventCurrentTabWindow
 398 exports.getRootWindow             = getRootWindow
 399 exports.getCurrentTabWindow       = getCurrentTabWindow
 400
 401 exports.blurActiveElement         = blurActiveElement
 402 exports.isProperLink              = isProperLink
 403 exports.isTextInputElement        = isTextInputElement
 404 exports.isContentEditable         = isContentEditable
 405 exports.isActivatable             = isActivatable
 406 exports.isAdjustable              = isAdjustable
 407 exports.getSessionStore           = getSessionStore
 408
 409 exports.loadCss                   = loadCss
 410
 411 exports.simulateClick             = simulateClick
 412 exports.isEventSimulated          = isEventSimulated
 413 exports.simulateWheel             = simulateWheel
 414 exports.WHEEL_MODE_PIXEL          = WHEEL_MODE_PIXEL
 415 exports.WHEEL_MODE_LINE           = WHEEL_MODE_LINE
 416 exports.WHEEL_MODE_PAGE           = WHEEL_MODE_PAGE
 417 exports.writeToClipboard          = writeToClipboard
 418 exports.timeIt                    = timeIt
 419
 420 exports.getMatchingBlacklistRules = getMatchingBlacklistRules
 421 exports.isBlacklisted             = isBlacklisted
 422 exports.getBlacklistedKeys        = getBlacklistedKeys
 423 exports.updateBlacklist           = updateBlacklist
 424 exports.splitListString           = splitListString
 425 exports.getBestPatternMatch       = getBestPatternMatch
 426
 427 exports.getVersion                = getVersion
 428 exports.parseHTML                 = parseHTML
 429 exports.escapeHTML                = escapeHTML
 430 exports.createElement             = createElement
 431 exports.getAllElements            = getAllElements
 432 exports.isURL                     = isURL
 433 exports.browserSearchSubmission   = browserSearchSubmission
 434 exports.normalizedKey             = normalizedKey
 435 exports.getHintChars              = getHintChars
 436 exports.removeDuplicates          = removeDuplicates
 437 exports.removeDuplicateCharacters = removeDuplicateCharacters
 438 exports.getResourceURI            = getResourceURI
 439 exports.ADDON_ID                  = ADDON_ID