extension/test/index.coffee

   1 ###
   2 # Copyright Simon Lydell 2014, 2015, 2016.
   3 #
   4 # This file is part of VimFx.
   5 #
   6 # VimFx is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # VimFx is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  18 ###
  19
  20 # This file implements a simple test runner.
  21
  22 utils = require('../lib/utils')
  23
  24 {Assert} = Cu.import('chrome://specialpowers/content/Assert.jsm', {})
  25 assert = new Assert()
  26
  27 list = do -> # @echo TESTS
  28
  29 module.exports = (topLevelObject) ->
  30   report = []
  31   passed = 0
  32   total = 0
  33
  34   for name in list when name.endsWith('-frame') == IS_FRAME_SCRIPT
  35     tests = require("./#{name}")
  36     report.push(name)
  37     for key, fn of tests when key.startsWith('test')
  38       total += 1
  39       error = null
  40       teardowns = []
  41       teardown = (fn) -> teardowns.push(fn)
  42       try
  43         fn(assert, topLevelObject, teardown)
  44         passed += 1
  45       catch error then null
  46       finally
  47         (try fn()) for fn in teardowns
  48       report.push("  #{if error then '✘' else '✔'} #{key}")
  49       report.push(utils.formatError(error).replace(/^/gm, '    ')) if error
  50
  51   type = if IS_FRAME_SCRIPT then 'frame' else 'regular'
  52   report.push("\n#{passed}/#{total} #{type} tests passed.\n")
  53   console.info("\n#{report.join('\n')}")