extension/lib/vim-frame.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013.
   3 # Copyright Simon Lydell 2013, 2014, 2015.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file is the equivalent to vim.coffee. `vim.window` is called
  22 # `vim.content` to be consistent with Firefox’s frame script terminology and to
  23 # avoid confusion about what it represents. There is one `VimFrame` instance for
  24 # each tab. It mostly tries to mimic the `Vim` class in vim.coffee, but also
  25 # keeps track of web page state. `VimFrame` is not part of the public API.
  26
  27 messageManager     = require('./message-manager')
  28 ScrollableElements = require('./scrollable-elements')
  29 utils              = require('./utils')
  30
  31 MINIMUM_SCROLL = 5
  32
  33 class VimFrame
  34   constructor: (@content) ->
  35     @mode = 'normal'
  36
  37     @resetState()
  38
  39     messageManager.listen('modeChange', ({mode}) =>
  40       @mode = mode
  41     )
  42
  43     messageManager.listen('markPageInteraction',
  44                           @markPageInteraction.bind(this))
  45
  46   # If the target is the topmost document, reset everything. Otherwise filter
  47   # out elements belonging to the target frame. On some sites, such as Gmail,
  48   # some elements might be dead at this point.
  49   resetState: (target = @content.document) ->
  50     if target == @content.document
  51       @state =
  52         hasInteraction:       false
  53         shouldRefocus:        false
  54         lastFocusedTextInput: null
  55         scrollableElements:   new ScrollableElements(@content, MINIMUM_SCROLL)
  56         markerElements:       []
  57         inputs:               null
  58
  59     else
  60       isDead = (element) ->
  61         return Cu.isDeadWrapper(element) or element.ownerDocument == target
  62       check = (prop) =>
  63         @state[prop] = null if @state[prop] and isDead(@state[prop])
  64
  65       check('lastFocusedTextInput')
  66       @state.scrollableElements.reject(isDead)
  67       # `markerElements` and `inputs` could theoretically need to be filtered
  68       # too at this point. YAGNI until an issue arises from it.
  69
  70   options: (prefs) -> messageManager.get('options', {prefs})
  71
  72   enterMode: (@mode, args...) ->
  73     messageManager.send('vimMethod', {
  74       method: 'enterMode'
  75       args: [@mode, args...]
  76     })
  77
  78   onInput: (event) ->
  79     focusType = utils.getFocusType(event.originalTarget)
  80     suppress = messageManager.get('consumeKeyEvent', {focusType})
  81     return suppress
  82
  83   notify: (args...) ->
  84     messageManager.send('vimMethod', {method: 'notify', args})
  85
  86   markPageInteraction: -> @state.hasInteraction = true
  87
  88 module.exports = VimFrame