extension/lib/vim.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file defines the `vim` API, available to all modes and commands. There is
  22 # one `Vim` instance for each tab. Most importantly, it provides access to the
  23 # owning Firefox window and the current mode, and allows you to change mode.
  24 # `vim` objects are exposed by the config file API. Underscored names are
  25 # private and should not be used by API consumers.
  26
  27 messageManager = require('./message-manager')
  28 ScrollableElements = require('./scrollable-elements')
  29 statusPanel = require('./status-panel')
  30 utils = require('./utils')
  31
  32 ChromeWindow = Ci.nsIDOMChromeWindow
  33
  34 class Vim
  35   constructor: (browser, @_parent) ->
  36     @mode = undefined
  37     @focusType = 'none'
  38     @_setBrowser(browser, {addListeners: false})
  39     @_storage = {}
  40
  41     @_resetState()
  42
  43     Object.defineProperty(this, 'options', {
  44       get: => @_parent.options
  45       enumerable: true
  46     })
  47
  48   _start: ->
  49     @_onLocationChange(@browser.currentURI.spec)
  50     @_addListeners()
  51     focusType = utils.getFocusType(utils.getActiveElement(@window))
  52     @_setFocusType(focusType)
  53
  54   _addListeners: ->
  55     # Require the subset of the options needed to be listed explicitly (as
  56     # opposed to sending _all_ options) for performance. Each option access
  57     # might trigger an optionOverride.
  58     @_listen('options', ({prefs}) =>
  59       options = {}
  60       for pref in prefs
  61         options[pref] = @options[pref]
  62       return options
  63     )
  64
  65     @_listen('vimMethod', ({method, args = []}, callback = null) =>
  66       result = this[method](args...)
  67       callback?(result)
  68     )
  69
  70     @_listen('vimMethodSync', ({method, args = []}) =>
  71       return this[method](args...)
  72     )
  73
  74     @_listen('locationChange', @_onLocationChange.bind(this))
  75
  76     @_listen('frameCanReceiveEvents', (value) =>
  77       @_state.frameCanReceiveEvents = value
  78     )
  79
  80     @_listen('focusType', (focusType) =>
  81       # If the focus moves from a web page element to a browser UI element, the
  82       # focus and blur events happen in the expected order, but the message from
  83       # the frame script arrives too late. Therefore, check that the currently
  84       # active element isn’t a browser UI element first.
  85       unless @_isUIElement(utils.getActiveElement(@window))
  86         @_setFocusType(focusType)
  87     )
  88
  89   _setBrowser: (@browser, {addListeners = true} = {}) ->
  90     @window = @browser.ownerGlobal
  91     @_messageManager = @browser.messageManager
  92
  93     @_statusPanel?.remove()
  94     @_statusPanel = statusPanel.injectStatusPanel(@browser)
  95
  96     @_addListeners() if addListeners
  97
  98   _resetState: ->
  99     @_state = {
 100       frameCanReceiveEvents: false
 101       scrollableElements: new ScrollableElements(@window)
 102       lastNotification: null
 103     }
 104
 105   _isBlacklisted: (url) -> @options.blacklist.some((regex) -> regex.test(url))
 106
 107   isUIEvent: (event) ->
 108     return not @_state.frameCanReceiveEvents or
 109            @_isUIElement(event.originalTarget)
 110
 111   _isUIElement: (element) ->
 112     # TODO: The `element.ownerGlobal` check will be redundant when
 113     # non-multi-process is removed from Firefox.
 114     return element.ownerGlobal instanceof ChromeWindow and
 115            element != @window.gBrowser.selectedBrowser
 116
 117   # `args...` is passed to the mode's `onEnter` method.
 118   _enterMode: (mode, args...) ->
 119     return if @mode == mode
 120
 121     unless utils.has(@_parent.modes, mode)
 122       modes = Object.keys(@_parent.modes).join(', ')
 123       throw new Error(
 124         "VimFx: Unknown mode. Available modes are: #{modes}. Got: #{mode}"
 125       )
 126
 127     @_call('onLeave') if @mode?
 128     @mode = mode
 129     @_call('onEnter', null, args...)
 130     @_parent.emit('modeChange', {vim: this})
 131     @_send('modeChange', {mode})
 132
 133   _consumeKeyEvent: (event) ->
 134     return @_parent.consumeKeyEvent(event, this)
 135
 136   _onInput: (match, event) ->
 137     uiEvent = if @isUIEvent(event) then event else false
 138     suppress = @_call('onInput', {uiEvent, count: match.count}, match)
 139     return suppress
 140
 141   _onLocationChange: (url) ->
 142     switch
 143       when @_isBlacklisted(url)
 144         @_enterMode('ignore', {type: 'blacklist'})
 145       when (@mode == 'ignore' and @_storage.ignore.type == 'blacklist') or
 146            not @mode
 147         @_enterMode('normal')
 148     @_parent.emit('locationChange', {vim: this, location: new @window.URL(url)})
 149
 150   _call: (method, data = {}, extraArgs...) ->
 151     args = Object.assign({vim: this, storage: @_storage[@mode] ?= {}}, data)
 152     currentMode = @_parent.modes[@mode]
 153     return currentMode[method].call(currentMode, args, extraArgs...)
 154
 155   _run: (name, data = {}, callback = null) ->
 156     @_send('runCommand', {name, data}, callback)
 157
 158   _messageManagerOptions: (options) ->
 159     return Object.assign({
 160       messageManager: @_messageManager
 161     }, options)
 162
 163   _listen: (name, listener, options = {}) ->
 164     messageManager.listen(name, listener, @_messageManagerOptions(options))
 165
 166   _listenOnce: (name, listener, options = {}) ->
 167     messageManager.listenOnce(name, listener, @_messageManagerOptions(options))
 168
 169   _send: (name, data, callback = null, options = {}) ->
 170     messageManager.send(name, data, callback, @_messageManagerOptions(options))
 171
 172   notify: (message) ->
 173     @_state.lastNotification = message
 174     @_parent.emit('notification', {vim: this, message})
 175     if @options.notifications_enabled
 176       @_statusPanel.setAttribute('label', message)
 177       @_statusPanel.removeAttribute('inactive')
 178
 179   hideNotification: ->
 180     @_parent.emit('hideNotification', {vim: this})
 181     @_statusPanel.setAttribute('inactive', 'true')
 182
 183   _modal: (type, args, callback = null) ->
 184     @_run('modal', {type, args}, callback)
 185
 186   markPageInteraction: (value = null) -> @_send('markPageInteraction', value)
 187
 188   _focusMarkerElement: (elementIndex, options = {}) ->
 189     # If you, for example, focus the location bar, unfocus it by pressing
 190     # `<esc>` and then try to focus a link or text input in a web page the focus
 191     # won’t work unless `@browser` is focused first.
 192     @browser.focus()
 193     browserOffset = @_getBrowserOffset()
 194     @_run('focus_marker_element', {elementIndex, browserOffset, options})
 195
 196   _setFocusType: (focusType) ->
 197     return if focusType == @focusType
 198     @focusType = focusType
 199     switch
 200       when @focusType == 'ignore'
 201         @_enterMode('ignore', {type: 'focusType'})
 202       when @mode == 'ignore' and @_storage.ignore.type == 'focusType'
 203         @_enterMode('normal')
 204       when @mode == 'normal' and @focusType == 'findbar'
 205         @_enterMode('find')
 206       when @mode == 'find' and @focusType != 'findbar'
 207         @_enterMode('normal')
 208     @_parent.emit('focusTypeChange', {vim: this})
 209
 210   _getBrowserOffset: ->
 211     browserRect = @browser.getBoundingClientRect()
 212     return {
 213       x: @window.screenX + browserRect.left
 214       y: @window.screenY + browserRect.top
 215     }
 216
 217 module.exports = Vim