extension/lib/command.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2013.
   3 # Copyright Simon Lydell 2013, 2014, 2015.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 legacy        = require('./legacy')
  22 utils         = require('./utils')
  23 _             = require('./l10n')
  24 { getPref
  25 , setPref
  26 , isPrefSet } = require('./prefs')
  27
  28 class Command
  29   constructor: (@group, @name, @func, keys) ->
  30     @prefName = "commands.#{ @name }.keys"
  31     @keyValues =
  32       if isPrefSet(@prefName)
  33         try JSON.parse(getPref(@prefName))
  34         catch then []
  35       else
  36         keys
  37     for key, index in @keyValues when typeof key == 'string'
  38       @keyValues[index] = legacy.convertKey(key)
  39
  40   keys: (value) ->
  41     if value == undefined
  42       return @keyValues
  43     else
  44       @keyValues = value
  45       setPref(@prefName, JSON.stringify(value))
  46
  47   help: -> _("help_command_#{ @name }")
  48
  49   match: (str, numbers = null) ->
  50     for key in @keys()
  51       key = utils.normalizedKey(key)
  52       if key.startsWith(str)
  53         # When letter 0 follows after a number, it is considered as number 0
  54         # instead of a valid command.
  55         continue if key == '0' and numbers
  56         count = if numbers then Number(numbers[numbers.length - 1]) else null
  57         return {match: true, exact: (key == str), command: this, count}
  58
  59   @searchForMatchingCommand: (commands, keys) ->
  60     for index in [0...keys.length] by 1
  61       str = keys[index..].join('')
  62       numbers = keys[0..index].join('').match(/[1-9]\d*/g)
  63       for command in commands
  64         return match if match = command.match(str, numbers)
  65     return {match: false}
  66
  67 module.exports = Command