extension/lib/marker.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file contains an abstraction for hint markers. It creates the UI for a
  22 # marker and provides methods to manipulate the markers.
  23
  24 utils = require('./utils')
  25
  26 class Marker
  27   # `@wrapper` is a stand-in for the element that the marker represents. See
  28   # `MarkerContainer::injectHints` for more information.
  29   constructor: (@wrapper, @document, {@isComplementary}) ->
  30     @elementShape  = @wrapper.shape
  31     @markerElement = utils.createBox(@document, 'marker')
  32     @markerElement.setAttribute('data-type', @wrapper.type)
  33     @weight = @elementShape.area
  34     @width = 0
  35     @height = 0
  36     @hint = ''
  37     @hintIndex = 0
  38     @zoom = 1
  39     @viewport = null
  40     @position = null
  41     @originalPosition = null
  42
  43   reset: ->
  44     @setHint(@hint)
  45     @show()
  46
  47   show: -> @setVisibility(true)
  48   hide: -> @setVisibility(false)
  49
  50   setVisibility: (visible) ->
  51     @markerElement.classList.toggle('marker--hidden', not visible)
  52
  53   # To be called when the marker has been both assigned a hint and inserted
  54   # into the DOM, and thus gotten a width and height.
  55   setPosition: (@viewport, @zoom) ->
  56     {
  57       markerElement: {clientWidth, clientHeight}
  58       elementShape: {nonCoveredPoint: {x: left, y: top, offset}}
  59     } = this
  60
  61     @width  = clientWidth  / @zoom
  62     @height = clientHeight / @zoom
  63
  64     # Center the marker vertically on the non-covered point.
  65     top -= Math.ceil(@height / 2)
  66
  67     # Make the position relative to the top frame.
  68     left += offset.left
  69     top  += offset.top
  70
  71     @originalPosition = {left, top}
  72     @moveTo(left, top)
  73
  74   moveTo: (left, top) ->
  75     # Make sure that the marker stays within the viewport.
  76     left = Math.min(left, @viewport.right  - @width)
  77     top  = Math.min(top,  @viewport.bottom - @height)
  78     left = Math.max(left, @viewport.left)
  79     top  = Math.max(top,  @viewport.top)
  80
  81     # Take the current zoom into account.
  82     left = Math.round(left * @zoom)
  83     top  = Math.round(top  * @zoom)
  84
  85     # The positioning is absolute.
  86     @markerElement.style.left = "#{left}px"
  87     @markerElement.style.top  = "#{top}px"
  88
  89     # For quick access.
  90     @position = {
  91       left, right: left + @width,
  92       top, bottom: top + @height,
  93     }
  94
  95   updatePosition: (dx, dy) ->
  96     @moveTo(@originalPosition.left + dx, @originalPosition.top + dy)
  97
  98   setHint: (@hint) ->
  99     @hintIndex = 0
 100     @markerElement.textContent = ''
 101     fragment = @document.createDocumentFragment()
 102     utils.createBox(@document, 'marker-char', fragment, char) for char in @hint
 103     @markerElement.appendChild(fragment)
 104
 105   matchHintChar: (char) ->
 106     if char == @hint[@hintIndex]
 107       @toggleLastHintChar(true)
 108       @hintIndex += 1
 109       return true
 110     return false
 111
 112   deleteHintChar: ->
 113     if @hintIndex > 0
 114       @hintIndex -= 1
 115       @toggleLastHintChar(false)
 116
 117   toggleLastHintChar: (visible) ->
 118     @markerElement.children[@hintIndex]
 119       .classList.toggle('marker-char--matched', visible)
 120
 121   isMatched: -> (@hintIndex == @hint.length)
 122
 123   markMatched: (matched) ->
 124     @markerElement.classList.toggle('marker--matched', matched)
 125
 126 module.exports = Marker