extension/lib/hints.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013.
   3 # Copyright Simon Lydell 2013, 2014, 2015.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file contains functions for getting markable elements, and related data,
  22 # as well as for creating and inserting markers for markable elements.
  23
  24 huffman    = require('n-ary-huffman')
  25 { Marker } = require('./marker')
  26 utils      = require('./utils')
  27
  28 CONTAINER_ID = 'VimFxMarkersContainer'
  29
  30 Element     = Ci.nsIDOMElement
  31 XULDocument = Ci.nsIDOMXULDocument
  32
  33 # For some time we used to return the hints container from `injectHints`, and
  34 # use that reference to remove the hints when needed. That’s fine in theory, but
  35 # in case anything breaks we might loose that reference and end up with
  36 # unremovable hints on the screen. Explicitly looking for an element with the
  37 # container ID is more fail-safe.
  38 removeHints = (window) ->
  39   window.document.getElementById(CONTAINER_ID)?.remove()
  40
  41 # Create `Marker`s for every element (represented by a regular object of data
  42 # about the element—a “wrapper,” a stand-in for the real element, which is only
  43 # accessible in frame scripts) in `wrappers`, and insert them into `window`.
  44 injectHints = (window, wrappers, viewport, options) ->
  45   semantic   = []
  46   unsemantic = []
  47   combined   = []
  48   markerMap  = {}
  49
  50   for wrapper in wrappers
  51     marker = new Marker(wrapper, window.document)
  52     group = switch
  53       when wrapper.parentIndex? then combined
  54       when wrapper.semantic     then semantic
  55       else unsemantic
  56     group.push(marker)
  57     markerMap[wrapper.elementIndex] = marker
  58
  59   markers = semantic.concat(unsemantic)
  60
  61   return null if markers.length == 0
  62
  63   # Each marker gets a unique `z-index`, so that it can be determined if a
  64   # marker overlaps another. Put more important markers (higher weight) at the
  65   # end, so that they get higher `z-index`, in order not to be overlapped.
  66   zIndex = 0
  67   setZIndexes = (markers) ->
  68     markers.sort((a, b) -> a.weight - b.weight)
  69     for marker in markers when marker not instanceof huffman.BranchPoint
  70       marker.markerElement.style.zIndex = zIndex++
  71       # Add `z-index` space for all the children of the marker.
  72       zIndex += marker.wrapper.numChildren if marker.wrapper.numChildren?
  73     return
  74
  75   # The `markers` passed to this function have been sorted by `setZIndexes` in
  76   # advance, so we can skip sorting in the `huffman.createTree` function.
  77   hintChars = options.hint_chars
  78   createHuffmanTree = (markers) ->
  79     return huffman.createTree(markers, hintChars.length, {sorted: true})
  80
  81   # Semantic elements should always get better hints and higher `z-index`:es
  82   # than unsemantic ones, even if they are smaller. The former is achieved by
  83   # putting the unsemantic elements in their own branch of the huffman tree.
  84   if unsemantic.length > 0
  85     if markers.length > hintChars.length
  86       setZIndexes(unsemantic)
  87       subTree = createHuffmanTree(unsemantic)
  88       semantic.push(subTree)
  89     else
  90       semantic.push(unsemantic...)
  91
  92   setZIndexes(semantic)
  93
  94   tree = createHuffmanTree(semantic)
  95   tree.assignCodeWords(hintChars, (marker, hint) -> marker.setHint(hint))
  96
  97   # Markers for links with the same href can be combined to use the same hint.
  98   # They should all have the same `z-index` (because they all have the same
  99   # combined weight), but in case any of them cover another they still get a
 100   # unique `z-index` (space for this was added in `setZIndexes`).
 101   for marker in combined
 102     parent = markerMap[marker.wrapper.parentIndex]
 103     marker.markerElement.style.zIndex = parent.markerElement.style.zIndex++
 104     marker.setHint(parent.hint)
 105   markers.push(combined...)
 106
 107   removeHints(window) # Better safe than sorry.
 108   container = window.document.createElement('box')
 109   container.id = CONTAINER_ID
 110   window.gBrowser.mCurrentBrowser.parentNode.appendChild(container)
 111
 112   zoom =
 113     if window.ZoomManager.useFullZoom
 114       window.ZoomManager.getZoomForBrowser(window.gBrowser.selectedBrowser)
 115     else
 116       # If “full zoom” is not used, it means that “Zoom text only” is enabled.
 117       # If so, that “zoom” does not need to be taken into account.
 118       1
 119
 120   for marker in markers
 121     container.appendChild(marker.markerElement)
 122     # Must be done after the hints have been inserted into the DOM (see
 123     # marker.coffee).
 124     marker.setPosition(viewport, zoom)
 125
 126   return markers
 127
 128
 129 getMarkableElementsAndViewport = (window, filter) ->
 130   {
 131     clientWidth, clientHeight # Viewport size excluding scrollbars, usually.
 132     scrollWidth, scrollHeight
 133   } = window.document.documentElement
 134   { innerWidth, innerHeight } = window # Viewport size including scrollbars.
 135   # We don’t want markers to cover the scrollbars, so we should use
 136   # `clientWidth` and `clientHeight`. However, when there are no scrollbars
 137   # those might be too small. Then we use `innerWidth` and `innerHeight`.
 138   width  = if scrollWidth  > innerWidth  then clientWidth  else innerWidth
 139   height = if scrollHeight > innerHeight then clientHeight else innerHeight
 140   viewport = {
 141     left:   0
 142     top:    0
 143     right:  width
 144     bottom: height
 145     width
 146     height
 147   }
 148
 149   wrappers = []
 150   getMarkableElements(window, viewport, wrappers, filter)
 151   return {wrappers, viewport}
 152
 153 # `filter` is a function that is given every element in every frame of the page.
 154 # It should return wrapper objects for markable elements and a falsy value for
 155 # all other elements. All returned wrappers are added to `wrappers`. `wrappers`
 156 # is modified instead of using return values to avoid array concatenation for
 157 # each frame. It might sound expensive to go through _every_ element, but that’s
 158 # actually what other methods like using XPath or CSS selectors would need to do
 159 # anyway behind the scenes.
 160 getMarkableElements = (window, viewport, wrappers, filter, parents = []) ->
 161   { document } = window
 162
 163   localGetElementShape = getElementShape.bind(null, window, viewport, parents)
 164   for element in getElements(document, viewport) when element instanceof Element
 165     continue unless wrapper = filter(element, localGetElementShape)
 166     wrappers.push(wrapper)
 167
 168   for frame in window.frames
 169     rect = frame.frameElement.getBoundingClientRect() # Frames only have one.
 170     continue unless isInsideViewport(rect, viewport)
 171
 172     # Calculate the visible part of the frame, according to the parent.
 173     { clientWidth, clientHeight } = frame.document.documentElement
 174     frameViewport =
 175       left:   Math.max(viewport.left - rect.left, 0)
 176       top:    Math.max(viewport.top  - rect.top,  0)
 177       right:  clientWidth  + Math.min(viewport.right  - rect.right,  0)
 178       bottom: clientHeight + Math.min(viewport.bottom - rect.bottom, 0)
 179
 180     # `.getComputedStyle()` may return `null` if the computed style isn’t
 181     # availble yet. If so, consider the element not visible.
 182     continue unless computedStyle = window.getComputedStyle(frame.frameElement)
 183     offset =
 184       left: rect.left +
 185         parseFloat(computedStyle.getPropertyValue('border-left-width')) +
 186         parseFloat(computedStyle.getPropertyValue('padding-left'))
 187       top: rect.top +
 188         parseFloat(computedStyle.getPropertyValue('border-top-width')) +
 189         parseFloat(computedStyle.getPropertyValue('padding-top'))
 190
 191     getMarkableElements(frame, frameViewport, wrappers, filter,
 192                         parents.concat({ window, offset }))
 193
 194   return
 195
 196 # Returns a suitable set of elements in `document` that could possibly get
 197 # markers.
 198 getElements = (document, viewport) ->
 199   # In XUL documents we have to resort to get every single element in the entire
 200   # document, because there are lots of complicated “anonymous” elements, which
 201   # `windowUtils.nodesFromRect()` does not catch.
 202   if document instanceof XULDocument
 203     elements = []
 204     getAllRegular = (element) ->
 205       for child in element.getElementsByTagName('*')
 206         elements.push(child)
 207         getAllAnonymous(child)
 208       return
 209     getAllAnonymous = (element) ->
 210       for child in document.getAnonymousNodes(element) or []
 211         continue unless child instanceof Element
 212         elements.push(child)
 213         getAllRegular(child)
 214       return
 215     getAllRegular(document.documentElement)
 216     return elements
 217   # In other documents we can use a super-fast Firefox API to get all elements
 218   # in the viewport.
 219   else
 220     windowUtils = document.defaultView
 221       .QueryInterface(Ci.nsIInterfaceRequestor)
 222       .getInterface(Ci.nsIDOMWindowUtils)
 223     return windowUtils.nodesFromRect(
 224       viewport.left, viewport.top, # Rect coordinates, relative to the viewport.
 225       # Distances to expand in all directions: top, right, bottom, left.
 226       0, viewport.right, viewport.bottom, 0,
 227       true, # Unsure what this does. Toggling it seems to make no difference.
 228       true  # Ensure that the list of matching elements is fully up to date.
 229     )
 230
 231 # Returns the “shape” of `element`:
 232 #
 233 # - `nonCoveredPoint`: The coordinates of the first point of `element` that
 234 #   isn’t covered by another element (except children of `element`). It also
 235 #   contains the offset needed to make those coordinates relative to the top
 236 #   frame, as well as the rectangle that the coordinates occur in.
 237 # - `area`: The area of the part of `element` that is inside `viewport`.
 238 #
 239 # Returns `null` if `element` is outside `viewport` or entirely covered by other
 240 # elements.
 241 getElementShape = (window, viewport, parents, element) ->
 242   # `element.getClientRects()` returns a list of rectangles, usually just one,
 243   # which is identical to the one returned by `element.getBoundingClientRect()`.
 244   # However, if `element` is inline and line-wrapped, then it returns one
 245   # rectangle for each line, since each line may be of different length, for
 246   # example. That allows us to properly add hints to line-wrapped links.
 247   rects = element.getClientRects()
 248   totalArea = 0
 249   visibleRects = []
 250   # The `isInsideViewport` check is not needed in HTML documents, but in XUL
 251   # documents (see `getElements()`). However, there seems to be no performance
 252   # gain in not running the check in HTML documents, so let’s keep it simple.
 253   for rect in rects when isInsideViewport(rect, viewport)
 254     visibleRect = adjustRectToViewport(rect, viewport)
 255     continue if visibleRect.area == 0
 256     totalArea += visibleRect.area
 257     visibleRects.push(visibleRect)
 258
 259   if visibleRects.length == 0
 260     if rects.length == 1 and totalArea == 0
 261       [ rect ] = rects
 262       if rect.width > 0 or rect.height > 0
 263         # If we get here, it means that everything inside `element` is floated
 264         # and/or absolutely positioned (and that `element` hasn’t been made to
 265         # “contain” the floats). For example, a link in a menu could contain a
 266         # span of text floated to the left and an icon floated to the right.
 267         # Those are still clickable. Therefore we return the shape of the first
 268         # visible child instead. At least in that example, that’s the best bet.
 269         for child in element.children
 270           shape = getElementShape(window, viewport, parents, child)
 271           return shape if shape
 272     return null
 273
 274   # Even if `element` has a visible rect, it might be covered by other elements.
 275   for visibleRect in visibleRects
 276     nonCoveredPoint = getFirstNonCoveredPoint(window, viewport, element,
 277                                               visibleRect, parents)
 278     if nonCoveredPoint
 279       nonCoveredPoint.rect = visibleRect
 280       break
 281
 282   return null unless nonCoveredPoint
 283
 284   return {
 285     nonCoveredPoint, area: totalArea
 286   }
 287
 288
 289 MINIMUM_EDGE_DISTANCE = 4
 290 isInsideViewport = (rect, viewport) ->
 291   return \
 292     rect.left   <= viewport.right  - MINIMUM_EDGE_DISTANCE and
 293     rect.top    <= viewport.bottom + MINIMUM_EDGE_DISTANCE and
 294     rect.right  >= viewport.left   + MINIMUM_EDGE_DISTANCE and
 295     rect.bottom >= viewport.top    - MINIMUM_EDGE_DISTANCE
 296
 297
 298 adjustRectToViewport = (rect, viewport) ->
 299   # The right and bottom values are subtracted by 1 because
 300   # `document.elementFromPoint(right, bottom)` does not return the element
 301   # otherwise.
 302   left   = Math.max(rect.left,       viewport.left)
 303   right  = Math.min(rect.right - 1,  viewport.right)
 304   top    = Math.max(rect.top,        viewport.top)
 305   bottom = Math.min(rect.bottom - 1, viewport.bottom)
 306
 307   # Make sure that `right >= left and bottom >= top`, since we subtracted by 1
 308   # above.
 309   right  = Math.max(right, left)
 310   bottom = Math.max(bottom, top)
 311
 312   width  = right - left
 313   height = bottom - top
 314   area   = Math.floor(width * height)
 315
 316   return {
 317     left, right, top, bottom
 318     height, width, area
 319   }
 320
 321
 322 getFirstNonCoveredPoint = (window, viewport, element, elementRect, parents) ->
 323   # Tries a point `(x + dx, y + dy)`. Returns `(x, y)` (and the frame offset)
 324   # if it passes the tests. Otherwise it tries to the right of whatever is at
 325   # `(x, y)`, `tryRight` times . If nothing succeeds, `false` is returned. `dx`
 326   # and `dy` are used to offset the wanted point `(x, y)` while trying (see the
 327   # invocations of `tryPoint` below).
 328   tryPoint = (x, dx, y, dy, tryRight = 0) ->
 329     elementAtPoint = window.document.elementFromPoint(x + dx, y + dy)
 330     offset = {left: 0, top: 0}
 331     found = false
 332
 333     # Ensure that `element`, or a child of `element` (anything inside an `<a>`
 334     # is clickable too), really is present at (x,y). Note that this is not 100%
 335     # bullet proof: Combinations of CSS can cause this check to fail, even
 336     # though `element` isn’t covered. We don’t try to temporarily reset such CSS
 337     # because of performance. Instead we rely on that some of the attempts below
 338     # will work.
 339     if element.contains(elementAtPoint) or # Note that `a.contains(a) == true`!
 340        (window.document instanceof XULDocument and
 341         getClosestNonAnonymousParent(element) == elementAtPoint)
 342       found = true
 343       # If we’re currently in a frame, there might be something on top of the
 344       # frame that covers `element`. Therefore we ensure that the frame really
 345       # is present at the point for each parent in `parents`.
 346       currentWindow = window
 347       for parent in parents by -1
 348         offset.left += parent.offset.left
 349         offset.top  += parent.offset.top
 350         elementAtPoint = parent.window.document.elementFromPoint(
 351           offset.left + x + dx, offset.top + y + dy
 352         )
 353         unless elementAtPoint == currentWindow.frameElement
 354           found = false
 355           break
 356         currentWindow = parent.window
 357
 358     if found
 359       return {x, y, offset}
 360     else
 361       return false if elementAtPoint == null or tryRight == 0
 362       rect = elementAtPoint.getBoundingClientRect()
 363       x = rect.right - offset.left + 1
 364       return false if x > viewport.right
 365       return tryPoint(x, 0, y, 0, tryRight - 1)
 366
 367
 368   # Try the left-middle point, or immediately to the right of a covering element
 369   # at that point. If both of those are covered the whole element is considered
 370   # to be covered. The reasoning is:
 371   #
 372   # - A marker should show up as near the left edge of its visible area as
 373   #   possible. Having it appear to the far right (for example) is confusing.
 374   # - We can’t try too many times because of performance.
 375   # - We used to try left-top first, but if `element` has `border-radius`, the
 376   #   corners won’t really belong to `element`, so `document.elementFromPoint()`
 377   #   will return whatever is behind. This will result in missing or
 378   #   out-of-place markers. The solution is to temporarily add a CSS class that
 379   #   removes `border-radius`, but that turned out to be rather slow, making it
 380   #   not worth it. Usually you don’t see the difference between left-top and
 381   #   left-middle, because links are usually not that high.
 382   # - We used to try left-bottom as well, but that is so rare that it’s not
 383   #   worth it.
 384   #
 385   # It is safer to try points at least one pixel into the element from the
 386   # edges, hence the `+1`.
 387   { left, top, bottom, height } = elementRect
 388   nonCoveredPoint = tryPoint(left, +1, Math.floor(top + height / 2), 0, 1)
 389
 390   return nonCoveredPoint
 391
 392 # In XUL documents there are “anonymous” elements, whose node names start with
 393 # `xul:` or `html:`. These are never returned by `document.elementFromPoint` but
 394 # their closest non-anonymous parents are.
 395 getClosestNonAnonymousParent = (element) ->
 396   element = element.parentNode while element.prefix?
 397   return element
 398
 399 module.exports = {
 400   removeHints
 401   injectHints
 402   getMarkableElementsAndViewport
 403 }