extension/lib/hints.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013.
   3 # Copyright Simon Lydell 2013, 2014, 2015.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file contains functions for getting markable elements, and related data,
  22 # as well as for creating and inserting markers for markable elements.
  23
  24 huffman    = require('n-ary-huffman')
  25 { Marker } = require('./marker')
  26 utils      = require('./utils')
  27
  28 CONTAINER_ID = 'VimFxMarkersContainer'
  29
  30 Element     = Ci.nsIDOMElement
  31 XULDocument = Ci.nsIDOMXULDocument
  32
  33 # For some time we used to return the hints container from `injectHints`, and
  34 # use that reference to remove the hints when needed. That’s fine in theory, but
  35 # in case anything breaks we might loose that reference and end up with
  36 # unremovable hints on the screen. Explicitly looking for an element with the
  37 # container ID is more fail-safe.
  38 removeHints = (window) ->
  39   window.document.getElementById(CONTAINER_ID)?.remove()
  40
  41 # Create `Marker`s for every element (represented by a regular object of data
  42 # about the element—a “wrapper,” a stand-in for the real element, which is only
  43 # accessible in frame scripts) in `wrappers`, and insert them into `window`.
  44 injectHints = (window, wrappers, viewport, options) ->
  45   semantic   = []
  46   unsemantic = []
  47   combined   = []
  48   markerMap  = {}
  49
  50   for wrapper in wrappers
  51     marker = new Marker(wrapper, window.document)
  52     group = switch
  53       when wrapper.parentIndex? then combined
  54       when wrapper.semantic     then semantic
  55       else unsemantic
  56     group.push(marker)
  57     markerMap[wrapper.elementIndex] = marker
  58
  59   markers = semantic.concat(unsemantic)
  60
  61   return null if markers.length == 0
  62
  63   # Each marker gets a unique `z-index`, so that it can be determined if a
  64   # marker overlaps another. Put more important markers (higher weight) at the
  65   # end, so that they get higher `z-index`, in order not to be overlapped.
  66   zIndex = 0
  67   setZIndexes = (markers) ->
  68     markers.sort((a, b) -> a.weight - b.weight)
  69     for marker in markers when marker not instanceof huffman.BranchPoint
  70       marker.markerElement.style.zIndex = zIndex++
  71       # Add `z-index` space for all the children of the marker.
  72       zIndex += marker.wrapper.numChildren if marker.wrapper.numChildren?
  73     return
  74
  75   # The `markers` passed to this function have been sorted by `setZIndexes` in
  76   # advance, so we can skip sorting in the `huffman.createTree` function.
  77   hintChars = options.hint_chars
  78   createHuffmanTree = (markers) ->
  79     return huffman.createTree(markers, hintChars.length, {sorted: true})
  80
  81   # Semantic elements should always get better hints and higher `z-index`:es
  82   # than unsemantic ones, even if they are smaller. The former is achieved by
  83   # putting the unsemantic elements in their own branch of the huffman tree.
  84   if unsemantic.length > 0
  85     if markers.length > hintChars.length
  86       setZIndexes(unsemantic)
  87       subTree = createHuffmanTree(unsemantic)
  88       semantic.push(subTree)
  89     else
  90       semantic.push(unsemantic...)
  91
  92   setZIndexes(semantic)
  93
  94   tree = createHuffmanTree(semantic)
  95   tree.assignCodeWords(hintChars, (marker, hint) -> marker.setHint(hint))
  96
  97   # Markers for links with the same href can be combined to use the same hint.
  98   # They should all have the same `z-index` (because they all have the same
  99   # combined weight), but in case any of them cover another they still get a
 100   # unique `z-index` (space for this was added in `setZIndexes`).
 101   for marker in combined
 102     parent = markerMap[marker.wrapper.parentIndex]
 103     marker.markerElement.style.zIndex = parent.markerElement.style.zIndex++
 104     marker.setHint(parent.hint)
 105   markers.push(combined...)
 106
 107   removeHints(window) # Better safe than sorry.
 108   container = window.document.createElement('box')
 109   container.id = CONTAINER_ID
 110   window.gBrowser.mCurrentBrowser.parentNode.appendChild(container)
 111
 112   zoom = window.ZoomManager.getZoomForBrowser(window.gBrowser.selectedBrowser)
 113   for marker in markers
 114     container.appendChild(marker.markerElement)
 115     # Must be done after the hints have been inserted into the DOM (see
 116     # marker.coffee).
 117     marker.setPosition(viewport, zoom)
 118
 119   return markers
 120
 121
 122 getMarkableElementsAndViewport = (window, filter) ->
 123   {
 124     clientWidth, clientHeight # Viewport size excluding scrollbars, usually.
 125     scrollWidth, scrollHeight
 126   } = window.document.documentElement
 127   { innerWidth, innerHeight } = window # Viewport size including scrollbars.
 128   # We don’t want markers to cover the scrollbars, so we should use
 129   # `clientWidth` and `clientHeight`. However, when there are no scrollbars
 130   # those might be too small. Then we use `innerWidth` and `innerHeight`.
 131   width  = if scrollWidth  > innerWidth  then clientWidth  else innerWidth
 132   height = if scrollHeight > innerHeight then clientHeight else innerHeight
 133   viewport = {
 134     left:   0
 135     top:    0
 136     right:  width
 137     bottom: height
 138     width
 139     height
 140   }
 141
 142   wrappers = []
 143   getMarkableElements(window, viewport, wrappers, filter)
 144   return {wrappers, viewport}
 145
 146 # `filter` is a function that is given every element in every frame of the page.
 147 # It should return wrapper objects for markable elements and a falsy value for
 148 # all other elements. All returned wrappers are added to `wrappers`. `wrappers`
 149 # is modified instead of using return values to avoid array concatenation for
 150 # each frame. It might sound expensive to go through _every_ element, but that’s
 151 # actually what other methods like using XPath or CSS selectors would need to do
 152 # anyway behind the scenes.
 153 getMarkableElements = (window, viewport, wrappers, filter, parents = []) ->
 154   { document } = window
 155
 156   localGetElementShape = getElementShape.bind(null, window, viewport, parents)
 157   for element in getElements(document, viewport) when element instanceof Element
 158     continue unless wrapper = filter(element, localGetElementShape)
 159     wrappers.push(wrapper)
 160
 161   for frame in window.frames
 162     rect = frame.frameElement.getBoundingClientRect() # Frames only have one.
 163     continue unless isInsideViewport(rect, viewport)
 164
 165     # Calculate the visible part of the frame, according to the parent.
 166     { clientWidth, clientHeight } = frame.document.documentElement
 167     frameViewport =
 168       left:   Math.max(viewport.left - rect.left, 0)
 169       top:    Math.max(viewport.top  - rect.top,  0)
 170       right:  clientWidth  + Math.min(viewport.right  - rect.right,  0)
 171       bottom: clientHeight + Math.min(viewport.bottom - rect.bottom, 0)
 172
 173     # `.getComputedStyle()` may return `null` if the computed style isn’t
 174     # availble yet. If so, consider the element not visible.
 175     continue unless computedStyle = window.getComputedStyle(frame.frameElement)
 176     offset =
 177       left: rect.left +
 178         parseFloat(computedStyle.getPropertyValue('border-left-width')) +
 179         parseFloat(computedStyle.getPropertyValue('padding-left'))
 180       top: rect.top +
 181         parseFloat(computedStyle.getPropertyValue('border-top-width')) +
 182         parseFloat(computedStyle.getPropertyValue('padding-top'))
 183
 184     getMarkableElements(frame, frameViewport, wrappers, filter,
 185                         parents.concat({ window, offset }))
 186
 187   return
 188
 189 # Returns a suitable set of elements in `document` that could possibly get
 190 # markers.
 191 getElements = (document, viewport) ->
 192   # In XUL documents we have to resort to get every single element in the entire
 193   # document, because there are lots of complicated “anonymous” elements, which
 194   # `windowUtils.nodesFromRect()` does not catch.
 195   if document instanceof XULDocument
 196     elements = []
 197     getAllRegular = (element) ->
 198       for child in element.getElementsByTagName('*')
 199         elements.push(child)
 200         getAllAnonymous(child)
 201       return
 202     getAllAnonymous = (element) ->
 203       for child in document.getAnonymousNodes(element) or []
 204         continue unless child instanceof Element
 205         elements.push(child)
 206         getAllRegular(child)
 207       return
 208     getAllRegular(document.documentElement)
 209     return elements
 210   # In other documents we can use a super-fast Firefox API to get all elements
 211   # in the viewport.
 212   else
 213     windowUtils = document.defaultView
 214       .QueryInterface(Ci.nsIInterfaceRequestor)
 215       .getInterface(Ci.nsIDOMWindowUtils)
 216     return windowUtils.nodesFromRect(
 217       viewport.left, viewport.top, # Rect coordinates, relative to the viewport.
 218       # Distances to expand in all directions: top, right, bottom, left.
 219       0, viewport.right, viewport.bottom, 0,
 220       true, # Unsure what this does. Toggling it seems to make no difference.
 221       true  # Ensure that the list of matching elements is fully up to date.
 222     )
 223
 224 # Returns the “shape” of `element`:
 225 #
 226 # - `nonCoveredPoint`: The coordinates of the first point of `element` that
 227 #   isn’t covered by another element (except children of `element`). It also
 228 #   contains the offset needed to make those coordinates relative to the top
 229 #   frame, as well as the rectangle that the coordinates occur in.
 230 # - `area`: The area of the part of `element` that is inside `viewport`.
 231 #
 232 # Returns `null` if `element` is outside `viewport` or entirely covered by other
 233 # elements.
 234 getElementShape = (window, viewport, parents, element) ->
 235   # `element.getClientRects()` returns a list of rectangles, usually just one,
 236   # which is identical to the one returned by `element.getBoundingClientRect()`.
 237   # However, if `element` is inline and line-wrapped, then it returns one
 238   # rectangle for each line, since each line may be of different length, for
 239   # example. That allows us to properly add hints to line-wrapped links.
 240   rects = element.getClientRects()
 241   totalArea = 0
 242   visibleRects = []
 243   # The `isInsideViewport` check is not needed in HTML documents, but in XUL
 244   # documents (see `getElements()`). However, there seems to be no performance
 245   # gain in not running the check in HTML documents, so let’s keep it simple.
 246   for rect in rects when isInsideViewport(rect, viewport)
 247     visibleRect = adjustRectToViewport(rect, viewport)
 248     continue if visibleRect.area == 0
 249     totalArea += visibleRect.area
 250     visibleRects.push(visibleRect)
 251
 252   if visibleRects.length == 0
 253     if rects.length == 1 and totalArea == 0
 254       [ rect ] = rects
 255       if rect.width > 0 or rect.height > 0
 256         # If we get here, it means that everything inside `element` is floated
 257         # and/or absolutely positioned (and that `element` hasn’t been made to
 258         # “contain” the floats). For example, a link in a menu could contain a
 259         # span of text floated to the left and an icon floated to the right.
 260         # Those are still clickable. Therefore we return the shape of the first
 261         # visible child instead. At least in that example, that’s the best bet.
 262         for child in element.children
 263           shape = getElementShape(window, viewport, parents, child)
 264           return shape if shape
 265     return null
 266
 267   # Even if `element` has a visible rect, it might be covered by other elements.
 268   for visibleRect in visibleRects
 269     nonCoveredPoint = getFirstNonCoveredPoint(window, viewport, element,
 270                                               visibleRect, parents)
 271     if nonCoveredPoint
 272       nonCoveredPoint.rect = visibleRect
 273       break
 274
 275   return null unless nonCoveredPoint
 276
 277   return {
 278     nonCoveredPoint, area: totalArea
 279   }
 280
 281
 282 MINIMUM_EDGE_DISTANCE = 4
 283 isInsideViewport = (rect, viewport) ->
 284   return \
 285     rect.left   <= viewport.right  - MINIMUM_EDGE_DISTANCE and
 286     rect.top    <= viewport.bottom + MINIMUM_EDGE_DISTANCE and
 287     rect.right  >= viewport.left   + MINIMUM_EDGE_DISTANCE and
 288     rect.bottom >= viewport.top    - MINIMUM_EDGE_DISTANCE
 289
 290
 291 adjustRectToViewport = (rect, viewport) ->
 292   # The right and bottom values are subtracted by 1 because
 293   # `document.elementFromPoint(right, bottom)` does not return the element
 294   # otherwise.
 295   left   = Math.max(rect.left,       viewport.left)
 296   right  = Math.min(rect.right - 1,  viewport.right)
 297   top    = Math.max(rect.top,        viewport.top)
 298   bottom = Math.min(rect.bottom - 1, viewport.bottom)
 299
 300   # Make sure that `right >= left and bottom >= top`, since we subtracted by 1
 301   # above.
 302   right  = Math.max(right, left)
 303   bottom = Math.max(bottom, top)
 304
 305   width  = right - left
 306   height = bottom - top
 307   area   = Math.floor(width * height)
 308
 309   return {
 310     left, right, top, bottom
 311     height, width, area
 312   }
 313
 314
 315 getFirstNonCoveredPoint = (window, viewport, element, elementRect, parents) ->
 316   # Tries a point `(x + dx, y + dy)`. Returns `(x, y)` (and the frame offset)
 317   # if it passes the tests. Otherwise it tries to the right of whatever is at
 318   # `(x, y)`, `tryRight` times . If nothing succeeds, `false` is returned. `dx`
 319   # and `dy` are used to offset the wanted point `(x, y)` while trying (see the
 320   # invocations of `tryPoint` below).
 321   tryPoint = (x, dx, y, dy, tryRight = 0) ->
 322     elementAtPoint = window.document.elementFromPoint(x + dx, y + dy)
 323     offset = {left: 0, top: 0}
 324     found = false
 325
 326     # Ensure that `element`, or a child of `element` (anything inside an `<a>`
 327     # is clickable too), really is present at (x,y). Note that this is not 100%
 328     # bullet proof: Combinations of CSS can cause this check to fail, even
 329     # though `element` isn’t covered. We don’t try to temporarily reset such CSS
 330     # because of performance. Instead we rely on that some of the attempts below
 331     # will work.
 332     if element.contains(elementAtPoint) or # Note that `a.contains(a) == true`!
 333        (window.document instanceof XULDocument and
 334         getClosestNonAnonymousParent(element) == elementAtPoint)
 335       found = true
 336       # If we’re currently in a frame, there might be something on top of the
 337       # frame that covers `element`. Therefore we ensure that the frame really
 338       # is present at the point for each parent in `parents`.
 339       currentWindow = window
 340       for parent in parents by -1
 341         offset.left += parent.offset.left
 342         offset.top  += parent.offset.top
 343         elementAtPoint = parent.window.document.elementFromPoint(
 344           offset.left + x + dx, offset.top + y + dy
 345         )
 346         unless elementAtPoint == currentWindow.frameElement
 347           found = false
 348           break
 349         currentWindow = parent.window
 350
 351     if found
 352       return {x, y, offset}
 353     else
 354       return false if elementAtPoint == null or tryRight == 0
 355       rect = elementAtPoint.getBoundingClientRect()
 356       x = rect.right - offset.left + 1
 357       return false if x > viewport.right
 358       return tryPoint(x, 0, y, 0, tryRight - 1)
 359
 360
 361   # Try the left-middle point, or immediately to the right of a covering element
 362   # at that point. If both of those are covered the whole element is considered
 363   # to be covered. The reasoning is:
 364   #
 365   # - A marker should show up as near the left edge of its visible area as
 366   #   possible. Having it appear to the far right (for example) is confusing.
 367   # - We can’t try too many times because of performance.
 368   # - We used to try left-top first, but if `element` has `border-radius`, the
 369   #   corners won’t really belong to `element`, so `document.elementFromPoint()`
 370   #   will return whatever is behind. This will result in missing or
 371   #   out-of-place markers. The solution is to temporarily add a CSS class that
 372   #   removes `border-radius`, but that turned out to be rather slow, making it
 373   #   not worth it. Usually you don’t see the difference between left-top and
 374   #   left-middle, because links are usually not that high.
 375   # - We used to try left-bottom as well, but that is so rare that it’s not
 376   #   worth it.
 377   #
 378   # It is safer to try points at least one pixel into the element from the
 379   # edges, hence the `+1`.
 380   { left, top, bottom, height } = elementRect
 381   nonCoveredPoint = tryPoint(left, +1, Math.floor(top + height / 2), 0, 1)
 382
 383   return nonCoveredPoint
 384
 385 # In XUL documents there are “anonymous” elements, whose node names start with
 386 # `xul:` or `html:`. These are never returned by `document.elementFromPoint` but
 387 # their closest non-anonymous parents are.
 388 getClosestNonAnonymousParent = (element) ->
 389   element = element.parentNode while element.prefix?
 390   return element
 391
 392 module.exports = {
 393   removeHints
 394   injectHints
 395   getMarkableElementsAndViewport
 396 }