extension/lib/events.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file sets up all event listeners needed to power VimFx: To know when to
  22 # launch commands and to provide state to them. Events in web page content are
  23 # listened for in events-frame.coffee.
  24
  25 button = require('./button')
  26 messageManager = require('./message-manager')
  27 prefs = require('./prefs')
  28 utils = require('./utils')
  29
  30 HELD_MODIFIERS_ATTRIBUTE = 'vimfx-held-modifiers'
  31
  32 class UIEventManager
  33   constructor: (@vimfx, @window) ->
  34     @listen = utils.listen.bind(null, @window)
  35     @listenOnce = utils.listenOnce.bind(null, @window)
  36
  37     # This flag controls whether to suppress the various key events or not.
  38     @suppress = false
  39
  40     # If a matched shortcut has the `<late>` special key, this flag is set to
  41     # `true`.
  42     @late = false
  43
  44     # When a menu or panel is shown VimFx should temporarily stop processing
  45     # keyboard input, allowing accesskeys to be used.
  46     @popupPassthrough = false
  47
  48     @enteredKeys = new EnteredKeysManager(@window)
  49
  50   addListeners: ->
  51     checkPassthrough = (value, event) =>
  52       target = event.originalTarget
  53       if target.localName in ['menupopup', 'panel'] and
  54          # Don’t set `@popupPassthrough` to `false` if there actually are popups
  55          # open. This is the case when a sub-menu closes.
  56          (value or not @anyPopupsOpen())
  57         @popupPassthrough = value
  58
  59     @listen('popupshown',  checkPassthrough.bind(null, true))
  60     @listen('popuphidden', checkPassthrough.bind(null, false))
  61
  62     @listen('keydown', (event) =>
  63       # No matter what, always reset the `@suppress` flag, so we don't
  64       # suppress more than intended.
  65       @suppress = false
  66
  67       # Reset the `@late` flag, telling any late listeners for the previous
  68       # event not to run. Also reset the `late` pref, telling frame scripts not
  69       # to do synchronous message passing on every keydown.
  70       @late = false
  71       prefs.set('late', false)
  72
  73       if @popupPassthrough
  74         # The `@popupPassthrough` flag is set a bit unreliably. Sometimes it
  75         # can be stuck as `true` even though no popup is shown, effectively
  76         # disabling the extension. Therefore we check if there actually _are_
  77         # any open popups before stopping processing keyboard input. This is
  78         # only done when popups (might) be open (not on every keystroke) for
  79         # performance reasons.
  80         return if @anyPopupsOpen()
  81         @popupPassthrough = false # No popup was actually open.
  82
  83       return unless vim = @vimfx.getCurrentVim(@window)
  84
  85       @consumeKeyEvent(vim, event)
  86       if @suppress
  87         utils.suppressEvent(event) # This also suppresses the 'keypress' event.
  88       else
  89         # If this keydown event wasn’t suppressed, it’s an obvious interaction
  90         # with the page. If it _was_ suppressed, though, it’s an interaction
  91         # depending on the command triggered; if _it_ calls
  92         # `vim.markPageInteraction()` or not.
  93         vim.markPageInteraction() if vim.isUIEvent(event)
  94     )
  95
  96     @listen('keyup', (event) =>
  97       utils.suppressEvent(event) if @suppress
  98       @setHeldModifiers(event, {filterCurrentOnly: true})
  99     )
 100
 101     handleFocusRelatedEvent = (options, event) =>
 102       target = event.originalTarget
 103       return unless vim = @vimfx.getCurrentVim(@window)
 104
 105       findBar = @window.gBrowser.getFindBar()
 106       if target == findBar._findField.mInputField
 107         vim.enterMode(options.mode)
 108
 109       if vim.isUIEvent(event)
 110         focusType = utils.getFocusType(utils.getActiveElement(@window))
 111         vim._setFocusType(focusType)
 112
 113     @listen('focus', handleFocusRelatedEvent.bind(null, {mode: 'find'}))
 114     @listen('blur',  handleFocusRelatedEvent.bind(null, {mode: 'normal'}))
 115
 116     @listen('click', (event) =>
 117       target = event.originalTarget
 118       return unless vim = @vimfx.getCurrentVim(@window)
 119
 120       # In multi-process, clicks simulated by VimFx cannot be caught here. In
 121       # non-multi-process, they unfortunately can. This hack should be
 122       # sufficient for that case until non-multi-process is removed from
 123       # Firefox.
 124       isVimFxGeneratedEvent = (
 125         event.layerX == 0 and event.layerY == 0 and
 126         event.movementX == 0 and event.movementY == 0
 127       )
 128
 129       # If the user clicks the reload button or a link when in hints mode, we’re
 130       # going to end up in hints mode without any markers. Or if the user clicks
 131       # a text input, then that input will be focused, but you can’t type in it
 132       # (instead markers will be matched). So if the user clicks anything in
 133       # hints mode it’s better to leave it.
 134       if vim.mode == 'hints' and not isVimFxGeneratedEvent and
 135          # Exclude the VimFx button, though, since clicking it returns to normal
 136          # mode. Otherwise we’d first return to normal mode and then the button
 137          # would open the help dialog.
 138          target != button.getButton(@window)
 139         vim.enterMode('normal')
 140
 141       vim._send('clearHover') unless isVimFxGeneratedEvent
 142     )
 143
 144     @listen('overflow', (event) =>
 145       target = event.originalTarget
 146       return unless vim = @vimfx.getCurrentVim(@window)
 147       if vim._isUIElement(target)
 148         vim._state.scrollableElements.addChecked(target)
 149     )
 150
 151     @listen('underflow', (event) =>
 152       target = event.originalTarget
 153       return unless vim = @vimfx.getCurrentVim(@window)
 154       if vim._isUIElement(target)
 155         vim._state.scrollableElements.deleteChecked(target)
 156     )
 157
 158     @listen('TabSelect', (event) =>
 159       target = event.originalTarget
 160       target.setAttribute('VimFx-visited', 'true')
 161       @vimfx.emit('TabSelect', {event})
 162
 163       return unless vim = @vimfx.getCurrentVim(@window)
 164       vim.hideNotification()
 165     )
 166
 167     @listen('TabClose', (event) =>
 168       browser = @window.gBrowser.getBrowserForTab(event.originalTarget)
 169       return unless vim = @vimfx.vims.get(browser)
 170       # Note: `lastClosedVim` must be stored so that any window can access it.
 171       @vimfx.lastClosedVim = vim
 172     )
 173
 174     messageManager.listen('cachedPageshow', ((data, callback, browser) =>
 175       [oldVim, @vimfx.lastClosedVim] = [@vimfx.lastClosedVim, null]
 176       unless oldVim
 177         callback(false)
 178         return
 179
 180       if @vimfx.vims.has(browser)
 181         vim = @vimfx.vims.get(browser)
 182         if vim._messageManager == vim.browser.messageManager
 183           callback(false)
 184           return
 185
 186       # If we get here, it means that we’ve detected a tab dragged from one
 187       # window to another. If so, the `vim` object from the last closed tab (the
 188       # moved tab) should be re-used. See the commit message for commit bb70257d
 189       # for more details.
 190       oldVim._setBrowser(browser)
 191       @vimfx.vims.set(browser, oldVim)
 192       @vimfx.emit('modeChange', {vim: oldVim})
 193       callback(true)
 194     ), {messageManager: @window.messageManager})
 195
 196   consumeKeyEvent: (vim, event) ->
 197     match = vim._consumeKeyEvent(event)
 198
 199     if match
 200       if @vimfx.options.notify_entered_keys
 201         if match.type in ['none', 'full'] or match.likelyConflict
 202           @enteredKeys.clear(vim)
 203         else
 204           @enteredKeys.push(vim, match.keyStr, @vimfx.options.timeout)
 205       else
 206         vim.hideNotification()
 207
 208       if match.specialKeys['<late>']
 209         @suppress = false
 210         @consumeLateKeydown(vim, event, match)
 211       else
 212         @suppress = vim._onInput(match, event)
 213     else
 214       @suppress = null
 215     @setHeldModifiers(event)
 216
 217   consumeLateKeydown: (vim, event, match) ->
 218     @late = true
 219
 220     # The passed in `event` is the regular non-late browser UI keydown event.
 221     # It is only used to set held keys. This is easier than sending an event
 222     # subset from frame scripts.
 223     listener = ({defaultPrevented}) =>
 224       # `@late` is reset on every keydown. If it is no longer `true`, it means
 225       # that the page called `event.stopPropagation()`, which prevented this
 226       # listener from running for that event.
 227       return unless @late
 228       @suppress =
 229         if defaultPrevented
 230           false
 231         else
 232           vim._onInput(match, event)
 233       @setHeldModifiers(event)
 234       return @suppress
 235
 236     if vim.isUIEvent(event)
 237       @listenOnce('keydown', ((lateEvent) =>
 238         listener(lateEvent)
 239         if @suppress
 240           utils.suppressEvent(lateEvent)
 241           @listenOnce('keyup', utils.suppressEvent, false)
 242       ), false)
 243     else
 244       # Hack to avoid synchronous messages on every keydown (see
 245       # events-frame.coffee).
 246       prefs.set('late', true)
 247       vim._listenOnce('lateKeydown', listener)
 248
 249   setHeldModifiers: (event, {filterCurrentOnly = false} = {}) ->
 250     mainWindow = @window.document.documentElement
 251     modifiers =
 252       if filterCurrentOnly
 253         mainWindow.getAttribute(HELD_MODIFIERS_ATTRIBUTE)
 254       else
 255         if @suppress == null then 'alt ctrl meta shift' else ''
 256     isHeld = (modifier) -> event["#{modifier}Key"]
 257     mainWindow.setAttribute(HELD_MODIFIERS_ATTRIBUTE,
 258                             modifiers.split(' ').filter(isHeld).join(' '))
 259
 260   anyPopupsOpen: ->
 261     # The autocomplete popup in text inputs (for example) is technically a
 262     # panel, but it does not respond to key presses. Therefore
 263     # `[ignorekeys="true"]` is excluded.
 264     #
 265     # coffeelint: disable=max_line_length
 266     # <https://developer.mozilla.org/en-US/docs/Mozilla/Tech/XUL/PopupGuide/PopupKeys#Ignoring_Keys>
 267     # coffeelint: enable=max_line_length
 268     popups = utils.querySelectorAllDeep(
 269       @window, ':-moz-any(menupopup, panel):not([ignorekeys="true"])'
 270     )
 271     for popup in popups
 272       return true if popup.state == 'open'
 273     return false
 274
 275 class EnteredKeysManager
 276   constructor: (@window) ->
 277     @keys = []
 278     @timeout = null
 279
 280   clear: (notifier) ->
 281     @keys = []
 282     @clearTimeout()
 283     notifier.hideNotification()
 284
 285   push: (notifier, keyStr, duration) ->
 286     @keys.push(keyStr)
 287     @clearTimeout()
 288     notifier.notify(@keys.join(''))
 289     clear = @clear.bind(this)
 290     @timeout = @window.setTimeout((-> clear(notifier)), duration)
 291
 292   clearTimeout: ->
 293     @window.clearTimeout(@timeout) if @timeout?
 294     @timeout = null
 295
 296 module.exports = UIEventManager