extension/lib/main-frame.coffee

   1 ###
   2 # Copyright Simon Lydell 2015.
   3 #
   4 # This file is part of VimFx.
   5 #
   6 # VimFx is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # VimFx is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  18 ###
  19
  20 # This file is the equivalent of main.coffee, but for frame scripts.
  21
  22 commands = require('./commands-frame')
  23 config = require('./config')
  24 createConfigAPI = require('./api-frame')
  25 FrameEventManager = require('./events-frame')
  26 messageManager = require('./message-manager')
  27 prefs = require('./prefs')
  28 VimFrame = require('./vim-frame')
  29 test = try require('../test/index')
  30
  31 module.exports = ->
  32   {content} = FRAME_SCRIPT_ENVIRONMENT
  33   vim = new VimFrame(content)
  34
  35   eventManager = new FrameEventManager(vim)
  36   eventManager.addListeners()
  37   eventManager.sendFocusType({ignore: ['none']})
  38
  39   messageManager.listen('runCommand', ({name, data}, callback) ->
  40     result = commands[name](Object.assign({vim}, data))
  41     callback?(result)
  42   )
  43
  44   shutdownHandlers = []
  45   onShutdown = (fn) -> shutdownHandlers.push(fn)
  46
  47   loadConfig = ->
  48     configDir = prefs.get('config_file_directory')
  49     scope = {vimfx: createConfigAPI(vim, onShutdown)}
  50     error = config.loadFile(configDir, 'frame.js', scope)
  51     return error
  52
  53   # main.coffee cannot know when the 'loadConfig' listener below is ready, so
  54   # run `loadConfig` manually on startup.
  55   loadConfig()
  56
  57   messageManager.listen('loadConfig', (data, callback) ->
  58     error = loadConfig()
  59     callback(not error)
  60   )
  61
  62   messageManager.listen('unloadConfig', ->
  63     for shutdownHandler in shutdownHandlers
  64       try
  65         shutdownHandler()
  66       catch error
  67         console.error("VimFx: `vimfx.on('shutdown')` error in frame.js", error)
  68     shutdownHandlers = []
  69   )
  70
  71   if test
  72     messageManager.send('runTests', null, (ok) -> test(vim) if ok)