extension/lib/commands.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 # Copyright Wang Zhuochun 2013, 2014.
   5 #
   6 # This file is part of VimFx.
   7 #
   8 # VimFx is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # VimFx is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  20 ###
  21
  22 # This file defines all Normal mode commands. Commands that need to interact
  23 # with web page content do so by running `vim._run(name)`, which invokes `name`
  24 # in commands-frame.coffee.
  25
  26 # NOTE: Most tab related commands need to do their actual tab manipulations in
  27 # the next tick (`utils.nextTick`) to work around bug 1200334.
  28
  29 config    = require('./config')
  30 help      = require('./help')
  31 hints     = require('./hints')
  32 prefs     = require('./prefs')
  33 translate = require('./l10n')
  34 utils     = require('./utils')
  35
  36 commands = {}
  37
  38
  39
  40 commands.focus_location_bar = ({vim}) ->
  41   vim.window.focusAndSelectUrlBar()
  42
  43 commands.focus_search_bar = ({vim, count}) ->
  44   # The `.webSearch()` method opens a search engine in a tab if the search bar
  45   # has been removed. Therefore we first check if it exists.
  46   if vim.window.BrowserSearch.searchBar
  47     vim.window.BrowserSearch.webSearch()
  48
  49 helper_paste_and_go = (props, {vim}) ->
  50   {gURLBar} = vim.window
  51   gURLBar.value = vim.window.readFromClipboard()
  52   gURLBar.handleCommand(new vim.window.KeyboardEvent('keydown', props))
  53
  54 commands.paste_and_go = helper_paste_and_go.bind(null, null)
  55
  56 commands.paste_and_go_in_tab = helper_paste_and_go.bind(null, {altKey: true})
  57
  58 commands.copy_current_url = ({vim}) ->
  59   utils.writeToClipboard(vim.window.gBrowser.currentURI.spec)
  60   vim.notify(translate('notification.copy_current_url'))
  61
  62 commands.go_up_path = ({vim, count}) ->
  63   vim._run('go_up_path', {count})
  64
  65 commands.go_to_root = ({vim}) ->
  66   vim._run('go_to_root')
  67
  68 commands.go_home = ({vim}) ->
  69   vim.window.BrowserHome()
  70
  71 helper_go_history = (direction, {vim, count = 1}) ->
  72   {window} = vim
  73   {SessionStore, gBrowser} = window
  74
  75   if (direction == 'back'    and not gBrowser.canGoBack) or
  76      (direction == 'forward' and not gBrowser.canGoForward)
  77     vim.notify(translate("notification.history_#{direction}.limit"))
  78     return
  79
  80   # `SessionStore.getSessionHistory()` (used below to support counts) starts
  81   # lots of asynchronous tasks internally, which is a bit unreliable, it has
  82   # turned out. The primary use of the `history_back` and `history_forward`
  83   # commands is to go _one_ step back or forward, though, so those cases are
  84   # optimized to use more reliable ways of going back and forward. Also, some
  85   # extensions override the following functions, so calling them also gives
  86   # better interoperability.
  87   if count == 1
  88     if direction == 'back'
  89       window.BrowserBack()
  90     else
  91       window.BrowserForward()
  92     return
  93
  94   SessionStore.getSessionHistory(gBrowser.selectedTab, (sessionHistory) ->
  95     {index} = sessionHistory
  96     newIndex = index + count * (if direction == 'back' then -1 else 1)
  97     newIndex = Math.max(newIndex, 0)
  98     newIndex = Math.min(newIndex, sessionHistory.entries.length - 1)
  99     gBrowser.gotoIndex(newIndex)
 100   )
 101
 102 commands.history_back    = helper_go_history.bind(null, 'back')
 103
 104 commands.history_forward = helper_go_history.bind(null, 'forward')
 105
 106 commands.history_list = ({vim}) ->
 107   menu = vim.window.document.getElementById('backForwardMenu')
 108   utils.openPopup(menu)
 109   if menu.childElementCount == 0
 110     vim.notify(translate('notification.history_list.none'))
 111
 112 commands.reload = ({vim}) ->
 113   vim.window.BrowserReload()
 114
 115 commands.reload_force = ({vim}) ->
 116   vim.window.BrowserReloadSkipCache()
 117
 118 commands.reload_all = ({vim}) ->
 119   vim.window.gBrowser.reloadAllTabs()
 120
 121 commands.reload_all_force = ({vim}) ->
 122   for tab in vim.window.gBrowser.visibleTabs
 123     gBrowser = tab.linkedBrowser
 124     consts = gBrowser.webNavigation
 125     flags = consts.LOAD_FLAGS_BYPASS_PROXY | consts.LOAD_FLAGS_BYPASS_CACHE
 126     gBrowser.reload(flags)
 127   return
 128
 129 commands.stop = ({vim}) ->
 130   vim.window.BrowserStop()
 131
 132 commands.stop_all = ({vim}) ->
 133   for tab in vim.window.gBrowser.visibleTabs
 134     tab.linkedBrowser.stop()
 135   return
 136
 137
 138
 139 helper_scroll = (vim, uiEvent, args...) ->
 140   [
 141     method, type, directions, amounts
 142     properties = null, adjustment = 0, name = 'scroll'
 143   ] = args
 144   options = {
 145     method, type, directions, amounts, properties, adjustment
 146     smooth: (prefs.root.get('general.smoothScroll') and
 147              prefs.root.get("general.smoothScroll.#{type}"))
 148   }
 149   reset = prefs.root.tmp(
 150     'layout.css.scroll-behavior.spring-constant',
 151     vim.options["smoothScroll.#{type}.spring-constant"]
 152   )
 153
 154   helpScroll = help.getHelp(vim.window)?.querySelector('.wrapper')
 155   if uiEvent or helpScroll
 156     activeElement = helpScroll or utils.getActiveElement(vim.window)
 157     if vim._state.scrollableElements.has(activeElement) or helpScroll
 158       utils.scroll(activeElement, options)
 159       reset()
 160       return
 161
 162   vim._run(name, options, reset)
 163
 164
 165 helper_scrollByLinesX = (amount, {vim, uiEvent, count = 1}) ->
 166   distance = prefs.root.get('toolkit.scrollbox.horizontalScrollDistance')
 167   helper_scroll(vim, uiEvent, 'scrollBy', 'lines', ['left'],
 168                 [amount * distance * count * 5])
 169
 170 helper_scrollByLinesY = (amount, {vim, uiEvent, count = 1}) ->
 171   distance = prefs.root.get('toolkit.scrollbox.verticalScrollDistance')
 172   helper_scroll(vim, uiEvent, 'scrollBy', 'lines', ['top'],
 173                 [amount * distance * count * 20])
 174
 175 helper_scrollByPagesY = (amount, type, {vim, uiEvent, count = 1}) ->
 176   adjustment = prefs.get("scroll.#{type}_page_adjustment")
 177   helper_scroll(vim, uiEvent, 'scrollBy', 'pages', ['top'],
 178                 [amount * count], ['clientHeight'], adjustment)
 179
 180 helper_scrollToX = (amount, {vim, uiEvent}) ->
 181   helper_scroll(vim, uiEvent, 'scrollTo', 'other', ['left'],
 182                 [amount], ['scrollLeftMax'])
 183   helper_mark_last_scroll_position(vim)
 184
 185 helper_scrollToY = (amount, {vim, uiEvent}) ->
 186   helper_scroll(vim, uiEvent, 'scrollTo', 'other', ['top'],
 187                 [amount], ['scrollTopMax'])
 188   helper_mark_last_scroll_position(vim)
 189
 190 commands.scroll_left           = helper_scrollByLinesX.bind(null, -1)
 191 commands.scroll_right          = helper_scrollByLinesX.bind(null, +1)
 192 commands.scroll_down           = helper_scrollByLinesY.bind(null, +1)
 193 commands.scroll_up             = helper_scrollByLinesY.bind(null, -1)
 194 commands.scroll_page_down      = helper_scrollByPagesY.bind(null, +1,   'full')
 195 commands.scroll_page_up        = helper_scrollByPagesY.bind(null, -1,   'full')
 196 commands.scroll_half_page_down = helper_scrollByPagesY.bind(null, +0.5, 'half')
 197 commands.scroll_half_page_up   = helper_scrollByPagesY.bind(null, -0.5, 'half')
 198 commands.scroll_to_top         = helper_scrollToY.bind(null, 0)
 199 commands.scroll_to_bottom      = helper_scrollToY.bind(null, Infinity)
 200 commands.scroll_to_left        = helper_scrollToX.bind(null, 0)
 201 commands.scroll_to_right       = helper_scrollToX.bind(null, Infinity)
 202
 203 helper_mark_last_scroll_position = (vim) ->
 204   keyStr = vim.options['scroll.last_position_mark']
 205   vim._run('mark_scroll_position', {keyStr, notify: false})
 206
 207 commands.mark_scroll_position = ({vim}) ->
 208   vim.enterMode('marks', (keyStr) -> vim._run('mark_scroll_position', {keyStr}))
 209
 210 commands.scroll_to_mark = ({vim}) ->
 211   vim.enterMode('marks', (keyStr) ->
 212     unless keyStr == vim.options['scroll.last_position_mark']
 213       helper_mark_last_scroll_position(vim)
 214     helper_scroll(vim, null, 'scrollTo', 'other', ['top', 'left'], keyStr,
 215                   ['scrollTopMax', 'scrollLeftMax'], 0, 'scroll_to_mark')
 216   )
 217
 218
 219
 220 commands.tab_new = ({vim}) ->
 221   utils.nextTick(vim.window, ->
 222     vim.window.BrowserOpenTab()
 223   )
 224
 225 commands.tab_duplicate = ({vim}) ->
 226   {gBrowser} = vim.window
 227   utils.nextTick(vim.window, ->
 228     gBrowser.duplicateTab(gBrowser.selectedTab)
 229   )
 230
 231 absoluteTabIndex = (relativeIndex, gBrowser, {pinnedSeparate}) ->
 232   tabs = gBrowser.visibleTabs
 233   {selectedTab} = gBrowser
 234
 235   currentIndex  = tabs.indexOf(selectedTab)
 236   absoluteIndex = currentIndex + relativeIndex
 237   numTabsTotal  = tabs.length
 238   numPinnedTabs = gBrowser._numPinnedTabs
 239
 240   [numTabs, min] = switch
 241     when not pinnedSeparate  then [numTabsTotal,  0]
 242     when selectedTab.pinned  then [numPinnedTabs, 0]
 243     else [numTabsTotal - numPinnedTabs, numPinnedTabs]
 244
 245   # Wrap _once_ if at one of the ends of the tab bar and cannot move in the
 246   # current direction.
 247   if (relativeIndex < 0 and currentIndex == min) or
 248      (relativeIndex > 0 and currentIndex == min + numTabs - 1)
 249     if absoluteIndex < min
 250       absoluteIndex += numTabs
 251     else if absoluteIndex >= min + numTabs
 252       absoluteIndex -= numTabs
 253
 254   absoluteIndex = Math.max(min, absoluteIndex)
 255   absoluteIndex = Math.min(absoluteIndex, min + numTabs - 1)
 256
 257   return absoluteIndex
 258
 259 helper_switch_tab = (direction, {vim, count = 1}) ->
 260   {gBrowser} = vim.window
 261   index = absoluteTabIndex(direction * count, gBrowser, {pinnedSeparate: false})
 262   utils.nextTick(vim.window, ->
 263     gBrowser.selectTabAtIndex(index)
 264   )
 265
 266 commands.tab_select_previous = helper_switch_tab.bind(null, -1)
 267
 268 commands.tab_select_next     = helper_switch_tab.bind(null, +1)
 269
 270 commands.tab_select_most_recent = ({vim, count = 1}) ->
 271   {gBrowser} = vim.window
 272   tabsSorted = Array.filter(gBrowser.tabs, (tab) -> not tab.closing)
 273     .sort((a, b) -> b.lastAccessed - a.lastAccessed)
 274   mostRecentTab = tabsSorted[Math.min(count, tabsSorted.length - 1)]
 275   gBrowser.selectedTab = mostRecentTab if mostRecentTab
 276
 277 helper_move_tab = (direction, {vim, count = 1}) ->
 278   {gBrowser} = vim.window
 279   index = absoluteTabIndex(direction * count, gBrowser, {pinnedSeparate: true})
 280   utils.nextTick(vim.window, ->
 281     gBrowser.moveTabTo(gBrowser.selectedTab, index)
 282   )
 283
 284 commands.tab_move_backward = helper_move_tab.bind(null, -1)
 285
 286 commands.tab_move_forward  = helper_move_tab.bind(null, +1)
 287
 288 commands.tab_move_to_window = ({vim}) ->
 289   {gBrowser} = vim.window
 290   gBrowser.replaceTabWithWindow(gBrowser.selectedTab)
 291
 292 commands.tab_select_first = ({vim, count = 1}) ->
 293   utils.nextTick(vim.window, ->
 294     vim.window.gBrowser.selectTabAtIndex(count - 1)
 295   )
 296
 297 commands.tab_select_first_non_pinned = ({vim, count = 1}) ->
 298   firstNonPinned = vim.window.gBrowser._numPinnedTabs
 299   utils.nextTick(vim.window, ->
 300     vim.window.gBrowser.selectTabAtIndex(firstNonPinned + count - 1)
 301   )
 302
 303 commands.tab_select_last = ({vim, count = 1}) ->
 304   utils.nextTick(vim.window, ->
 305     vim.window.gBrowser.selectTabAtIndex(-count)
 306   )
 307
 308 commands.tab_toggle_pinned = ({vim}) ->
 309   currentTab = vim.window.gBrowser.selectedTab
 310   if currentTab.pinned
 311     vim.window.gBrowser.unpinTab(currentTab)
 312   else
 313     vim.window.gBrowser.pinTab(currentTab)
 314
 315 commands.tab_close = ({vim, count = 1}) ->
 316   {gBrowser} = vim.window
 317   return if gBrowser.selectedTab.pinned
 318   currentIndex = gBrowser.visibleTabs.indexOf(gBrowser.selectedTab)
 319   utils.nextTick(vim.window, ->
 320     for tab in gBrowser.visibleTabs[currentIndex...(currentIndex + count)]
 321       gBrowser.removeTab(tab)
 322     return
 323   )
 324
 325 commands.tab_restore = ({vim, count = 1}) ->
 326   utils.nextTick(vim.window, ->
 327     for index in [0...count] by 1
 328       restoredTab = vim.window.undoCloseTab()
 329       if not restoredTab and index == 0
 330         vim.notify(translate('notification.tab_restore.none'))
 331         break
 332     return
 333   )
 334
 335 commands.tab_restore_list = ({vim}) ->
 336   {window} = vim
 337   fragment = window.RecentlyClosedTabsAndWindowsMenuUtils.getTabsFragment(
 338     window, 'menuitem'
 339   )
 340   if fragment.childElementCount == 0
 341     vim.notify(translate('notification.tab_restore.none'))
 342   else
 343     utils.openPopup(utils.injectTemporaryPopup(window.document, fragment))
 344
 345 commands.tab_close_to_end = ({vim}) ->
 346   {gBrowser} = vim.window
 347   gBrowser.removeTabsToTheEndFrom(gBrowser.selectedTab)
 348
 349 commands.tab_close_other = ({vim}) ->
 350   {gBrowser} = vim.window
 351   gBrowser.removeAllTabsBut(gBrowser.selectedTab)
 352
 353
 354
 355 helper_follow = (name, vim, callback, count = null) ->
 356   vim.markPageInteraction()
 357   help.removeHelp(vim.window)
 358
 359   # Enter hints mode immediately, with an empty set of markers. The user might
 360   # press keys before the `vim._run` callback is invoked. Those key presses
 361   # should be handled in hints mode, not normal mode.
 362   initialMarkers = []
 363   storage = vim.enterMode('hints', initialMarkers, callback, count,
 364                           vim.options.hints_sleep)
 365
 366   vim._run(name, null, ({wrappers, viewport}) ->
 367     # The user might have exited hints mode (and perhaps even entered it again)
 368     # before this callback is invoked. If so, `storage.markers` has been
 369     # cleared, or set to a new value. Only proceed if it is unchanged.
 370     return unless storage.markers == initialMarkers
 371
 372     if wrappers.length > 0
 373       {markers, markerMap} = hints.injectHints(vim.window, wrappers, viewport,
 374                                                vim.options)
 375       storage.markers = markers
 376       storage.markerMap = markerMap
 377     else
 378       vim.notify(translate('notification.follow.none'))
 379       vim.enterMode('normal')
 380   )
 381
 382 helper_follow_clickable = ({inTab, inBackground}, {vim, count = 1}) ->
 383   callback = (marker, timesLeft, keyStr) ->
 384     {type, elementIndex} = marker.wrapper
 385     isLast = (timesLeft == 1)
 386     isLink = (type == 'link')
 387
 388     switch
 389       when keyStr.startsWith(vim.options.hints_toggle_in_tab)
 390         inTab = not inTab
 391       when keyStr.startsWith(vim.options.hints_toggle_in_background)
 392         inTab = true
 393         inBackground = not inBackground
 394       else
 395         unless isLast
 396           inTab = true
 397           inBackground = true
 398
 399     inTab = false unless isLink
 400
 401     if type == 'text' or (isLink and not (inTab and inBackground))
 402       isLast = true
 403
 404     vim._focusMarkerElement(elementIndex)
 405
 406     if inTab
 407       utils.nextTick(vim.window, ->
 408         utils.openTab(vim.window, marker.wrapper.href, {
 409           inBackground
 410           relatedToCurrent: true
 411         })
 412       )
 413     else
 414       vim._run('click_marker_element', {
 415         elementIndex, type
 416         preventTargetBlank: vim.options.prevent_target_blank
 417       })
 418
 419     return not isLast
 420
 421   name = if inTab then 'follow_in_tab' else 'follow'
 422   helper_follow(name, vim, callback, count)
 423
 424 commands.follow =
 425   helper_follow_clickable.bind(null, {inTab: false, inBackground: true})
 426
 427 commands.follow_in_tab =
 428   helper_follow_clickable.bind(null, {inTab: true, inBackground: true})
 429
 430 commands.follow_in_focused_tab =
 431   helper_follow_clickable.bind(null, {inTab: true, inBackground: false})
 432
 433 commands.follow_in_window = ({vim}) ->
 434   callback = (marker) ->
 435     vim._focusMarkerElement(marker.wrapper.elementIndex)
 436     vim.window.openLinkIn(marker.wrapper.href, 'window', {})
 437   helper_follow('follow_in_tab', vim, callback)
 438
 439 commands.follow_multiple = (args) ->
 440   args.count = Infinity
 441   commands.follow(args)
 442
 443 commands.follow_copy = ({vim}) ->
 444   callback = (marker) ->
 445     {elementIndex} = marker.wrapper
 446     property = switch marker.wrapper.type
 447       when 'link'            then 'href'
 448       when 'text'            then 'value'
 449       when 'contenteditable' then 'textContent'
 450     vim._run('copy_marker_element', {elementIndex, property})
 451   helper_follow('follow_copy', vim, callback)
 452
 453 commands.follow_focus = ({vim}) ->
 454   callback = (marker) ->
 455     vim._focusMarkerElement(marker.wrapper.elementIndex, {select: true})
 456   return helper_follow('follow_focus', vim, callback)
 457
 458 commands.click_browser_element = ({vim}) ->
 459   markerElements = []
 460
 461   filter = (element, getElementShape) ->
 462     document = element.ownerDocument
 463     type = switch
 464       when vim._state.scrollableElements.has(element)
 465         'scrollable'
 466       when (element.tabIndex > -1 and
 467             # `.localName` is `.nodeName` without `xul:` (if it exists).
 468             not (element.localName.endsWith('box') and
 469                  element.localName != 'checkbox') and
 470             element.localName not in ['tabs', 'menuitem', 'menuseparator']) or
 471            element.onclick
 472         'clickable'
 473     return unless type
 474     return unless shape = getElementShape(element)
 475     length = markerElements.push(element)
 476     return {type, semantic: true, shape, elementIndex: length - 1}
 477
 478   callback = (marker) ->
 479     element = markerElements[marker.wrapper.elementIndex]
 480     switch marker.wrapper.type
 481       when 'scrollable'
 482         utils.focusElement(element, {flag: 'FLAG_BYKEY'})
 483       when 'clickable'
 484         utils.focusElement(element)
 485         utils.simulateMouseEvents(element, 'click')
 486
 487   {wrappers, viewport} =
 488     hints.getMarkableElementsAndViewport(vim.window, filter)
 489
 490   if wrappers.length > 0
 491     {markers} = hints.injectHints(vim.window, wrappers, viewport, {
 492       hint_chars: vim.options.hint_chars
 493       ui: true
 494     })
 495     vim.enterMode('hints', markers, callback)
 496   else
 497     vim.notify(translate('notification.follow.none'))
 498
 499 helper_follow_pattern = (type, {vim}) ->
 500   options =
 501     pattern_selector: vim.options.pattern_selector
 502     pattern_attrs:    vim.options.pattern_attrs
 503     patterns:         vim.options["#{type}_patterns"]
 504   vim._run('follow_pattern', {type, options})
 505
 506 commands.follow_previous = helper_follow_pattern.bind(null, 'prev')
 507
 508 commands.follow_next     = helper_follow_pattern.bind(null, 'next')
 509
 510 commands.focus_text_input = ({vim, count}) ->
 511   vim.markPageInteraction()
 512   vim._run('focus_text_input', {count})
 513
 514
 515
 516 findStorage = {lastSearchString: ''}
 517
 518 helper_find = ({highlight, linksOnly = false}, {vim}) ->
 519   helpSearchInput = help.getSearchInput(vim.window)
 520   if helpSearchInput
 521     helpSearchInput.select()
 522     return
 523
 524   helper_mark_last_scroll_position(vim)
 525   findBar = vim.window.gBrowser.getFindBar()
 526
 527   mode = if linksOnly then findBar.FIND_LINKS else findBar.FIND_NORMAL
 528   findBar.startFind(mode)
 529   utils.focusElement(findBar._findField, {select: true})
 530
 531   return if linksOnly
 532   return unless highlightButton = findBar.getElement('highlight')
 533   if highlightButton.checked != highlight
 534     highlightButton.click()
 535
 536 commands.find = helper_find.bind(null, {highlight: false})
 537
 538 commands.find_highlight_all = helper_find.bind(null, {highlight: true})
 539
 540 commands.find_links_only = helper_find.bind(null, {linksOnly: true})
 541
 542 helper_find_again = (direction, {vim}) ->
 543   findBar = vim.window.gBrowser.getFindBar()
 544   if findStorage.lastSearchString.length == 0
 545     vim.notify(translate('notification.find_again.none'))
 546     return
 547   helper_mark_last_scroll_position(vim)
 548   findBar._findField.value = findStorage.lastSearchString
 549   findBar.onFindAgainCommand(direction)
 550   message = findBar._findStatusDesc.textContent
 551   vim.notify(message) if message
 552
 553 commands.find_next     = helper_find_again.bind(null, false)
 554
 555 commands.find_previous = helper_find_again.bind(null, true)
 556
 557
 558
 559 commands.window_new = ({vim}) ->
 560   vim.window.OpenBrowserWindow()
 561
 562 commands.window_new_private = ({vim}) ->
 563   vim.window.OpenBrowserWindow({private: true})
 564
 565 commands.enter_mode_ignore = ({vim}) ->
 566   vim.enterMode('ignore')
 567
 568 # Quote next keypress (pass it through to the page).
 569 commands.quote = ({vim, count = 1}) ->
 570   vim.enterMode('ignore', count)
 571
 572 commands.enter_reader_view = ({vim}) ->
 573   button = vim.window.document.getElementById('reader-mode-button')
 574   if not button?.hidden
 575     button.click()
 576   else
 577     vim.notify(translate('notification.enter_reader_view.none'))
 578
 579 commands.reload_config_file = ({vim}) ->
 580   vim._parent.emit('shutdown')
 581   config.load(vim._parent, (status) -> switch status
 582     when null
 583       vim.notify(translate('notification.reload_config_file.none'))
 584     when true
 585       vim.notify(translate('notification.reload_config_file.success'))
 586     else
 587       vim.notify(translate('notification.reload_config_file.failure'))
 588   )
 589
 590 commands.help = ({vim}) ->
 591   help.injectHelp(vim.window, vim._parent)
 592
 593 commands.dev = ({vim}) ->
 594   vim.window.DeveloperToolbar.show(true) # `true` to focus.
 595
 596 commands.esc = ({vim}) ->
 597   vim._run('esc')
 598   utils.blurActiveBrowserElement(vim)
 599   vim.window.DeveloperToolbar.hide()
 600   vim.window.gBrowser.getFindBar().close()
 601   # TODO: Remove when Tab Groups have been removed.
 602   vim.window.TabView?.hide()
 603   hints.removeHints(vim.window) # Better safe than sorry.
 604
 605   unless help.getSearchInput(vim.window)?.getAttribute('focused')
 606     help.removeHelp(vim.window)
 607
 608
 609
 610 module.exports = {
 611   commands
 612   findStorage
 613 }