extension/lib/events-frame.coffee

   1 ###
   2 # Copyright Simon Lydell 2015, 2016.
   3 #
   4 # This file is part of VimFx.
   5 #
   6 # VimFx is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # VimFx is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  18 ###
  19
  20 # This file is the equivalent to events.coffee, but for frame scripts.
  21
  22 notation = require('vim-like-key-notation')
  23 commands = require('./commands-frame')
  24 messageManager = require('./message-manager')
  25 prefs = require('./prefs')
  26 utils = require('./utils')
  27
  28 nsIFocusManager = Cc['@mozilla.org/focus-manager;1']
  29   .getService(Ci.nsIFocusManager)
  30
  31 XULDocument = Ci.nsIDOMXULDocument
  32
  33 class FrameEventManager
  34   constructor: (@vim) ->
  35     @numFocusToSuppress = 0
  36     @keepInputs = false
  37     @currentUrl = false
  38     @disconnectActiveElementObserver = null
  39
  40   listen: utils.listen.bind(null, FRAME_SCRIPT_ENVIRONMENT)
  41   listenOnce: utils.listenOnce.bind(null, FRAME_SCRIPT_ENVIRONMENT)
  42
  43   addListeners: ->
  44     # If the page already was loaded when VimFx was initialized, send the
  45     # 'frameCanReceiveEvents' message straight away.
  46     if @vim.content.document.readyState == 'complete'
  47       messageManager.send('frameCanReceiveEvents', true)
  48
  49     @listen('readystatechange', (event) =>
  50       target = event.originalTarget
  51       topDocument = @vim.content.document
  52       [oldUrl, @currentUrl] = [@currentUrl, @vim.content.location.href]
  53
  54       switch target.readyState
  55         when 'interactive'
  56           if target == topDocument or
  57              # When loading the editor on codepen.io, a frame gets
  58              # 'readystatechange' → 'interactive' quite a bit before the
  59              # toplevel document does. Checking for this case lets us send
  60              # 'locationChange' earlier, allowing to enter Ignore mode earlier,
  61              # for example. Be careful not to trigger a 'locationChange' for
  62              # frames loading _after_ the toplevel document, though. Finally,
  63              # checking for 'uninitialized' is needed to be able to blacklist
  64              # some XUL pages.
  65              (topDocument.readyState in ['loading', 'uninitialized'] and
  66               oldUrl == null)
  67             messageManager.send('locationChange', @currentUrl)
  68
  69         when 'complete'
  70           if target == topDocument
  71             messageManager.send('frameCanReceiveEvents', true)
  72     )
  73
  74     @listen('pageshow', (event) =>
  75       [oldUrl, @currentUrl] = [@currentUrl, @vim.content.location.href]
  76
  77       # When navigating the history, `event.persisted` is `true` (meaning that
  78       # the page loaded from cache) and 'readystatechange' won’t be fired, so
  79       # send a 'locationChange' message to make sure that the blacklist is
  80       # applied etc. The reason we don’t simply _always_ do this on the
  81       # 'pageshow' event, is because it usually fires too late. However, it also
  82       # fires after having moved a tab to another window. In that case it is
  83       # _not_ a location change; the blacklist should not be applied.
  84       if event.persisted
  85         url = @vim.content.location.href
  86         messageManager.send('cachedPageshow', null, (movedToNewTab) =>
  87           if not movedToNewTab and oldUrl != @currentUrl
  88             messageManager.send('locationChange', @currentUrl)
  89         )
  90     )
  91
  92     @listen('pagehide', (event) =>
  93       target = event.originalTarget
  94       @currentUrl = null
  95
  96       if target == @vim.content.document
  97         messageManager.send('frameCanReceiveEvents', false)
  98         @vim.enterMode('normal') if @vim.mode == 'hints'
  99
 100       # If the target isn’t the topmost document, it means that a frame has
 101       # changed: It could have been removed or its `src` attribute could have
 102       # been changed. If the frame contains other frames, 'pagehide' events have
 103       # already been fired for them.
 104       @vim.resetState(target)
 105     )
 106
 107     messageManager.listen('getMarkableElementsMovements', (data, callback) =>
 108       diffs = @vim.state.markerElements.map(({element, originalRect}) ->
 109         newRect = element.getBoundingClientRect()
 110         return {
 111           dx: newRect.left - originalRect.left
 112           dy: newRect.top  - originalRect.top
 113         }
 114       )
 115       callback(diffs)
 116     )
 117
 118     @listen('overflow', (event) =>
 119       target = event.originalTarget
 120       @vim.state.scrollableElements.addChecked(target)
 121     )
 122
 123     @listen('underflow', (event) =>
 124       target = event.originalTarget
 125       @vim.state.scrollableElements.deleteChecked(target)
 126     )
 127
 128     @listen('keydown', (event) =>
 129       @keepInputs = false
 130     )
 131
 132     @listen('keydown', ((event) =>
 133       suppress = false
 134
 135       # This message _has_ to be synchronous so we can suppress the event if
 136       # needed. To avoid sending a synchronous message on _every_ keydown, this
 137       # hack of toggling a pref when a `<late>` shortcut is encountered is used.
 138       if prefs.get('late')
 139         suppress = messageManager.get('lateKeydown', {
 140           defaultPrevented: event.defaultPrevented
 141         })
 142
 143       if @vim.state.inputs and @vim.mode == 'normal' and not suppress and
 144          not event.defaultPrevented
 145         # There is no need to take `ignore_keyboard_layout` and `translations`
 146         # into account here, since we want to override the _native_ `<tab>`
 147         # behavior. Then, `event.key` is the way to go. (Unless the prefs are
 148         # customized. YAGNI until requested.)
 149         keyStr = notation.stringify(event)
 150         direction = switch keyStr
 151           when ''
 152             null
 153           when prefs.get('focus_previous_key')
 154             -1
 155           when prefs.get('focus_next_key')
 156             +1
 157           else
 158             null
 159         if direction?
 160           suppress = commands.move_focus({@vim, direction})
 161           @keepInputs = true
 162
 163       if suppress
 164         utils.suppressEvent(event)
 165         @listenOnce('keyup', utils.suppressEvent, false)
 166     ), false)
 167
 168     @listen('mousedown', (event) =>
 169       # Allow clicking on another text input without exiting “gi mode”. Listen
 170       # for 'mousedown' instead of 'click', because only the former runs before
 171       # the 'blur' event. Also, `event.originalTarget` does _not_ work here.
 172       @keepInputs = (@vim.state.inputs and event.target in @vim.state.inputs)
 173
 174       # Clicks are always counted as page interaction. Listen for 'mousedown'
 175       # instead of 'click' to mark the interaction as soon as possible.
 176       @vim.markPageInteraction()
 177     )
 178
 179     messageManager.listen('browserRefocus', =>
 180       # Suppress the next two focus events (for `document` and `window`; see
 181       # `blurActiveBrowserElement`).
 182       @numFocusToSuppress = 2
 183     )
 184
 185     @listen('focus', (event) =>
 186       target = event.originalTarget
 187
 188       if @numFocusToSuppress > 0
 189         utils.suppressEvent(event)
 190         @numFocusToSuppress -= 1
 191         return
 192
 193       @vim.state.explicitBodyFocus = (target == @vim.content.document.body)
 194
 195       @sendFocusType()
 196
 197       # Reset `hasInteraction` when (re-)selecting a tab, or coming back from
 198       # another window, in order to prevent the common “automatically re-focus
 199       # when switching back to the tab” behaviour many sites have, unless a text
 200       # input _should_ be re-focused when coming back to the tab (see the 'blur'
 201       # event below).
 202       if target == @vim.content.document
 203         if @vim.state.shouldRefocus
 204           @vim.state.hasInteraction = true
 205           @vim.state.shouldRefocus = false
 206         else
 207           @vim.state.hasInteraction = false
 208         return
 209
 210       if utils.isTextInputElement(target)
 211         # Save the last focused text input regardless of whether that input
 212         # might be blurred because of autofocus prevention.
 213         @vim.state.lastFocusedTextInput = target
 214         @vim.state.hasFocusedTextInput = true
 215
 216         if @vim.mode == 'caret' and not utils.isContentEditable(target)
 217           @vim.enterMode('normal')
 218
 219       # Blur the focus target, if autofocus prevention is enabled…
 220       if prefs.get('prevent_autofocus') and
 221          @vim.mode in prefs.get('prevent_autofocus_modes').split(/\s+/) and
 222          # …and the user has interacted with the page…
 223          not @vim.state.hasInteraction and
 224          # …and the event is programmatic (not caused by clicks or keypresses)…
 225          nsIFocusManager.getLastFocusMethod(null) == 0 and
 226          # …and the target may steal most keystrokes…
 227          utils.isTypingElement(target) and
 228          # …and the page isn’t a Firefox internal page (like `about:config`).
 229          @vim.content.document not instanceof XULDocument
 230         # Some sites (such as icloud.com) re-focuses inputs if they are blurred,
 231         # causing an infinite loop of autofocus prevention and re-focusing.
 232         # Therefore, blur events that happen just after an autofocus prevention
 233         # are suppressed.
 234         @listenOnce('blur', utils.suppressEvent)
 235         target.blur()
 236         @vim.state.hasFocusedTextInput = false
 237     )
 238
 239     @listen('blur', (event) =>
 240       target = event.originalTarget
 241
 242       @vim.clearHover() if target == @vim.state.lastHoveredElement
 243
 244       @sendFocusType()
 245
 246       # If a text input is blurred immediately before the document loses focus,
 247       # it most likely means that the user switched tab, for example by pressing
 248       # `<c-tab>`, or switched to another window, while the text input was
 249       # focused. In this case, when switching back to that tab, the text input
 250       # will, and should, be re-focused (because it was focused when you left
 251       # the tab). This case is kept track of so that the autofocus prevention
 252       # does not catch it.
 253       if utils.isTypingElement(target)
 254         utils.nextTick(@vim.content, =>
 255           @vim.state.shouldRefocus = not @vim.content.document.hasFocus()
 256
 257           # “gi mode” ends when blurring a text input, unless `<tab>` was just
 258           # pressed.
 259           unless @vim.state.shouldRefocus or @keepInputs
 260             commands.clear_inputs({@vim})
 261         )
 262     )
 263
 264   sendFocusType: ({ignore = []} = {}) ->
 265     return unless activeElement = utils.getActiveElement(@vim.content)
 266     focusType = utils.getFocusType(activeElement)
 267     messageManager.send('focusType', focusType) unless focusType in ignore
 268
 269     # If a text input is removed from the DOM while it is focused, no 'focus'
 270     # or 'blur' events will be fired, making VimFx think that the text input is
 271     # still focused. Therefore we add a temporary observer for the currently
 272     # focused element and re-send the focusType if it gets removed.
 273     @disconnectActiveElementObserver?()
 274     @disconnectActiveElementObserver =
 275       if focusType == 'none'
 276         null
 277       else
 278         utils.onRemoved(activeElement, @sendFocusType.bind(this))
 279
 280 module.exports = FrameEventManager