extension/lib/utils.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014.
   4 # Copyright Wang Zhuochun 2013.
   5 #
   6 # This file is part of VimFx.
   7 #
   8 # VimFx is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # VimFx is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  20 ###
  21
  22 notation = require('vim-like-key-notation')
  23 { getPref
  24 , setPref
  25 } = require('./prefs')
  26
  27 ADDON_ID = 'VimFx@akhodakivskiy.github.com'
  28
  29 { classes: Cc, interfaces: Ci, utils: Cu } = Components
  30
  31 Window              = Ci.nsIDOMWindow
  32 ChromeWindow        = Ci.nsIDOMChromeWindow
  33 Element             = Ci.nsIDOMElement
  34 HTMLDocument        = Ci.nsIDOMHTMLDocument
  35 HTMLAnchorElement   = Ci.nsIDOMHTMLAnchorElement
  36 HTMLButtonElement   = Ci.nsIDOMHTMLButtonElement
  37 HTMLInputElement    = Ci.nsIDOMHTMLInputElement
  38 HTMLTextAreaElement = Ci.nsIDOMHTMLTextAreaElement
  39 HTMLSelectElement   = Ci.nsIDOMHTMLSelectElement
  40 XULDocument         = Ci.nsIDOMXULDocument
  41 XULButtonElement    = Ci.nsIDOMXULButtonElement
  42 XULControlElement   = Ci.nsIDOMXULControlElement
  43 XULMenuListElement  = Ci.nsIDOMXULMenuListElement
  44 XULTextBoxElement   = Ci.nsIDOMXULTextBoxElement
  45
  46 class Bucket
  47   constructor: (@newFunc) ->
  48     @bucket = new WeakMap()
  49
  50   get: (obj) ->
  51     if @bucket.has(obj)
  52       return @bucket.get(obj)
  53     else
  54       value = @newFunc(obj)
  55       @bucket.set(obj, value)
  56       return value
  57
  58   forget: (obj) ->
  59     @bucket.delete(obj)
  60
  61 getEventWindow = (event) ->
  62   if event.originalTarget instanceof Window
  63     return event.originalTarget
  64   else
  65     doc = event.originalTarget.ownerDocument or event.originalTarget
  66     if doc instanceof HTMLDocument or doc instanceof XULDocument
  67       return doc.defaultView
  68
  69 getEventRootWindow = (event) ->
  70   return unless window = getEventWindow(event)
  71   return getRootWindow(window)
  72
  73 getEventCurrentTabWindow = (event) ->
  74   return unless rootWindow = getEventRootWindow(event)
  75   return getCurrentTabWindow(rootWindow)
  76
  77 getRootWindow = (window) ->
  78   return window
  79     .QueryInterface(Ci.nsIInterfaceRequestor)
  80     .getInterface(Ci.nsIWebNavigation)
  81     .QueryInterface(Ci.nsIDocShellTreeItem)
  82     .rootTreeItem
  83     .QueryInterface(Ci.nsIInterfaceRequestor)
  84     .getInterface(Window)
  85
  86 getCurrentTabWindow = (window) ->
  87   return window.gBrowser.selectedTab.linkedBrowser.contentWindow
  88
  89 blurActiveElement = (window) ->
  90   # Only blur focusable elements, in order to interfere with the browser as
  91   # little as possible.
  92   { activeElement } = window.document
  93   if activeElement and activeElement.tabIndex > -1
  94     activeElement.blur()
  95
  96 isProperLink = (element) ->
  97   return (element instanceof HTMLAnchorElement or
  98           (element.ownerDocument instanceof XULDocument and
  99            element.hasAttribute('href'))) and
 100          not element.href.endsWith('#') and
 101          not element.href.startsWith('javascript:')
 102
 103 isTextInputElement = (element) ->
 104   return (element instanceof HTMLInputElement and element.type in [
 105            'text', 'search', 'tel', 'url', 'email', 'password', 'number'
 106          ]) or
 107          element instanceof HTMLTextAreaElement or
 108          # `<select>` elements can also receive text input: You may type the
 109          # text of an item to select it.
 110          element instanceof HTMLSelectElement or
 111          element instanceof XULMenuListElement or
 112          element instanceof XULTextBoxElement
 113
 114 isContentEditable = (element) ->
 115   return element.isContentEditable or
 116          isGoogleEditable(element)
 117
 118 isGoogleEditable = (element) ->
 119   # `g_editable` is a non-standard attribute commonly used by Google.
 120   return element.getAttribute?('g_editable') == 'true' or
 121          element.ownerDocument.body?.getAttribute('g_editable') == 'true'
 122
 123 isActivatable = (element) ->
 124   return element instanceof HTMLAnchorElement or
 125          element instanceof HTMLButtonElement or
 126          (element instanceof HTMLInputElement and element.type in [
 127            'button', 'submit', 'reset', 'image'
 128          ]) or
 129          element instanceof XULButtonElement
 130
 131 isAdjustable = (element) ->
 132   return element instanceof HTMLInputElement and element.type in [
 133            'checkbox', 'radio', 'file', 'color'
 134            'date', 'time', 'datetime', 'datetime-local', 'month', 'week'
 135          ] or
 136          element instanceof XULControlElement
 137
 138 area = (element) ->
 139   return element.clientWidth * element.clientHeight
 140
 141 getSessionStore = ->
 142   Cc['@mozilla.org/browser/sessionstore;1'].getService(Ci.nsISessionStore)
 143
 144 loadCss = do ->
 145   sss = Cc['@mozilla.org/content/style-sheet-service;1']
 146     .getService(Ci.nsIStyleSheetService)
 147   return (name) ->
 148     uri = getResourceURI("resources/#{ name }.css")
 149     # `AGENT_SHEET` is used to override userContent.css and Stylish. Custom
 150     # website themes installed by users often make the hint markers unreadable,
 151     # for example. Just using `!important` in the CSS is not enough.
 152     unless sss.sheetRegistered(uri, sss.AGENT_SHEET)
 153       sss.loadAndRegisterSheet(uri, sss.AGENT_SHEET)
 154
 155     module.onShutdown(->
 156       sss.unregisterSheet(uri, sss.AGENT_SHEET)
 157     )
 158
 159 # Store events that we’ve simulated. A `WeakMap` is used in order not to leak
 160 # memory. This approach is better than for example setting `event.simulated =
 161 # true`, since that tells the sites that the click was simulated, and allows
 162 # sites to spoof it.
 163 simulated_events = new WeakMap()
 164
 165 # Simulate mouse click with a full chain of events. ('command' is for XUL
 166 # elements.)
 167 eventSequence = ['mouseover', 'mousedown', 'mouseup', 'click', 'command']
 168 simulateClick = (element) ->
 169   window = element.ownerDocument.defaultView
 170   for type in eventSequence
 171     mouseEvent = new window.MouseEvent(type)
 172     element.dispatchEvent(mouseEvent)
 173
 174 isEventSimulated = (event) ->
 175   return simulated_events.has(event)
 176
 177 WHEEL_MODE_PIXEL = Ci.nsIDOMWheelEvent.DOM_DELTA_PIXEL
 178 WHEEL_MODE_LINE  = Ci.nsIDOMWheelEvent.DOM_DELTA_LINE
 179 WHEEL_MODE_PAGE  = Ci.nsIDOMWheelEvent.DOM_DELTA_PAGE
 180
 181 # Simulate mouse scroll event by specific offsets given that mouse cursor is at
 182 # specified position.
 183 simulateWheel = (window, deltaX, deltaY, mode = WHEEL_MODE_PIXEL) ->
 184   windowUtils = window
 185     .QueryInterface(Ci.nsIInterfaceRequestor)
 186     .getInterface(Ci.nsIDOMWindowUtils)
 187
 188   [pX, pY] = [window.innerWidth / 2, window.innerHeight / 2]
 189   windowUtils.sendWheelEvent(
 190     pX, pY,             # Window offset (x, y) in pixels.
 191     deltaX, deltaY, 0,  # Deltas (x, y, z).
 192     mode,               # Mode (pixel, line, page).
 193     0,                  # Key Modifiers.
 194     0, 0,               # Line or Page deltas (x, y).
 195     0                   # Options.
 196   )
 197
 198 # Write a string to the system clipboard.
 199 writeToClipboard = (text) ->
 200   clipboardHelper = Cc['@mozilla.org/widget/clipboardhelper;1']
 201     .getService(Ci.nsIClipboardHelper)
 202   clipboardHelper.copyString(text)
 203
 204 # Executes function `func` and mearues how much time it took.
 205 timeIt = (func, name) ->
 206   console.time(name)
 207   result = func()
 208   console.timeEnd(name)
 209   return result
 210
 211 isBlacklisted = (str) ->
 212   matchingRules = getMatchingBlacklistRules(str)
 213   return (matchingRules.length != 0)
 214
 215 # Returns all blacklisted keys in matching rules.
 216 getBlacklistedKeys = (str) ->
 217   matchingRules = getMatchingBlacklistRules(str)
 218   blacklistedKeys = []
 219   for rule in matchingRules when /##/.test(rule)
 220     blacklistedKeys.push(x) for x in rule.split('##')[1].split('#')
 221   return blacklistedKeys
 222
 223 # Returns all rules in the blacklist that match the provided string.
 224 getMatchingBlacklistRules = (str) ->
 225   return getBlacklist().filter((rule) ->
 226     /// ^#{ simpleWildcards(rule.split('##')[0]) }$ ///i.test(str)
 227   )
 228
 229 getBlacklist = ->
 230   return splitListString(getPref('black_list'))
 231
 232 setBlacklist = (blacklist) ->
 233   setPref('black_list', blacklist.join(','))
 234
 235 updateBlacklist = ({ add, remove } = {}) ->
 236   blacklist = getBlacklist()
 237
 238   if add
 239     blacklist.push(splitListString(add)...)
 240
 241   blacklist = blacklist.filter((rule) -> rule != '')
 242   blacklist = removeDuplicates(blacklist)
 243
 244   if remove
 245     for rule in splitListString(remove) when rule in blacklist
 246       blacklist.splice(blacklist.indexOf(rule), 1)
 247
 248   setBlacklist(blacklist)
 249
 250 # Splits a comma/space separated list into an array.
 251 splitListString = (str) ->
 252   return str.split(/\s*,[\s,]*/)
 253
 254 # Prepares a string to be used in a regexp, where "*" matches zero or more
 255 # characters and "!" matches one character.
 256 simpleWildcards = (string) ->
 257   return regexpEscape(string).replace(/\\\*/g, '.*').replace(/!/g, '.')
 258
 259 # Returns the first element that matches a pattern, favoring earlier patterns.
 260 # The patterns are case insensitive `simpleWildcards`s and must match either in
 261 # the beginning or at the end of a string. Moreover, a pattern does not match
 262 # in the middle of words, so "previous" does not match "previously". If that is
 263 # desired, a pattern such as "previous*" can be used instead. Note: We cannot
 264 # use `\b` word boundaries, because they don’t work well with non-English
 265 # characters. Instead we match a space as word boundary. Therefore we normalize
 266 # the whitespace and add spaces at the edges of the element text.
 267 getBestPatternMatch = (patterns, attrs, elements) ->
 268   regexps = []
 269   for pattern in patterns
 270     wildcarded = simpleWildcards(pattern)
 271     regexps.push(/// ^\s(?:#{ wildcarded })\s | \s(?:#{ wildcarded })\s$ ///i)
 272
 273   # Helper function that matches a string against all the patterns.
 274   matches = (text) ->
 275     normalizedText = " #{ text } ".replace(/\s+/g, ' ')
 276     for re in regexps
 277       if re.test(normalizedText)
 278         return true
 279     return false
 280
 281   # First search in attributes (favoring earlier attributes) as it's likely
 282   # that they are more specific than text contexts.
 283   for attr in attrs
 284     for element in elements
 285       if matches(element.getAttribute(attr))
 286         return element
 287
 288   # Then search in element contents.
 289   for element in elements
 290     if matches(element.textContent)
 291       return element
 292
 293   return null
 294
 295 # Get VimFx verion. AddonManager only provides async API to access addon data,
 296 # so it's a bit tricky...
 297 getVersion = do ->
 298   version = null
 299
 300   scope = {}
 301   Cu.import('resource://gre/modules/AddonManager.jsm', scope)
 302   scope.AddonManager.getAddonByID(ADDON_ID, (addon) -> version = addon.version)
 303
 304   return ->
 305     return version
 306
 307 parseHTML = (document, html) ->
 308   parser = Cc['@mozilla.org/parserutils;1'].getService(Ci.nsIParserUtils)
 309   flags = parser.SanitizerAllowStyle
 310   return parser.parseFragment(html, flags, false, null,
 311                               document.documentElement)
 312
 313 escapeHTML = (s) ->
 314   return s
 315     .replace(/&/g, '&amp;')
 316     .replace(/</g, '&lt;')
 317     .replace(/>/g, '&gt;')
 318     .replace(/"/g, '&quot;')
 319     .replace(/'/g, '&apos;')
 320
 321 createElement = (document, type, attributes = {}) ->
 322   element = document.createElement(type)
 323
 324   for attribute, value of attributes
 325     element.setAttribute(attribute, value)
 326
 327   if document instanceof HTMLDocument
 328     element.classList.add('VimFxReset')
 329
 330   return element
 331
 332 getAllElements = (document) -> switch
 333   when document instanceof HTMLDocument
 334     return document.getElementsByTagName('*')
 335   when document instanceof XULDocument
 336     elements = []
 337     getAllRegular = (element) ->
 338       for child in element.getElementsByTagName('*')
 339         elements.push(child)
 340         getAllAnonymous(child)
 341       return
 342     getAllAnonymous = (element) ->
 343       for child in document.getAnonymousNodes(element) or []
 344         continue unless child instanceof Element
 345         elements.push(child)
 346         getAllRegular(child)
 347       return
 348     getAllRegular(document.documentElement)
 349     return elements
 350
 351 isURL = (str) ->
 352   try
 353     url = Cc['@mozilla.org/network/io-service;1']
 354       .getService(Ci.nsIIOService)
 355       .newURI(str, null, null)
 356       .QueryInterface(Ci.nsIURL)
 357     return true
 358   catch err
 359     return false
 360
 361 # Use Firefox services to search for a given string.
 362 browserSearchSubmission = (str) ->
 363   ss = Cc['@mozilla.org/browser/search-service;1']
 364     .getService(Ci.nsIBrowserSearchService)
 365
 366   engine = ss.currentEngine or ss.defaultEngine
 367   return engine.getSubmission(str, null)
 368
 369 normalizedKey = (key) -> key.map(notation.normalize).join('')
 370
 371 # Get hint characters, convert them to lower case, and filter duplicates.
 372 getHintChars = ->
 373   hintChars = getPref('hint_chars')
 374   # Make sure that hint chars contain at least two characters.
 375   if not hintChars or hintChars.length < 2
 376     hintChars = 'fj'
 377
 378   return removeDuplicateCharacters(hintChars)
 379
 380 # Remove duplicate characters from string (case insensitive).
 381 removeDuplicateCharacters = (str) ->
 382   return removeDuplicates( str.toLowerCase().split('') ).join('')
 383
 384 # Return URI to some file in the extension packaged as resource.
 385 getResourceURI = do ->
 386   baseURI = Services.io.newURI(__SCRIPT_URI_SPEC__, null, null)
 387   return (path) -> return Services.io.newURI(path, null, baseURI)
 388
 389 # Escape a string to render it usable in regular expressions.
 390 regexpEscape = (s) -> s and s.replace(/[-\/\\^$*+?.()|[\]{}]/g, '\\$&')
 391
 392 removeDuplicates = (array) ->
 393   # coffeelint: disable=no_backticks
 394   return `[...new Set(array)]`
 395   # coffeelint: enable=no_backticks
 396
 397 exports.Bucket                    = Bucket
 398 exports.getEventWindow            = getEventWindow
 399 exports.getEventRootWindow        = getEventRootWindow
 400 exports.getEventCurrentTabWindow  = getEventCurrentTabWindow
 401 exports.getRootWindow             = getRootWindow
 402 exports.getCurrentTabWindow       = getCurrentTabWindow
 403
 404 exports.blurActiveElement         = blurActiveElement
 405 exports.isProperLink              = isProperLink
 406 exports.isTextInputElement        = isTextInputElement
 407 exports.isContentEditable         = isContentEditable
 408 exports.isActivatable             = isActivatable
 409 exports.isAdjustable              = isAdjustable
 410 exports.area                      = area
 411 exports.getSessionStore           = getSessionStore
 412
 413 exports.loadCss                   = loadCss
 414
 415 exports.simulateClick             = simulateClick
 416 exports.isEventSimulated          = isEventSimulated
 417 exports.simulateWheel             = simulateWheel
 418 exports.WHEEL_MODE_PIXEL          = WHEEL_MODE_PIXEL
 419 exports.WHEEL_MODE_LINE           = WHEEL_MODE_LINE
 420 exports.WHEEL_MODE_PAGE           = WHEEL_MODE_PAGE
 421 exports.writeToClipboard          = writeToClipboard
 422 exports.timeIt                    = timeIt
 423
 424 exports.getMatchingBlacklistRules = getMatchingBlacklistRules
 425 exports.isBlacklisted             = isBlacklisted
 426 exports.getBlacklistedKeys        = getBlacklistedKeys
 427 exports.updateBlacklist           = updateBlacklist
 428 exports.splitListString           = splitListString
 429 exports.getBestPatternMatch       = getBestPatternMatch
 430
 431 exports.getVersion                = getVersion
 432 exports.parseHTML                 = parseHTML
 433 exports.escapeHTML                = escapeHTML
 434 exports.createElement             = createElement
 435 exports.getAllElements            = getAllElements
 436 exports.isURL                     = isURL
 437 exports.browserSearchSubmission   = browserSearchSubmission
 438 exports.normalizedKey             = normalizedKey
 439 exports.getHintChars              = getHintChars
 440 exports.removeDuplicates          = removeDuplicates
 441 exports.removeDuplicateCharacters = removeDuplicateCharacters
 442 exports.getResourceURI            = getResourceURI
 443 exports.ADDON_ID                  = ADDON_ID