extension/lib/events-frame.coffee

   1 ###
   2 # Copyright Simon Lydell 2015.
   3 #
   4 # This file is part of VimFx.
   5 #
   6 # VimFx is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # VimFx is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  18 ###
  19
  20 # This file is the equivalent to events.coffee, but for frame scripts.
  21
  22 messageManager = require('./message-manager')
  23 utils          = require('./utils')
  24
  25 class FrameEventManager
  26   constructor: (@vim) ->
  27     @numFocusToSuppress = 0
  28
  29   listen: utils.listen.bind(null, FRAME_SCRIPT_ENVIRONMENT)
  30   listenOnce: utils.listenOnce.bind(null, FRAME_SCRIPT_ENVIRONMENT)
  31
  32   addListeners: ->
  33     # If the page already was loaded when VimFx was initialized, send the
  34     # 'DOMWindowCreated' message straight away.
  35     if @vim.content.document.readyState in ['interactive', 'complete']
  36       messageManager.send('DOMWindowCreated')
  37     else
  38       @listen('DOMWindowCreated', (event) ->
  39         messageManager.send('DOMWindowCreated')
  40       )
  41
  42     @listen('readystatechange', (event) =>
  43       target = event.originalTarget
  44
  45       # If the topmost document starts loading, it means that we have navigated
  46       # to a new page or refreshed the page.
  47       if target == @vim.content.document and target.readyState == 'interactive'
  48         messageManager.send('locationChange', @vim.content.location.href)
  49     )
  50
  51     @listen('pagehide', (event) =>
  52       target = event.originalTarget
  53
  54       if target == @vim.content.document
  55         @vim.resetState()
  56       else
  57         # If the target isn’t the topmost document, it means that a frame has
  58         # changed: It could have been removed or its `src` attribute could have
  59         # been changed. Any scrollable elements in the frame (or its sub-frames)
  60         # then need to be filtered out.
  61         @vim.state.scrollableElements
  62           .reject(utils.windowContainsDeep.bind(null, target.defaultView))
  63     )
  64
  65     @listen('click', (event) =>
  66       if @vim.mode == 'hints' and event.isTrusted
  67         messageManager.send('enterMode', {mode: 'normal'})
  68     )
  69
  70     @listen('overflow', (event) =>
  71       target = event.originalTarget
  72       return unless computedStyle = @vim.content.getComputedStyle(target)
  73       return if computedStyle.getPropertyValue('overflow') == 'hidden'
  74       @vim.state.scrollableElements.add(target)
  75     )
  76
  77     @listen('underflow', (event) =>
  78       target = event.originalTarget
  79       @vim.state.scrollableElements.delete(target)
  80     )
  81
  82     @listen('keydown', (event) =>
  83       suppress = @vim.onInput(event)
  84
  85       # This also suppresses the 'keypress' and 'keyup' events. (Yes, in frame
  86       # scripts, suppressing the 'keydown' events does seem to even suppress
  87       # the 'keyup' event!)
  88       utils.suppressEvent(event) if suppress
  89
  90       # From this line on, the rest of the code in `addListeners` is more or
  91       # less devoted to autofocus prevention. When enabled, focus events that
  92       # occur before the user has interacted with page are prevented.
  93       #
  94       # If this keydown event wasn’t suppressed (`not suppress`), it’s an
  95       # obvious interaction with the page. If it _was_ suppressed, though, it’s
  96       # an interaction depending on the command triggered; if it calls
  97       # `vim.markPageInteraction()` or not.
  98       @vim.markPageInteraction() unless suppress
  99     )
 100
 101     @listen('keydown', ((event) ->
 102       suppress = messageManager.get('lateKeydown', {
 103         defaultPrevented: event.defaultPrevented
 104       })
 105       utils.suppressEvent(event) if suppress
 106     ), false)
 107
 108     # Clicks are always counted as page interaction. Listen for 'mousedown'
 109     # instead of 'click' to mark the interaction as soon as possible.
 110     @listen('mousedown', @vim.markPageInteraction.bind(@vim))
 111
 112     messageManager.listen('browserRefocus', =>
 113       # Suppress the next two focus events (for `document` and `window`; see
 114       # `blurActiveBrowserElement`).
 115       @numFocusToSuppress = 2
 116     )
 117
 118     @listen('focus', (event) =>
 119       target = event.originalTarget
 120
 121       if @numFocusToSuppress > 0
 122         utils.suppressEvent(event)
 123         @numFocusToSuppress--
 124         return
 125
 126       # Reset `hasInteraction` when (re-)selecting a tab, or coming back from
 127       # another window, in order to prevent the common “automatically re-focus
 128       # when switching back to the tab” behaviour many sites have, unless a text
 129       # input _should_ be re-focused when coming back to the tab (see the 'blur'
 130       # event below).
 131       if target == @vim.content.document
 132         if @vim.state.shouldRefocus
 133           @vim.state.hasInteraction = true
 134           @vim.state.shouldRefocus = false
 135         else
 136           @vim.state.hasInteraction = false
 137         return
 138
 139       # Save the last focused text input regardless of whether that input might
 140       # be blurred because of autofocus prevention.
 141       if utils.isTextInputElement(target)
 142         @vim.state.lastFocusedTextInput = target
 143
 144       focusManager = Cc['@mozilla.org/focus-manager;1']
 145         .getService(Ci.nsIFocusManager)
 146
 147       # When moving a tab to another window, there is a short period of time
 148       # when there’s no listener for this call.
 149       return unless options = @vim.options(
 150         ['prevent_autofocus', 'prevent_autofocus_modes']
 151       )
 152
 153       # Blur the focus target, if autofocus prevention is enabled…
 154       if options.prevent_autofocus and
 155           @vim.mode in options.prevent_autofocus_modes and
 156           # …and the user has interacted with the page…
 157           not @vim.state.hasInteraction and
 158           # …and the event is programmatic (not caused by clicks or keypresses)…
 159           focusManager.getLastFocusMethod(null) == 0 and
 160           # …and the target may steal most keystrokes.
 161           (utils.isTypingElement(target) or utils.isContentEditable(target))
 162         # Some sites (such as icloud.com) re-focuses inputs if they are blurred,
 163         # causing an infinite loop of autofocus prevention and re-focusing.
 164         # Therefore, blur events that happen just after an autofocus prevention
 165         # are suppressed.
 166         @listenOnce('blur', utils.suppressEvent)
 167         target.blur()
 168     )
 169
 170     @listen('blur', (event) =>
 171       target = event.originalTarget
 172
 173       # If a text input is blurred immediately before the document loses focus,
 174       # it most likely means that the user switched tab, for example by pressing
 175       # `<c-tab>`, or switched to another window, while the text input was
 176       # focused. In this case, when switching back to that tab, the text input
 177       # will, and should, be re-focused (because it was focused when you left
 178       # the tab). This case is kept track of so that the autofocus prevention
 179       # does not catch it.
 180       if utils.isTypingElement(target) or utils.isContentEditable(target)
 181         utils.nextTick(@vim.content, =>
 182           @vim.state.shouldRefocus = not @vim.content.document.hasFocus()
 183         )
 184     )
 185
 186 module.exports = FrameEventManager