extension/lib/events.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file sets up all event listeners needed to power VimFx: To know when to
  22 # launch commands and to provide state to them. Events in web page content are
  23 # listened for in events-frame.coffee.
  24
  25 button = require('./button')
  26 messageManager = require('./message-manager')
  27 prefs = require('./prefs')
  28 utils = require('./utils')
  29
  30 HELD_MODIFIERS_ATTRIBUTE = 'vimfx-held-modifiers'
  31
  32 class UIEventManager
  33   constructor: (@vimfx, @window) ->
  34     @listen = utils.listen.bind(null, @window)
  35     @listenOnce = utils.listenOnce.bind(null, @window)
  36
  37     # This flag controls whether to suppress the various key events or not.
  38     @suppress = false
  39
  40     # If a matched shortcut has the `<late>` special key, this flag is set to
  41     # `true`.
  42     @late = false
  43
  44     # When a menu or panel is shown VimFx should temporarily stop processing
  45     # keyboard input, allowing accesskeys to be used.
  46     @popupPassthrough = false
  47
  48     @enteredKeys = new EnteredKeysManager(@window)
  49
  50   addListeners: ->
  51     checkPassthrough = (value, event) =>
  52       target = event.originalTarget
  53       if target.localName in ['menupopup', 'panel'] and
  54          # Don’t set `@popupPassthrough` to `false` if there actually are popups
  55          # open. This is the case when a sub-menu closes.
  56          (value or not @anyPopupsOpen())
  57         @popupPassthrough = value
  58
  59     @listen('popupshown',  checkPassthrough.bind(null, true))
  60     @listen('popuphidden', checkPassthrough.bind(null, false))
  61
  62     @listen('keydown', (event) =>
  63       # No matter what, always reset the `@suppress` flag, so we don't
  64       # suppress more than intended.
  65       @suppress = false
  66
  67       # Reset the `@late` flag, telling any late listeners for the previous
  68       # event not to run. Also reset the `late` pref, telling frame scripts not
  69       # to do synchronous message passing on every keydown.
  70       @late = false
  71       prefs.set('late', false)
  72
  73       if @popupPassthrough
  74         # The `@popupPassthrough` flag is set a bit unreliably. Sometimes it
  75         # can be stuck as `true` even though no popup is shown, effectively
  76         # disabling the extension. Therefore we check if there actually _are_
  77         # any open popups before stopping processing keyboard input. This is
  78         # only done when popups (might) be open (not on every keystroke) for
  79         # performance reasons.
  80         return if @anyPopupsOpen()
  81         @popupPassthrough = false # No popup was actually open.
  82
  83       return unless vim = @vimfx.getCurrentVim(@window)
  84
  85       @consumeKeyEvent(vim, event)
  86       if @suppress
  87         utils.suppressEvent(event) # This also suppresses the 'keypress' event.
  88       else
  89         # If this keydown event wasn’t suppressed, it’s an obvious interaction
  90         # with the page. If it _was_ suppressed, though, it’s an interaction
  91         # depending on the command triggered; if _it_ calls
  92         # `vim.markPageInteraction()` or not.
  93         vim.markPageInteraction() if vim.isUIEvent(event)
  94     )
  95
  96     @listen('keyup', (event) =>
  97       utils.suppressEvent(event) if @suppress
  98       @setHeldModifiers(event, {filterCurrentOnly: true})
  99     )
 100
 101     handleFocusRelatedEvent = (event) =>
 102       return unless vim = @vimfx.getCurrentVim(@window)
 103
 104       if vim.isUIEvent(event)
 105         focusType = utils.getFocusType(utils.getActiveElement(@window))
 106         vim._setFocusType(focusType)
 107
 108         if focusType == 'editable' and vim.mode == 'caret'
 109           vim.enterMode('normal')
 110
 111     @listen('focus', handleFocusRelatedEvent)
 112     @listen('blur', (event) =>
 113       @window.setTimeout((->
 114         handleFocusRelatedEvent(event)
 115       ), @vimfx.options.blur_timeout)
 116     )
 117
 118     @listen('click', (event) =>
 119       target = event.originalTarget
 120       return unless vim = @vimfx.getCurrentVim(@window)
 121
 122       # In multi-process, clicks simulated by VimFx cannot be caught here. In
 123       # non-multi-process, they unfortunately can. This hack should be
 124       # sufficient for that case until non-multi-process is removed from
 125       # Firefox.
 126       isVimFxGeneratedEvent = (
 127         event.layerX == 0 and event.layerY == 0 and
 128         event.movementX == 0 and event.movementY == 0
 129       )
 130
 131       # If the user clicks the reload button or a link when in hints mode, we’re
 132       # going to end up in hints mode without any markers. Or if the user clicks
 133       # a text input, then that input will be focused, but you can’t type in it
 134       # (instead markers will be matched). So if the user clicks anything in
 135       # hints mode it’s better to leave it.
 136       if vim.mode == 'hints' and not isVimFxGeneratedEvent and
 137          # Exclude the VimFx button, though, since clicking it returns to normal
 138          # mode. Otherwise we’d first return to normal mode and then the button
 139          # would open the help dialog.
 140          target != button.getButton(@window)
 141         vim.enterMode('normal')
 142
 143       vim._send('clearHover') unless isVimFxGeneratedEvent
 144     )
 145
 146     @listen('overflow', (event) =>
 147       target = event.originalTarget
 148       return unless vim = @vimfx.getCurrentVim(@window)
 149       if vim._isUIElement(target)
 150         vim._state.scrollableElements.addChecked(target)
 151     )
 152
 153     @listen('underflow', (event) =>
 154       target = event.originalTarget
 155       return unless vim = @vimfx.getCurrentVim(@window)
 156       if vim._isUIElement(target)
 157         vim._state.scrollableElements.deleteChecked(target)
 158     )
 159
 160     @listen('TabSelect', (event) =>
 161       target = event.originalTarget
 162       target.setAttribute('VimFx-visited', 'true')
 163       @vimfx.emit('TabSelect', {event})
 164
 165       return unless vim = @vimfx.getCurrentVim(@window)
 166       vim.hideNotification()
 167     )
 168
 169     @listen('TabClose', (event) =>
 170       browser = @window.gBrowser.getBrowserForTab(event.originalTarget)
 171       return unless vim = @vimfx.vims.get(browser)
 172       # Note: `lastClosedVim` must be stored so that any window can access it.
 173       @vimfx.lastClosedVim = vim
 174     )
 175
 176     messageManager.listen('cachedPageshow', ((data, callback, browser) =>
 177       [oldVim, @vimfx.lastClosedVim] = [@vimfx.lastClosedVim, null]
 178       unless oldVim
 179         callback(false)
 180         return
 181
 182       if @vimfx.vims.has(browser)
 183         vim = @vimfx.vims.get(browser)
 184         if vim._messageManager == vim.browser.messageManager
 185           callback(false)
 186           return
 187
 188       # If we get here, it means that we’ve detected a tab dragged from one
 189       # window to another. If so, the `vim` object from the last closed tab (the
 190       # moved tab) should be re-used. See the commit message for commit bb70257d
 191       # for more details.
 192       oldVim._setBrowser(browser)
 193       @vimfx.vims.set(browser, oldVim)
 194       @vimfx.emit('modeChange', {vim: oldVim})
 195       callback(true)
 196     ), {messageManager: @window.messageManager})
 197
 198   consumeKeyEvent: (vim, event) ->
 199     match = vim._consumeKeyEvent(event)
 200
 201     if match
 202       if @vimfx.options.notify_entered_keys
 203         if match.type in ['none', 'full'] or match.likelyConflict
 204           @enteredKeys.clear(vim)
 205         else
 206           @enteredKeys.push(vim, match.keyStr, @vimfx.options.timeout)
 207       else
 208         vim.hideNotification()
 209
 210       if match.specialKeys['<late>']
 211         @suppress = false
 212         @consumeLateKeydown(vim, event, match)
 213       else
 214         @suppress = vim._onInput(match, event)
 215     else
 216       @suppress = null
 217     @setHeldModifiers(event)
 218
 219   consumeLateKeydown: (vim, event, match) ->
 220     @late = true
 221
 222     # The passed in `event` is the regular non-late browser UI keydown event.
 223     # It is only used to set held keys. This is easier than sending an event
 224     # subset from frame scripts.
 225     listener = ({defaultPrevented}) =>
 226       # `@late` is reset on every keydown. If it is no longer `true`, it means
 227       # that the page called `event.stopPropagation()`, which prevented this
 228       # listener from running for that event.
 229       return unless @late
 230       @suppress =
 231         if defaultPrevented
 232           false
 233         else
 234           vim._onInput(match, event)
 235       @setHeldModifiers(event)
 236       return @suppress
 237
 238     if vim.isUIEvent(event)
 239       @listenOnce('keydown', ((lateEvent) =>
 240         listener(lateEvent)
 241         if @suppress
 242           utils.suppressEvent(lateEvent)
 243           @listenOnce('keyup', utils.suppressEvent, false)
 244       ), false)
 245     else
 246       # Hack to avoid synchronous messages on every keydown (see
 247       # events-frame.coffee).
 248       prefs.set('late', true)
 249       vim._listenOnce('lateKeydown', listener)
 250
 251   setHeldModifiers: (event, {filterCurrentOnly = false} = {}) ->
 252     mainWindow = @window.document.documentElement
 253     modifiers =
 254       if filterCurrentOnly
 255         mainWindow.getAttribute(HELD_MODIFIERS_ATTRIBUTE)
 256       else
 257         if @suppress == null then 'alt ctrl meta shift' else ''
 258     isHeld = (modifier) -> event["#{modifier}Key"]
 259     mainWindow.setAttribute(
 260       HELD_MODIFIERS_ATTRIBUTE, modifiers.split(' ').filter(isHeld).join(' ')
 261     )
 262
 263   anyPopupsOpen: ->
 264     # The autocomplete popup in text inputs (for example) is technically a
 265     # panel, but it does not respond to key presses. Therefore
 266     # `[ignorekeys="true"]` is excluded.
 267     #
 268     # coffeelint: disable=max_line_length
 269     # <https://developer.mozilla.org/en-US/docs/Mozilla/Tech/XUL/PopupGuide/PopupKeys#Ignoring_Keys>
 270     # coffeelint: enable=max_line_length
 271     popups = utils.querySelectorAllDeep(
 272       @window, ':-moz-any(menupopup, panel):not([ignorekeys="true"])'
 273     )
 274     for popup in popups
 275       return true if popup.state == 'open'
 276     return false
 277
 278 class EnteredKeysManager
 279   constructor: (@window) ->
 280     @keys = []
 281     @timeout = null
 282
 283   clear: (notifier) ->
 284     @keys = []
 285     @clearTimeout()
 286     notifier.hideNotification()
 287
 288   push: (notifier, keyStr, duration) ->
 289     @keys.push(keyStr)
 290     @clearTimeout()
 291     notifier.notify(@keys.join(''))
 292     clear = @clear.bind(this)
 293     @timeout = @window.setTimeout((-> clear(notifier)), duration)
 294
 295   clearTimeout: ->
 296     @window.clearTimeout(@timeout) if @timeout?
 297     @timeout = null
 298
 299 module.exports = UIEventManager