extension/packages/mode-hints/marker.coffee

   1 { SerializableBloomFilter
   2 , DummyBloomFilter } = require 'mode-hints/bloomfilter'
   3
   4 { getPref } = require 'prefs'
   5
   6 HTMLDocument      = Ci.nsIDOMHTMLDocument
   7 HTMLAnchorElement = Ci.nsIDOMHTMLAnchorElement
   8
   9 Z_INDEX_START = 99999999 # The highest `z-index` used in style.css
  10 _zIndex = Z_INDEX_START
  11 # Each marker will get a `z-index` of `_zIndex++`. In theory, `z-index` can be infinitely large. In
  12 # practice, Firefox uses a 32-bit signed integer to store it, so the maximum value is 2147483647
  13 # (http://www.puidokas.com/max-z-index/). However, we do not need to worry about hitting the limit,
  14 # since the user would have to browse through a bit more than 2 billion links in a single Firefox
  15 # session before that happens.
  16
  17 realBloomFilter = new SerializableBloomFilter('hints_bloom_data', 256 * 32, 16)
  18 dummyBloomFilter = new DummyBloomFilter()
  19
  20 # Wraps the markable element and provides methods to manipulate the markers
  21 class Marker
  22   # Creates the marker DOM node
  23   constructor: (@element) ->
  24     document = @element.ownerDocument
  25     window = document.defaultView
  26     @markerElement = document.createElement('div')
  27     @markerElement.className = 'VimFxReset VimFxHintMarker'
  28
  29     Object.defineProperty this, 'bloomFilter',
  30       get: -> if getPref('hints_bloom_on') then realBloomFilter else dummyBloomFilter
  31
  32   show: -> @setVisibility(true)
  33   hide: -> @setVisibility(false)
  34   setVisibility: (visible) ->
  35     method = if visible then 'remove' else 'add'
  36     @markerElement.classList[method]('VimFxHiddenHintMarker')
  37
  38   setPosition: (top, left) ->
  39     # The positioning is absulute
  40     @markerElement.style.top  = "#{ top }px"
  41     @markerElement.style.left = "#{ left }px"
  42
  43     # For quick access
  44     @position = {top, left}
  45
  46     # Each marker gets a unique `z-index`, so that it can be determined if a marker overlaps another.
  47     @markerElement.style.setProperty('z-index', _zIndex++, 'important')
  48
  49   # To be called when the marker has been both assigned a hint and inserted into the DOM, and thus
  50   # gotten a height and width.
  51   completePosition: ->
  52     {
  53       position: { top, left }
  54       markerElement: { offsetHeight: height, offsetWidth: width }
  55     } = this
  56     @position = {top, bottom: top + height, left, right: left + width, height, width}
  57
  58   setHint: (@hintChars) ->
  59     # Hint chars that have been matched so far
  60     @enteredHintChars = ''
  61
  62     document = @element.ownerDocument
  63
  64     while @markerElement.hasChildNodes()
  65       @markerElement.removeChild(@markerElement.firstChild)
  66
  67     fragment = document.createDocumentFragment()
  68     for char in @hintChars
  69       span = document.createElement('span')
  70       span.className = 'VimFxReset'
  71       span.textContent = char.toUpperCase()
  72       fragment.appendChild(span)
  73
  74     @markerElement.appendChild(fragment)
  75
  76     @completePosition()
  77
  78   matchHintChar: (char) ->
  79     @updateEnteredHintChars(char)
  80
  81   deleteHintChar: ->
  82     @updateEnteredHintChars(false)
  83
  84   updateEnteredHintChars: (char) ->
  85     if char == false
  86       method = 'remove'
  87       @enteredHintChars = @enteredHintChars[...-1]
  88       offset = 0
  89     else
  90       method = 'add'
  91       @enteredHintChars += char.toLowerCase()
  92       offset = -1
  93
  94     @markerElement.children[@enteredHintChars.length + offset]?.classList[method]('VimFxCharMatch')
  95     if @hintChars.startsWith(@enteredHintChars) then @show() else @hide()
  96
  97   isMatched: ->
  98     return @hintChars == @enteredHintChars
  99
 100   # Returns string features of the element that can be used in the bloom filter
 101   # in order to add relevance to the hint marker
 102   extractBloomFeatures: ->
 103     features = {}
 104
 105     # Class name of an element (walks up the node tree to find first element with at least one class)
 106     suffix = ''
 107     el = @element
 108     while el.classList?.length == 0 and el not instanceof HTMLDocument
 109       suffix += " #{ el.tagName }"
 110       el = el.parentNode
 111     if el?.classList?
 112       for className in el.classList
 113         features["#{ el.tagName }.#{ className }#{ suffix }"] = 10
 114
 115     if @element.id
 116       features["#{ el.tagName }.#{ @element.id }"] = 5
 117
 118     if @element instanceof HTMLAnchorElement
 119       features["a"] = 20 # Reward links no matter what
 120       features["#{ el.tagName }.#{ @element.href }"] = 60
 121       features["#{ el.tagName }.#{ @element.title }"] = 40
 122
 123     return features
 124
 125   # Returns rating of all present bloom features (plus 1)
 126   calcBloomRating: ->
 127     rating = 1
 128     for feature, weight of @extractBloomFeatures()
 129       rating += if @bloomFilter.test(feature) then weight else 0
 130
 131     return rating
 132
 133   reward: ->
 134     for feature, weight of @extractBloomFeatures()
 135       @bloomFilter.add(feature)
 136     @bloomFilter.save()
 137
 138 exports.Marker = Marker