extension/lib/prefs.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 defaults = require('./defaults')
  22
  23 { classes: Cc, interfaces: Ci } = Components
  24
  25 { prefs } = Services
  26
  27 branches =
  28   addon:
  29     user:    prefs.getBranch(defaults.BRANCH)
  30     default: prefs.getDefaultBranch(defaults.BRANCH)
  31   root:
  32     user:    prefs
  33     default: prefs.getDefaultBranch('')
  34
  35 get = (branch, key) ->
  36   return switch branch.getPrefType(key)
  37     when branch.PREF_BOOL
  38       branch.getBoolPref(key)
  39     when branch.PREF_INT
  40       branch.getIntPref(key)
  41     when branch.PREF_STRING
  42       branch.getComplexValue(key, Ci.nsISupportsString).data
  43
  44 set = (branch, key, value) ->
  45   switch typeof value
  46     when 'boolean'
  47       branch.setBoolPref(key, value)
  48     when 'number'
  49       branch.setIntPref(key, value) # `value` will be `Math.floor`ed.
  50     when 'string'
  51       str = Cc['@mozilla.org/supports-string;1']
  52         .createInstance(Ci.nsISupportsString)
  53       str.data = value
  54       branch.setComplexValue(key, Ci.nsISupportsString, str)
  55     else
  56       if value == null
  57         branch.clearUserPref(key)
  58       else
  59         throw new Error("VimFx: Prefs may only be set to a boolean, number,
  60                          string or null. Got: #{ typeof value }")
  61
  62 has = (branch, key) ->
  63   branch.prefHasUserValue(key)
  64
  65 tmp = (branch, pref, temporaryValue, fn) ->
  66   previousValue = if has(branch, pref) then get(branch, pref) else null
  67   set(branch, pref, temporaryValue)
  68   fn()
  69   set(branch, pref, previousValue)
  70
  71 observe = (branch, domain, callback) ->
  72   observer = {observe: (branch, topic, changedPref) -> callback(changedPref)}
  73   branch.addObserver(domain, observer, false)
  74   module.onShutdown(->
  75     branch.removeObserver(domain, observer)
  76   )
  77
  78 module.exports =
  79   get: get.bind(null, branches.addon.user)
  80   set: set.bind(null, branches.addon.user)
  81   has: has.bind(null, branches.addon.user)
  82   tmp: tmp.bind(null, branches.addon.user)
  83   observe: observe.bind(null, branches.addon.user)
  84   default:
  85     get: get.bind(null, branches.addon.default)
  86     set: set.bind(null, branches.addon.default)
  87     _init: ->
  88       @set(key, value) for key, value of defaults.all_prefs
  89       return
  90   root:
  91     get: get.bind(null, branches.root.user)
  92     set: set.bind(null, branches.root.user)
  93     has: has.bind(null, branches.root.user)
  94     tmp: tmp.bind(null, branches.root.user)
  95     default:
  96       get: get.bind(null, branches.root.default)
  97       set: set.bind(null, branches.root.default)
  98   unbound: {get, set, has, tmp, observe}