extension/packages/commands.coffee

   1 utils = require 'utils'
   2 help  = require 'help'
   3 { _ } = require 'l10n'
   4 { getPref
   5 , getComplexPref
   6 , setPref
   7 , isPrefSet
   8 , getFirefoxPref } = require 'prefs'
   9
  10 { classes: Cc, interfaces: Ci, utils: Cu } = Components
  11
  12 # “Selecting an element” means “focusing and selecting the text, if any, of an
  13 # element”.
  14
  15 # Open and select the Developer Toolbar
  16 command_dev = (vim) ->
  17   vim.rootWindow.DeveloperToolbar.show(true)
  18   vim.rootWindow.DeveloperToolbar.focus()
  19
  20 # Select the Address Bar
  21 command_focus = (vim) ->
  22   # This function works even if the Address Bar has been removed.
  23   vim.rootWindow.focusAndSelectUrlBar()
  24
  25 # Select the Search Bar
  26 command_focus_search = (vim) ->
  27   # A `?` is used since the Search Bar might have been removed.
  28   vim.BrowserSearch.searchBar?.select()
  29
  30 helper_paste = (vim) ->
  31   url = utils.readFromClipboard(vim.window)
  32   postData = null
  33   if not utils.isURL(url) and submission = utils.browserSearchSubmission(url)
  34     url = submission.uri.spec
  35     { postData } = submission
  36   return { url, postData }
  37
  38 # Go to or search for the contents of the system clipboard
  39 command_paste = (vim) ->
  40   { url, postData } = helper_paste(vim)
  41   vim.rootWindow.gBrowser.loadURIWithFlags(url, null, null, null, postData)
  42
  43 # Go to or search for the contents of the system clipboard in a new tab
  44 command_paste_tab = (vim) ->
  45   { url, postData } = helper_paste(vim)
  46   vim.rootWindow.gBrowser.selectedTab = vim.rootWindow.gBrowser.addTab(url, null, null, postData, null, false)
  47
  48 # Open a new tab and select the Address Bar
  49 command_open_tab = (vim) ->
  50   vim.rootWindow.BrowserOpenTab()
  51
  52 # Copy the URL or text of a marker element to the system clipboard
  53 command_marker_yank = (vim) ->
  54   callback = (marker) ->
  55     if url = marker.element.href
  56       marker.element.focus()
  57       utils.writeToClipboard(url)
  58     else if utils.isTextInputElement(marker.element)
  59       utils.writeToClipboard(marker.element.value)
  60
  61   vim.enterMode('hints', callback)
  62
  63 # Focus element
  64 command_marker_focus = (vim) ->
  65   callback = (marker) -> marker.element.focus()
  66
  67   vim.enterMode('hints', callback)
  68
  69 # Copy the current URL to the system clipboard
  70 command_yank = (vim) ->
  71   utils.writeToClipboard(vim.window.location.href)
  72
  73 # Reload the current tab, possibly from cache
  74 command_reload = (vim) ->
  75   vim.rootWindow.BrowserReload()
  76
  77 # Reload the current tab, skipping cache
  78 command_reload_force = (vim) ->
  79   vim.rootWindow.BrowserReloadSkipCache()
  80
  81 # Reload all tabs, possibly from cache
  82 command_reload_all = (vim) ->
  83   vim.rootWindow.gBrowser.reloadAllTabs()
  84
  85 # Reload all tabs, skipping cache
  86 command_reload_all_force = (vim) ->
  87   for tab in vim.rootWindow.gBrowser.visibleTabs
  88     window = tab.linkedBrowser.contentWindow
  89     window.location.reload(true)
  90
  91 # Stop loading the current tab
  92 command_stop = (vim) ->
  93   vim.window.stop()
  94
  95 # Stop loading all tabs
  96 command_stop_all = (vim) ->
  97   for tab in vim.rootWindow.gBrowser.visibleTabs
  98     window = tab.linkedBrowser.contentWindow
  99     window.stop()
 100
 101 # Scroll to the top of the page
 102 command_scroll_to_top = (vim) ->
 103   vim.rootWindow.goDoCommand('cmd_scrollTop')
 104
 105 # Scroll to the bottom of the page
 106 command_scroll_to_bottom = (vim) ->
 107   vim.rootWindow.goDoCommand('cmd_scrollBottom')
 108
 109 # Scroll down a bit
 110 command_scroll_down = (vim) ->
 111   utils.simulateWheel(vim.window, 0, getPref('scroll_step_lines'), utils.WHEEL_MODE_LINE)
 112
 113 # Scroll up a bit
 114 command_scroll_up = (vim) ->
 115   utils.simulateWheel(vim.window, 0, -getPref('scroll_step_lines'), utils.WHEEL_MODE_LINE)
 116
 117 # Scroll left a bit
 118 command_scroll_left = (vim) ->
 119   utils.simulateWheel(vim.window, -getPref('scroll_step_lines'), 0, utils.WHEEL_MODE_LINE)
 120
 121 # Scroll right a bit
 122 command_scroll_right = (vim) ->
 123   utils.simulateWheel(vim.window, getPref('scroll_step_lines'), 0, utils.WHEEL_MODE_LINE)
 124
 125 # Scroll down half a page
 126 command_scroll_half_page_down = (vim) ->
 127   utils.simulateWheel(vim.window, 0, 0.5, utils.WHEEL_MODE_PAGE)
 128
 129 # Scroll up half a page
 130 command_scroll_half_page_up = (vim) ->
 131   utils.simulateWheel(vim.window, 0, -0.5, utils.WHEEL_MODE_PAGE)
 132
 133 # Scroll down full a page
 134 command_scroll_page_down = (vim) ->
 135   utils.simulateWheel(vim.window, 0, 1, utils.WHEEL_MODE_PAGE)
 136
 137 # Scroll up full a page
 138 command_scroll_page_up = (vim) ->
 139   utils.simulateWheel(vim.window, 0, -1, utils.WHEEL_MODE_PAGE)
 140
 141 # Switch to the previous tab
 142 command_tab_prev = (vim) ->
 143   vim.rootWindow.gBrowser.tabContainer.advanceSelectedTab(-1, true) # `true` to allow wrapping
 144
 145 # Switch to the next tab
 146 command_tab_next = (vim) ->
 147   vim.rootWindow.gBrowser.tabContainer.advanceSelectedTab(1, true) # `true` to allow wrapping
 148
 149 # Load the home page
 150 command_home = (vim) ->
 151   vim.rootWindow.BrowserHome()
 152
 153 # Switch to the first tab
 154 command_tab_first = (vim) ->
 155   vim.rootWindow.gBrowser.selectTabAtIndex(0)
 156
 157 # Switch to the last tab
 158 command_tab_last = (vim) ->
 159   vim.rootWindow.gBrowser.selectTabAtIndex(-1)
 160
 161 # Go back in history
 162 command_back = (vim) ->
 163   vim.rootWindow.BrowserBack()
 164
 165 # Go forward in history
 166 command_forward = (vim) ->
 167   vim.rootWindow.BrowserForward()
 168
 169 # Close current tab
 170 command_close_tab = (vim) ->
 171   unless vim.rootWindow.gBrowser.selectedTab.pinned
 172     vim.rootWindow.gBrowser.removeCurrentTab()
 173
 174 # Restore last closed tab
 175 command_restore_tab = (vim) ->
 176   vim.rootWindow.undoCloseTab()
 177
 178 helper_follow = ({ inTab, multiple }, vim) ->
 179   callback = (matchedMarker, markers) ->
 180     matchedMarker.element.focus()
 181     utils.simulateClick(matchedMarker.element, {metaKey: inTab, ctrlKey: inTab})
 182     isEditable = utils.isElementEditable(matchedMarker.element)
 183     if multiple and not isEditable
 184       # By not resetting immediately one is able to see the last char being matched, which gives
 185       # some nice visual feedback that you've typed the right char.
 186       vim.window.setTimeout((-> marker.reset() for marker in markers), 100)
 187       return true
 188
 189   vim.enterMode('hints', callback)
 190
 191 # Follow links with hint markers
 192 command_follow = helper_follow.bind(undefined, {inTab: false})
 193
 194 # Follow links in a new Tab with hint markers
 195 command_follow_in_tab = helper_follow.bind(undefined, {inTab: true})
 196
 197 # Follow multiple links with hint markers
 198 command_follow_multiple = helper_follow.bind(undefined, {inTab: true, multiple: true})
 199
 200 helper_follow_pattern = (type, vim) ->
 201   links = utils.getMarkableElements(vim.window.document, {type: 'action'})
 202     .filter(utils.isElementVisible)
 203   patterns = utils.splitListString(getComplexPref("#{ type }_patterns"))
 204   matchingLink = utils.getBestPatternMatch(patterns, links)
 205
 206   if matchingLink
 207     utils.simulateClick(matchingLink, {metaKey: false, ctrlKey: false})
 208
 209 # Follow previous page
 210 command_follow_prev = helper_follow_pattern.bind(undefined, 'prev')
 211
 212 # Follow next page
 213 command_follow_next = helper_follow_pattern.bind(undefined, 'next')
 214
 215 # Go up one level in the URL hierarchy
 216 command_go_up_path = (vim) ->
 217   path = vim.window.location.pathname
 218   vim.window.location.pathname = path.replace(/// / [^/]+ /?$ ///, '')
 219
 220 # Go up to root of the URL hierarchy
 221 command_go_to_root = (vim) ->
 222   vim.window.location.href = vim.window.location.origin
 223
 224 # Move the current tab backward
 225 command_tab_move_left = (vim) ->
 226   { gBrowser } = vim.rootWindow
 227   lastIndex = gBrowser.tabContainer.selectedIndex
 228   gBrowser.moveTabBackward()
 229   if gBrowser.tabContainer.selectedIndex == lastIndex
 230     gBrowser.moveTabToEnd()
 231
 232 # Move the current tab forward
 233 command_tab_move_right = (vim) ->
 234   { gBrowser } = vim.rootWindow
 235   lastIndex = gBrowser.tabContainer.selectedIndex
 236   gBrowser.moveTabForward()
 237   if gBrowser.tabContainer.selectedIndex == lastIndex
 238     gBrowser.moveTabToStart()
 239
 240 # Display the Help Dialog
 241 command_help = (vim) ->
 242   help.injectHelp(vim.window.document, commands)
 243
 244 findStorage = { lastSearchString: '' }
 245
 246 # Switch into find mode
 247 command_find = (vim) ->
 248   vim.enterMode('find', { highlight: false })
 249
 250 # Switch into find mode with highlighting
 251 command_find_hl = (vim) ->
 252   vim.enterMode('find', { highlight: true })
 253
 254 # Search for the last pattern
 255 command_find_next = (vim) ->
 256   if findBar = vim.rootWindow.gBrowser.getFindBar()
 257     if findStorage.lastSearchString.length > 0
 258       findBar._findField.value = findStorage.lastSearchString
 259       findBar.onFindAgainCommand(false)
 260
 261 # Search for the last pattern backwards
 262 command_find_prev = (vim) ->
 263   if findBar = vim.rootWindow.gBrowser.getFindBar()
 264     if findStorage.lastSearchString.length > 0
 265       findBar._findField.value = findStorage.lastSearchString
 266       findBar.onFindAgainCommand(true)
 267
 268 command_insert_mode = (vim) ->
 269   vim.enterMode('insert')
 270
 271 command_Esc = (vim, event) ->
 272   utils.blurActiveElement(vim.window)
 273
 274   # Blur active XUL control
 275   callback = -> event.originalTarget?.ownerDocument?.activeElement?.blur()
 276   vim.window.setTimeout(callback, 0)
 277
 278   help.removeHelp(vim.window.document)
 279
 280   vim.rootWindow.DeveloperToolbar.hide()
 281
 282   vim.rootWindow.gBrowser.getFindBar()?.close()
 283
 284
 285 class Command
 286   constructor: (@group, @name, @func, keys) ->
 287     @defaultKeys = keys
 288     if isPrefSet(@prefName('keys'))
 289       try @keyValues = JSON.parse(getPref(@prefName('keys')))
 290     else
 291       @keyValues = keys
 292
 293   # Name of the preference for a given property
 294   prefName: (value) -> "commands.#{ @name }.#{ value }"
 295
 296   keys: (value) ->
 297     if value is undefined
 298       return @keyValues
 299     else
 300       @keyValues = value or @defaultKeyValues
 301       setPref(@prefName('keys'), value and JSON.stringify(value))
 302
 303   help: -> _("help_command_#{ @name }")
 304
 305 commands = [
 306   new Command('urls',   'focus',                  command_focus,                  ['o'])
 307   new Command('urls',   'focus_search',           command_focus_search,           ['O'])
 308   new Command('urls',   'paste',                  command_paste,                  ['p'])
 309   new Command('urls',   'paste_tab',              command_paste_tab,              ['P'])
 310   new Command('urls',   'marker_yank',            command_marker_yank,            ['y,f'])
 311   new Command('urls',   'marker_focus',           command_marker_focus,           ['v,f'])
 312   new Command('urls',   'yank',                   command_yank,                   ['y,y'])
 313   new Command('urls',   'reload',                 command_reload,                 ['r'])
 314   new Command('urls',   'reload_force',           command_reload_force,           ['R'])
 315   new Command('urls',   'reload_all',             command_reload_all,             ['a,r'])
 316   new Command('urls',   'reload_all_force',       command_reload_all_force,       ['a,R'])
 317   new Command('urls',   'stop',                   command_stop,                   ['s'])
 318   new Command('urls',   'stop_all',               command_stop_all,               ['a,s'])
 319
 320   new Command('nav',    'scroll_to_top',          command_scroll_to_top ,         ['g,g'])
 321   new Command('nav',    'scroll_to_bottom',       command_scroll_to_bottom,       ['G'])
 322   new Command('nav',    'scroll_down',            command_scroll_down,            ['j', 'c-e'])
 323   new Command('nav',    'scroll_up',              command_scroll_up,              ['k', 'c-y'])
 324   new Command('nav',    'scroll_left',            command_scroll_left,            ['h'])
 325   new Command('nav',    'scroll_right',           command_scroll_right ,          ['l'])
 326   new Command('nav',    'scroll_half_page_down',  command_scroll_half_page_down,  ['d'])
 327   new Command('nav',    'scroll_half_page_up',    command_scroll_half_page_up,    ['u'])
 328   new Command('nav',    'scroll_page_down',       command_scroll_page_down,       ['c-f'])
 329   new Command('nav',    'scroll_page_up',         command_scroll_page_up,         ['c-b'])
 330
 331   new Command('tabs',   'open_tab',               command_open_tab,               ['t'])
 332   new Command('tabs',   'tab_prev',               command_tab_prev,               ['J', 'g,T'])
 333   new Command('tabs',   'tab_next',               command_tab_next,               ['K', 'g,t'])
 334   new Command('tabs',   'tab_move_left',          command_tab_move_left,          ['c-J'])
 335   new Command('tabs',   'tab_move_right',         command_tab_move_right,         ['c-K'])
 336   new Command('tabs',   'home',                   command_home,                   ['g,h'])
 337   new Command('tabs',   'tab_first',              command_tab_first,              ['g,H', 'g,^'])
 338   new Command('tabs',   'tab_last',               command_tab_last,               ['g,L', 'g,$'])
 339   new Command('tabs',   'close_tab',              command_close_tab,              ['x'])
 340   new Command('tabs',   'restore_tab',            command_restore_tab,            ['X'])
 341
 342   new Command('browse', 'follow',                 command_follow,                 ['f'])
 343   new Command('browse', 'follow_in_tab',          command_follow_in_tab,          ['F'])
 344   new Command('browse', 'follow_multiple',        command_follow_multiple,        ['a,f'])
 345   new Command('browse', 'follow_previous',        command_follow_prev,            ['['])
 346   new Command('browse', 'follow_next',            command_follow_next,            [']'])
 347   new Command('browse', 'go_up_path',             command_go_up_path,             ['g,u'])
 348   new Command('browse', 'go_to_root',             command_go_to_root,             ['g,U'])
 349   new Command('browse', 'back',                   command_back,                   ['H'])
 350   new Command('browse', 'forward',                command_forward,                ['L'])
 351
 352   new Command('misc',   'find',                   command_find,                   ['/'])
 353   new Command('misc',   'find_hl',                command_find_hl,                ['a,/'])
 354   new Command('misc',   'find_next',              command_find_next,              ['n'])
 355   new Command('misc',   'find_prev',              command_find_prev,              ['N'])
 356   new Command('misc',   'insert_mode',            command_insert_mode,            ['i'])
 357   new Command('misc',   'help',                   command_help,                   ['?'])
 358   new Command('misc',   'dev',                    command_dev,                    [':'])
 359
 360   escapeCommand =
 361   new Command('misc',   'Esc',                    command_Esc,                    ['Esc'])
 362 ]
 363
 364 searchForMatchingCommand = (keys) ->
 365   for index in [0...keys.length] by 1
 366     str = keys[index..].join(',')
 367     for command in commands
 368       for key in command.keys()
 369         # The following hack is a workaround for the issue where # letter `c`
 370         # is considered a start of command with control modifier `c-xxx`
 371         if "#{key},".startsWith("#{str},")
 372           return {match: true, exact: (key == str), command}
 373
 374   return {match: false}
 375
 376 isEscCommandKey = (keyStr) -> keyStr in escapeCommand.keys()
 377
 378 isReturnCommandKey = (keyStr) -> keyStr.contains('Return')
 379
 380 exports.commands                  = commands
 381 exports.searchForMatchingCommand  = searchForMatchingCommand
 382 exports.isEscCommandKey           = isEscCommandKey
 383 exports.isReturnCommandKey        = isReturnCommandKey
 384 exports.findStorage               = findStorage