extension/packages/commands.coffee

   1 utils = require 'utils'
   2 help  = require 'help'
   3 { _ } = require 'l10n'
   4 { getPref
   5 , getComplexPref
   6 , setPref
   7 , isPrefSet
   8 , getFirefoxPref } = require 'prefs'
   9
  10 { classes: Cc, interfaces: Ci, utils: Cu } = Components
  11
  12 # “Selecting an element” means “focusing and selecting the text, if any, of an
  13 # element”.
  14
  15 # Open and select the Developer Toolbar
  16 command_dev = (vim) ->
  17   vim.rootWindow.DeveloperToolbar.show(true)
  18   vim.rootWindow.DeveloperToolbar.focus()
  19
  20 # Select the Address Bar
  21 command_focus = (vim) ->
  22   # This function works even if the Address Bar has been removed.
  23   vim.rootWindow.focusAndSelectUrlBar()
  24
  25 # Select the Search Bar
  26 command_focus_search = (vim) ->
  27   # A `?` is used since the Search Bar might have been removed.
  28   vim.BrowserSearch.searchBar?.select()
  29
  30 helper_paste = (vim) ->
  31   url = utils.readFromClipboard(vim.window)
  32   postData = null
  33   if not utils.isURL(url) and submission = utils.browserSearchSubmission(url)
  34     url = submission.uri.spec
  35     { postData } = submission
  36   return { url, postData }
  37
  38 # Go to or search for the contents of the system clipboard
  39 command_paste = (vim) ->
  40   { url, postData } = helper_paste(vim)
  41   vim.rootWindow.gBrowser.loadURIWithFlags(url, null, null, null, postData)
  42
  43 # Go to or search for the contents of the system clipboard in a new tab
  44 command_paste_tab = (vim) ->
  45   { url, postData } = helper_paste(vim)
  46   vim.rootWindow.gBrowser.selectedTab = vim.rootWindow.gBrowser.addTab(url, null, null, postData, null, false)
  47
  48 # Open a new tab and select the Address Bar
  49 command_open_tab = (vim) ->
  50   vim.rootWindow.BrowserOpenTab()
  51
  52 # Copy the URL or text of a marker element to the system clipboard
  53 command_marker_yank = (vim) ->
  54   callback = (marker) ->
  55     if url = marker.element.href
  56       marker.element.focus()
  57       utils.writeToClipboard(url)
  58     else if utils.isTextInputElement(marker.element)
  59       utils.writeToClipboard(marker.element.value)
  60
  61   vim.enterMode('hints', callback)
  62
  63 # Focus element
  64 command_marker_focus = (vim) ->
  65   callback = (marker) -> marker.element.focus()
  66
  67   vim.enterMode('hints', callback)
  68
  69 # Copy the current URL to the system clipboard
  70 command_yank = (vim) ->
  71   utils.writeToClipboard(vim.window.location.href)
  72
  73 # Reload the current tab, possibly from cache
  74 command_reload = (vim) ->
  75   vim.rootWindow.BrowserReload()
  76
  77 # Reload the current tab, skipping cache
  78 command_reload_force = (vim) ->
  79   vim.rootWindow.BrowserReloadSkipCache()
  80
  81 # Reload all tabs, possibly from cache
  82 command_reload_all = (vim) ->
  83   vim.rootWindow.gBrowser.reloadAllTabs()
  84
  85 # Reload all tabs, skipping cache
  86 command_reload_all_force = (vim) ->
  87   for tab in vim.rootWindow.gBrowser.visibleTabs
  88     window = tab.linkedBrowser.contentWindow
  89     window.location.reload(true)
  90
  91 # Stop loading the current tab
  92 command_stop = (vim) ->
  93   vim.window.stop()
  94
  95 # Stop loading all tabs
  96 command_stop_all = (vim) ->
  97   for tab in vim.rootWindow.gBrowser.visibleTabs
  98     window = tab.linkedBrowser.contentWindow
  99     window.stop()
 100
 101 # Scroll to the top of the page
 102 command_scroll_to_top = (vim) ->
 103   vim.rootWindow.goDoCommand('cmd_scrollTop')
 104
 105 # Scroll to the bottom of the page
 106 command_scroll_to_bottom = (vim) ->
 107   vim.rootWindow.goDoCommand('cmd_scrollBottom')
 108
 109 # Scroll down a bit
 110 command_scroll_down = (vim) ->
 111   utils.simulateWheel(vim.window, 0, getPref('scroll_step_lines'), utils.WHEEL_MODE_LINE)
 112
 113 # Scroll up a bit
 114 command_scroll_up = (vim) ->
 115   utils.simulateWheel(vim.window, 0, -getPref('scroll_step_lines'), utils.WHEEL_MODE_LINE)
 116
 117 # Scroll left a bit
 118 command_scroll_left = (vim) ->
 119   utils.simulateWheel(vim.window, -getPref('scroll_step_lines'), 0, utils.WHEEL_MODE_LINE)
 120
 121 # Scroll right a bit
 122 command_scroll_right = (vim) ->
 123   utils.simulateWheel(vim.window, getPref('scroll_step_lines'), 0, utils.WHEEL_MODE_LINE)
 124
 125 # Scroll down half a page
 126 command_scroll_half_page_down = (vim) ->
 127   utils.simulateWheel(vim.window, 0, 0.5, utils.WHEEL_MODE_PAGE)
 128
 129 # Scroll up half a page
 130 command_scroll_half_page_up = (vim) ->
 131   utils.simulateWheel(vim.window, 0, -0.5, utils.WHEEL_MODE_PAGE)
 132
 133 # Scroll down full a page
 134 command_scroll_page_down = (vim) ->
 135   utils.simulateWheel(vim.window, 0, 1, utils.WHEEL_MODE_PAGE)
 136
 137 # Scroll up full a page
 138 command_scroll_page_up = (vim) ->
 139   utils.simulateWheel(vim.window, 0, -1, utils.WHEEL_MODE_PAGE)
 140
 141 # Activate previous tab
 142 command_tab_prev = (vim) ->
 143   vim.rootWindow.gBrowser.tabContainer.advanceSelectedTab(-1, true)
 144
 145 # Activate next tab
 146 command_tab_next = (vim) ->
 147   vim.rootWindow.gBrowser.tabContainer.advanceSelectedTab(1, true)
 148
 149 command_home = (vim) ->
 150   url = getFirefoxPref('browser.startup.homepage')
 151   vim.rootWindow.gBrowser.loadURIWithFlags(url, null, null, null, null)
 152
 153 # Go to the first tab
 154 command_tab_first = (vim) ->
 155   vim.rootWindow.gBrowser.tabContainer.selectedIndex = 0
 156
 157 # Go to the last tab
 158 command_tab_last = (vim) ->
 159   itemCount = vim.rootWindow.gBrowser.tabContainer.itemCount
 160   vim.rootWindow.gBrowser.tabContainer.selectedIndex = itemCount - 1
 161
 162 # Go back in history
 163 command_back = (vim) ->
 164   vim.window.history.back()
 165
 166 # Go forward in history
 167 command_forward = (vim) ->
 168   vim.window.history.forward()
 169
 170 # Close current tab
 171 command_close_tab = (vim) ->
 172   unless vim.rootWindow.gBrowser.selectedTab.pinned
 173     vim.rootWindow.gBrowser.removeCurrentTab()
 174
 175 # Restore last closed tab
 176 command_restore_tab = (vim) ->
 177   ss = utils.getSessionStore()
 178   if ss and ss.getClosedTabCount(vim.rootWindow) > 0
 179     ss.undoCloseTab(vim.rootWindow, 0)
 180
 181 helper_follow = ({ inTab, multiple }, vim) ->
 182   callback = (matchedMarker, markers) ->
 183     matchedMarker.element.focus()
 184     utils.simulateClick(matchedMarker.element, {metaKey: inTab, ctrlKey: inTab})
 185     isEditable = utils.isElementEditable(matchedMarker.element)
 186     if multiple and not isEditable
 187       # By not resetting immediately one is able to see the last char being matched, which gives
 188       # some nice visual feedback that you've typed the right char.
 189       vim.window.setTimeout((-> marker.reset() for marker in markers), 100)
 190       return true
 191
 192   vim.enterMode('hints', callback)
 193
 194 # Follow links with hint markers
 195 command_follow = helper_follow.bind(undefined, {inTab: false})
 196
 197 # Follow links in a new Tab with hint markers
 198 command_follow_in_tab = helper_follow.bind(undefined, {inTab: true})
 199
 200 # Follow multiple links with hint markers
 201 command_follow_multiple = helper_follow.bind(undefined, {inTab: true, multiple: true})
 202
 203 helper_follow_pattern = (type, vim) ->
 204   links = utils.getMarkableElements(vim.window.document, {type: 'action'})
 205     .filter(utils.isElementVisible)
 206   patterns = utils.splitListString(getComplexPref("#{ type }_patterns"))
 207   matchingLink = utils.getBestPatternMatch(patterns, links)
 208
 209   if matchingLink
 210     utils.simulateClick(matchingLink, {metaKey: false, ctrlKey: false})
 211
 212 # Follow previous page
 213 command_follow_prev = helper_follow_pattern.bind(undefined, 'prev')
 214
 215 # Follow next page
 216 command_follow_next = helper_follow_pattern.bind(undefined, 'next')
 217
 218 # Go up one level in the URL hierarchy
 219 command_go_up_path = (vim) ->
 220   path = vim.window.location.pathname
 221   vim.window.location.pathname = path.replace(/// / [^/]+ /?$ ///, '')
 222
 223 # Go up to root of the URL hierarchy
 224 command_go_to_root = (vim) ->
 225   vim.window.location.href = vim.window.location.origin
 226
 227 # Move current tab to the left
 228 command_tab_move_left = (vim) ->
 229   if { gBrowser } = vim.rootWindow
 230     if tab = gBrowser.selectedTab
 231       index = gBrowser.tabContainer.selectedIndex
 232       total = gBrowser.tabContainer.itemCount
 233
 234       # `total` is added to deal with negative offset
 235       gBrowser.moveTabTo(tab, (total + index - 1) % total)
 236
 237 # Move current tab to the right
 238 command_tab_move_right = (vim) ->
 239   if { gBrowser } = vim.window
 240     if tab = gBrowser.selectedTab
 241       index = gBrowser.tabContainer.selectedIndex
 242       total = gBrowser.tabContainer.itemCount
 243
 244       gBrowser.moveTabTo(tab, (index + 1) % total)
 245
 246 # Display the Help Dialog
 247 command_help = (vim) ->
 248   help.injectHelp(vim.window.document, commands)
 249
 250 findStorage = { lastSearchString: '' }
 251
 252 # Switch into find mode
 253 command_find = (vim) ->
 254   vim.enterMode('find', { highlight: false })
 255
 256 # Switch into find mode with highlighting
 257 command_find_hl = (vim) ->
 258   vim.enterMode('find', { highlight: true })
 259
 260 # Search for the last pattern
 261 command_find_next = (vim) ->
 262   if findBar = vim.rootWindow.gBrowser.getFindBar()
 263     if findStorage.lastSearchString.length > 0
 264       findBar._findField.value = findStorage.lastSearchString
 265       findBar.onFindAgainCommand(false)
 266
 267 # Search for the last pattern backwards
 268 command_find_prev = (vim) ->
 269   if findBar = vim.rootWindow.gBrowser.getFindBar()
 270     if findStorage.lastSearchString.length > 0
 271       findBar._findField.value = findStorage.lastSearchString
 272       findBar.onFindAgainCommand(true)
 273
 274 command_insert_mode = (vim) ->
 275   vim.enterMode('insert')
 276
 277 command_Esc = (vim, event) ->
 278   utils.blurActiveElement(vim.window)
 279
 280   # Blur active XUL control
 281   callback = -> event.originalTarget?.ownerDocument?.activeElement?.blur()
 282   vim.window.setTimeout(callback, 0)
 283
 284   help.removeHelp(vim.window.document)
 285
 286   vim.rootWindow.DeveloperToolbar.hide()
 287
 288   vim.rootWindow.gBrowser.getFindBar()?.close()
 289
 290
 291 class Command
 292   constructor: (@group, @name, @func, keys) ->
 293     @defaultKeys = keys
 294     if isPrefSet(@prefName('keys'))
 295       try @keyValues = JSON.parse(getPref(@prefName('keys')))
 296     else
 297       @keyValues = keys
 298
 299   # Name of the preference for a given property
 300   prefName: (value) -> "commands.#{ @name }.#{ value }"
 301
 302   keys: (value) ->
 303     if value is undefined
 304       return @keyValues
 305     else
 306       @keyValues = value or @defaultKeyValues
 307       setPref(@prefName('keys'), value and JSON.stringify(value))
 308
 309   help: -> _("help_command_#{ @name }")
 310
 311 commands = [
 312   new Command('urls',   'focus',                  command_focus,                  ['o'])
 313   new Command('urls',   'focus_search',           command_focus_search,           ['O'])
 314   new Command('urls',   'paste',                  command_paste,                  ['p'])
 315   new Command('urls',   'paste_tab',              command_paste_tab,              ['P'])
 316   new Command('urls',   'marker_yank',            command_marker_yank,            ['y,f'])
 317   new Command('urls',   'marker_focus',           command_marker_focus,           ['v,f'])
 318   new Command('urls',   'yank',                   command_yank,                   ['y,y'])
 319   new Command('urls',   'reload',                 command_reload,                 ['r'])
 320   new Command('urls',   'reload_force',           command_reload_force,           ['R'])
 321   new Command('urls',   'reload_all',             command_reload_all,             ['a,r'])
 322   new Command('urls',   'reload_all_force',       command_reload_all_force,       ['a,R'])
 323   new Command('urls',   'stop',                   command_stop,                   ['s'])
 324   new Command('urls',   'stop_all',               command_stop_all,               ['a,s'])
 325
 326   new Command('nav',    'scroll_to_top',          command_scroll_to_top ,         ['g,g'])
 327   new Command('nav',    'scroll_to_bottom',       command_scroll_to_bottom,       ['G'])
 328   new Command('nav',    'scroll_down',            command_scroll_down,            ['j', 'c-e'])
 329   new Command('nav',    'scroll_up',              command_scroll_up,              ['k', 'c-y'])
 330   new Command('nav',    'scroll_left',            command_scroll_left,            ['h'])
 331   new Command('nav',    'scroll_right',           command_scroll_right ,          ['l'])
 332   new Command('nav',    'scroll_half_page_down',  command_scroll_half_page_down,  ['d'])
 333   new Command('nav',    'scroll_half_page_up',    command_scroll_half_page_up,    ['u'])
 334   new Command('nav',    'scroll_page_down',       command_scroll_page_down,       ['c-f'])
 335   new Command('nav',    'scroll_page_up',         command_scroll_page_up,         ['c-b'])
 336
 337   new Command('tabs',   'open_tab',               command_open_tab,               ['t'])
 338   new Command('tabs',   'tab_prev',               command_tab_prev,               ['J', 'g,T'])
 339   new Command('tabs',   'tab_next',               command_tab_next,               ['K', 'g,t'])
 340   new Command('tabs',   'tab_move_left',          command_tab_move_left,          ['c-J'])
 341   new Command('tabs',   'tab_move_right',         command_tab_move_right,         ['c-K'])
 342   new Command('tabs',   'home',                   command_home,                   ['g,h'])
 343   new Command('tabs',   'tab_first',              command_tab_first,              ['g,H', 'g,^'])
 344   new Command('tabs',   'tab_last',               command_tab_last,               ['g,L', 'g,$'])
 345   new Command('tabs',   'close_tab',              command_close_tab,              ['x'])
 346   new Command('tabs',   'restore_tab',            command_restore_tab,            ['X'])
 347
 348   new Command('browse', 'follow',                 command_follow,                 ['f'])
 349   new Command('browse', 'follow_in_tab',          command_follow_in_tab,          ['F'])
 350   new Command('browse', 'follow_multiple',        command_follow_multiple,        ['a,f'])
 351   new Command('browse', 'follow_previous',        command_follow_prev,            ['['])
 352   new Command('browse', 'follow_next',            command_follow_next,            [']'])
 353   new Command('browse', 'go_up_path',             command_go_up_path,             ['g,u'])
 354   new Command('browse', 'go_to_root',             command_go_to_root,             ['g,U'])
 355   new Command('browse', 'back',                   command_back,                   ['H'])
 356   new Command('browse', 'forward',                command_forward,                ['L'])
 357
 358   new Command('misc',   'find',                   command_find,                   ['/'])
 359   new Command('misc',   'find_hl',                command_find_hl,                ['a,/'])
 360   new Command('misc',   'find_next',              command_find_next,              ['n'])
 361   new Command('misc',   'find_prev',              command_find_prev,              ['N'])
 362   new Command('misc',   'insert_mode',            command_insert_mode,            ['i'])
 363   new Command('misc',   'help',                   command_help,                   ['?'])
 364   new Command('misc',   'dev',                    command_dev,                    [':'])
 365
 366   escapeCommand =
 367   new Command('misc',   'Esc',                    command_Esc,                    ['Esc'])
 368 ]
 369
 370 searchForMatchingCommand = (keys) ->
 371   for index in [0...keys.length] by 1
 372     str = keys[index..].join(',')
 373     for command in commands
 374       for key in command.keys()
 375         # The following hack is a workaround for the issue where # letter `c`
 376         # is considered a start of command with control modifier `c-xxx`
 377         if "#{key},".startsWith("#{str},")
 378           return {match: true, exact: (key == str), command}
 379
 380   return {match: false}
 381
 382 isEscCommandKey = (keyStr) -> keyStr in escapeCommand.keys()
 383
 384 isReturnCommandKey = (keyStr) -> keyStr.contains('Return')
 385
 386 exports.commands                  = commands
 387 exports.searchForMatchingCommand  = searchForMatchingCommand
 388 exports.isEscCommandKey           = isEscCommandKey
 389 exports.isReturnCommandKey        = isReturnCommandKey
 390 exports.findStorage               = findStorage