extension/lib/vimfx.coffee

   1 ###
   2 # Copyright Simon Lydell 2015.
   3 #
   4 # This file is part of VimFx.
   5 #
   6 # VimFx is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # VimFx is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  18 ###
  19
  20 # This file defines a top-level object to hold global state for VimFx. It keeps
  21 # track of all `Vim` instances (vim.coffee), all options and all keyboard
  22 # shortcuts. It can consume key presses according to its commands, and return
  23 # the commands for UI presentation. There is only one `VimFx` instance.
  24
  25 notation = require('vim-like-key-notation')
  26 prefs    = require('./prefs')
  27 utils    = require('./utils')
  28 Vim      = require('./vim')
  29
  30 DIGIT = /^\d$/
  31
  32 class VimFx extends utils.EventEmitter
  33   constructor: (@modes, @options) ->
  34     super()
  35     @vims = new WeakMap()
  36     @createKeyTrees()
  37     @reset()
  38     @on('modeChange', ({mode}) => @reset(mode))
  39
  40   SPECIAL_KEYS: ['<force>', '<late>']
  41
  42   addVim: (browser) ->
  43     @vims.set(browser, new Vim(browser, this))
  44
  45   # NOTE: This method is often called in event handlers. Many events may fire
  46   # before a `vim` object has been created for the current tab yet (such as when
  47   # the browser is starting up). Therefore always check if anything was
  48   # returned, such as:
  49   #
  50   #     return unless vim = @vimfx.getCurrentVim(@window)
  51   getCurrentVim: (window) -> @vims.get(window.gBrowser.selectedBrowser)
  52
  53   reset: (mode = null) ->
  54     @currentKeyTree = if mode then @keyTrees[mode] else {}
  55     @lastInputTime = 0
  56     @count = ''
  57
  58   createKeyTrees: ->
  59     {
  60       @keyTrees
  61       @commandsWithSpecialKeys
  62       @errors
  63     } = createKeyTrees(@getGroupedCommands(), @SPECIAL_KEYS)
  64
  65   stringifyKeyEvent: (event) ->
  66     return notation.stringify(event, {
  67       ignoreKeyboardLayout: @options.ignore_keyboard_layout
  68       translations: @options.translations
  69     })
  70
  71   consumeKeyEvent: (event, vim, focusType) ->
  72     {mode} = vim
  73     return unless keyStr = @stringifyKeyEvent(event)
  74
  75     now = Date.now()
  76     @reset(mode) if now - @lastInputTime >= @options.timeout
  77     @lastInputTime = now
  78
  79     toplevel = (@currentKeyTree == @keyTrees[mode])
  80
  81     if toplevel and @options.keyValidator
  82       unless @options.keyValidator(keyStr, mode)
  83         @reset(mode)
  84         return
  85
  86     type = 'none'
  87     command = null
  88
  89     switch
  90       when keyStr of @currentKeyTree and
  91            not (toplevel and keyStr == '0' and @count != '')
  92         next = @currentKeyTree[keyStr]
  93         if next instanceof Leaf
  94           type = 'full'
  95           command = next.command
  96         else
  97           @currentKeyTree = next
  98           type = 'partial'
  99
 100       when toplevel and DIGIT.test(keyStr) and
 101            not (keyStr == '0' and @count == '')
 102         @count += keyStr
 103         type = 'count'
 104
 105       else
 106         @reset(mode)
 107
 108     count = if @count == '' then undefined else Number(@count)
 109     specialKeys = @commandsWithSpecialKeys[command?.pref] ? {}
 110     focus = @adjustFocusType(event, vim, focusType, keyStr)
 111     unmodifiedKey = notation.parse(keyStr).key
 112     @reset(mode) if type == 'full'
 113     return {
 114       type, focus, command, count, specialKeys, keyStr, unmodifiedKey, toplevel
 115     }
 116
 117   adjustFocusType: (event, vim, focusType, keyStr) ->
 118     # Frame scripts and the tests don’t pass in `originalTarget`.
 119     document = event.originalTarget?.ownerDocument
 120     if focusType == null and document and
 121        # TODO: Remove when Tab Groups have been removed.
 122        (vim.window.TabView?.isVisible() or
 123         document.fullscreenElement or document.mozFullScreenElement)
 124       return 'other'
 125
 126     keys = @options["#{focusType}_element_keys"]
 127     return null if keys and keyStr not in keys
 128
 129     return focusType
 130
 131   getGroupedCommands: (options = {}) ->
 132     modes = {}
 133     for modeName, mode of @modes
 134       if options.enabledOnly
 135         usedSequences = getUsedSequences(@keyTrees[modeName])
 136       for commandName, command of mode.commands
 137         enabledSequences = null
 138         if options.enabledOnly
 139           enabledSequences = utils.removeDuplicates(
 140             command._sequences.filter((sequence) ->
 141               return (usedSequences[sequence] == command.pref)
 142             )
 143           )
 144           continue if enabledSequences.length == 0
 145         categories = modes[modeName] ?= {}
 146         category = categories[command.category] ?= []
 147         category.push(
 148           {command, enabledSequences, order: command.order, name: commandName}
 149         )
 150
 151     modesSorted = []
 152     for modeName, categories of modes
 153       categoriesSorted = []
 154       for categoryName, commands of categories
 155         category = @options.categories[categoryName]
 156         categoriesSorted.push({
 157           name:     category.name()
 158           _name:    categoryName
 159           order:    category.order
 160           commands: commands.sort(byOrder)
 161         })
 162       mode = @modes[modeName]
 163       modesSorted.push({
 164         name:       mode.name()
 165         _name:      modeName
 166         order:      mode.order
 167         categories: categoriesSorted.sort(byOrder)
 168       })
 169     return modesSorted.sort(byOrder)
 170
 171 byOrder = (a, b) -> a.order - b.order
 172
 173 class Leaf
 174   constructor: (@command, @originalSequence) ->
 175
 176 createKeyTrees = (groupedCommands, specialKeys) ->
 177   keyTrees = {}
 178   errors = {}
 179   commandsWithSpecialKeys = {}
 180
 181   pushError = (error, command) ->
 182     (errors[command.pref] ?= []).push(error)
 183
 184   pushOverrideErrors = (command, tree) ->
 185     {command: overridingCommand, originalSequence} = getFirstLeaf(tree)
 186     error =
 187       id:      'overridden_by'
 188       subject: overridingCommand.description()
 189       context: originalSequence
 190     pushError(error, command)
 191
 192   pushSpecialKeyError = (command, originalSequence, key) ->
 193     error =
 194       id: 'illegal_special_key'
 195       subject: key
 196       context: originalSequence
 197     pushError(error, command)
 198
 199   for mode in groupedCommands
 200     keyTrees[mode._name] = {}
 201     for category in mode.categories then for {command} in category.commands
 202       {shortcuts, errors: parseErrors} = parseShortcutPref(command.pref)
 203       pushError(error, command) for error in parseErrors
 204       command._sequences = []
 205
 206       for shortcut in shortcuts
 207         [prefixKeys..., lastKey] = shortcut.normalized
 208         tree = keyTrees[mode._name]
 209         command._sequences.push(shortcut.original)
 210         seenNonSpecialKey = false
 211
 212         errored = false
 213         for prefixKey, index in prefixKeys
 214           if prefixKey in specialKeys
 215             if seenNonSpecialKey
 216               pushSpecialKeyError(command, shortcut.original, prefixKey)
 217               errored = true
 218               break
 219             else
 220               (commandsWithSpecialKeys[command.pref] ?= {})[prefixKey] = true
 221               continue
 222           else
 223             seenNonSpecialKey = true
 224
 225           if prefixKey of tree
 226             next = tree[prefixKey]
 227             if next instanceof Leaf
 228               pushOverrideErrors(command, next)
 229               errored = true
 230               break
 231             else
 232               tree = next
 233           else
 234             tree = tree[prefixKey] = {}
 235         continue if errored
 236
 237         if lastKey in specialKeys
 238           subject = if seenNonSpecialKey then lastKey else shortcut.original
 239           pushSpecialKeyError(command, shortcut.original, subject)
 240           continue
 241         if lastKey of tree
 242           pushOverrideErrors(command, tree[lastKey])
 243           continue
 244         tree[lastKey] = new Leaf(command, shortcut.original)
 245
 246   return {keyTrees, commandsWithSpecialKeys, errors}
 247
 248 parseShortcutPref = (pref) ->
 249   shortcuts = []
 250   errors    = []
 251
 252   # The shorcut prefs are read from root in order to support other extensions to
 253   # extend VimFx with custom commands.
 254   prefValue = prefs.root.get(pref).trim()
 255
 256   unless prefValue == ''
 257     for sequence in prefValue.split(/\s+/)
 258       shortcut = []
 259       errored  = false
 260       for key in notation.parseSequence(sequence)
 261         try
 262           shortcut.push(notation.normalize(key))
 263         catch error
 264           throw error unless error.id?
 265           errors.push(error)
 266           errored = true
 267           break
 268       shortcuts.push({normalized: shortcut, original: sequence}) unless errored
 269
 270   return {shortcuts, errors}
 271
 272 getFirstLeaf = (node) ->
 273   if node instanceof Leaf
 274     return node
 275   for key, value of node
 276     return getFirstLeaf(value)
 277
 278 getLeaves = (node) ->
 279   if node instanceof Leaf
 280     return [node]
 281   leaves = []
 282   for key, value of node
 283     leaves.push(getLeaves(value)...)
 284   return leaves
 285
 286 getUsedSequences = (tree) ->
 287   usedSequences = {}
 288   for leaf in getLeaves(tree)
 289     usedSequences[leaf.originalSequence] = leaf.command.pref
 290   return usedSequences
 291
 292 module.exports = VimFx