extension/lib/vim-frame.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013.
   3 # Copyright Simon Lydell 2013, 2014, 2015.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file is the equivalent to vim.coffee. `vim.window` is called
  22 # `vim.content` to be consistent with Firefox’s frame script terminology and to
  23 # avoid confusion about what it represents. There is one `VimFrame` instance for
  24 # each tab. It mostly tries to mimic the `Vim` class in vim.coffee, but also
  25 # keeps track of web page state. `VimFrame` is not part of the public API.
  26
  27 messageManager     = require('./message-manager')
  28 ScrollableElements = require('./scrollable-elements')
  29 utils              = require('./utils')
  30
  31 class VimFrame
  32   constructor: (@content) ->
  33     @mode = 'normal'
  34
  35     @resetState()
  36
  37     messageManager.listen('modeChange', ({mode}) =>
  38       @mode = mode
  39     )
  40
  41     messageManager.listen('markPageInteraction',
  42                           @markPageInteraction.bind(this))
  43
  44   resetState: ->
  45     @state =
  46       hasInteraction:       false
  47       lastFocusedTextInput: null
  48       shouldRefocus:        false
  49       scrollableElements:   new ScrollableElements(@content)
  50
  51   options: (prefs) -> messageManager.get('options', {prefs})
  52
  53   enterMode: (@mode, args...) ->
  54     messageManager.send('vimMethod', {
  55       method: 'enterMode'
  56       args: [@mode, args...]
  57     })
  58
  59   onInput: (event) ->
  60     focusType = utils.getFocusType(event)
  61     suppress = messageManager.get('consumeKeyEvent', {focusType})
  62     return suppress
  63
  64   notify: (args...) ->
  65     messageManager.send('vimMethod', {method: 'notify', args})
  66
  67   markPageInteraction: -> @state.hasInteraction = true
  68
  69 module.exports = VimFrame