extension/packages/commands.coffee

   1 utils = require 'utils'
   2 help  = require 'help'
   3 { _ } = require 'l10n'
   4 { getPref
   5 , getComplexPref
   6 , setPref
   7 , isPrefSet } = require 'prefs'
   8
   9 { classes: Cc, interfaces: Ci, utils: Cu } = Components
  10
  11 # “Selecting an element” means “focusing and selecting the text, if any, of an
  12 # element”.
  13
  14 # Select the Address Bar.
  15 command_focus = (vim) ->
  16   # This function works even if the Address Bar has been removed.
  17   vim.rootWindow.focusAndSelectUrlBar()
  18
  19 # Select the Search Bar.
  20 command_focus_search = (vim) ->
  21   # The `.webSearch()` method opens a search engine in a tab if the Search Bar
  22   # has been removed. Therefore we first check if it exists.
  23   if vim.rootWindow.BrowserSearch.searchBar
  24     vim.rootWindow.BrowserSearch.webSearch()
  25
  26 helper_paste = (vim) ->
  27   url = utils.readFromClipboard(vim.window)
  28   postData = null
  29   if not utils.isURL(url) and submission = utils.browserSearchSubmission(url)
  30     url = submission.uri.spec
  31     { postData } = submission
  32   return {url, postData}
  33
  34 # Go to or search for the contents of the system clipboard.
  35 command_paste = (vim) ->
  36   { url, postData } = helper_paste(vim)
  37   vim.rootWindow.gBrowser.loadURIWithFlags(url, null, null, null, postData)
  38
  39 # Go to or search for the contents of the system clipboard in a new tab.
  40 command_paste_tab = (vim) ->
  41   { url, postData } = helper_paste(vim)
  42   vim.rootWindow.gBrowser.selectedTab =
  43     vim.rootWindow.gBrowser.addTab(url, null, null, postData, null, false)
  44
  45 # Copy the URL or text of a marker element to the system clipboard.
  46 command_marker_yank = (vim) ->
  47   callback = (marker) ->
  48     if url = marker.element.href
  49       marker.element.focus()
  50       utils.writeToClipboard(url)
  51     else if utils.isTextInputElement(marker.element)
  52       utils.writeToClipboard(marker.element.value)
  53
  54   vim.enterMode('hints', callback)
  55
  56 # Focus element.
  57 command_marker_focus = (vim) ->
  58   callback = (marker) -> marker.element.focus()
  59
  60   vim.enterMode('hints', callback)
  61
  62 # Copy the current URL to the system clipboard.
  63 command_yank = (vim) ->
  64   utils.writeToClipboard(vim.window.location.href)
  65
  66 # Reload the current tab, possibly from cache.
  67 command_reload = (vim) ->
  68   vim.rootWindow.BrowserReload()
  69
  70 # Reload the current tab, skipping cache.
  71 command_reload_force = (vim) ->
  72   vim.rootWindow.BrowserReloadSkipCache()
  73
  74 # Reload all tabs, possibly from cache.
  75 command_reload_all = (vim) ->
  76   vim.rootWindow.gBrowser.reloadAllTabs()
  77
  78 # Reload all tabs, skipping cache.
  79 command_reload_all_force = (vim) ->
  80   for tab in vim.rootWindow.gBrowser.visibleTabs
  81     window = tab.linkedBrowser.contentWindow
  82     window.location.reload(true)
  83
  84 # Stop loading the current tab.
  85 command_stop = (vim) ->
  86   vim.window.stop()
  87
  88 # Stop loading all tabs.
  89 command_stop_all = (vim) ->
  90   for tab in vim.rootWindow.gBrowser.visibleTabs
  91     window = tab.linkedBrowser.contentWindow
  92     window.stop()
  93
  94 # Scroll to the top of the page.
  95 command_scroll_to_top = (vim) ->
  96   vim.rootWindow.goDoCommand('cmd_scrollTop')
  97
  98 # Scroll to the bottom of the page.
  99 command_scroll_to_bottom = (vim) ->
 100   vim.rootWindow.goDoCommand('cmd_scrollBottom')
 101
 102 # Scroll down a bit.
 103 command_scroll_down = (vim) ->
 104   step = getPref('scroll_step_lines')
 105   utils.simulateWheel(vim.window, 0, +step, utils.WHEEL_MODE_LINE)
 106
 107 # Scroll up a bit.
 108 command_scroll_up = (vim) ->
 109   step = getPref('scroll_step_lines')
 110   utils.simulateWheel(vim.window, 0, -step, utils.WHEEL_MODE_LINE)
 111
 112 # Scroll left a bit.
 113 command_scroll_left = (vim) ->
 114   step = getPref('scroll_step_lines')
 115   utils.simulateWheel(vim.window, -step, 0, utils.WHEEL_MODE_LINE)
 116
 117 # Scroll right a bit.
 118 command_scroll_right = (vim) ->
 119   step = getPref('scroll_step_lines')
 120   utils.simulateWheel(vim.window, +step, 0, utils.WHEEL_MODE_LINE)
 121
 122 # Scroll down half a page.
 123 command_scroll_half_page_down = (vim) ->
 124   utils.simulateWheel(vim.window, 0, +0.5, utils.WHEEL_MODE_PAGE)
 125
 126 # Scroll up half a page.
 127 command_scroll_half_page_up = (vim) ->
 128   utils.simulateWheel(vim.window, 0, -0.5, utils.WHEEL_MODE_PAGE)
 129
 130 # Scroll down full a page.
 131 command_scroll_page_down = (vim) ->
 132   utils.simulateWheel(vim.window, 0, +1, utils.WHEEL_MODE_PAGE)
 133
 134 # Scroll up full a page.
 135 command_scroll_page_up = (vim) ->
 136   utils.simulateWheel(vim.window, 0, -1, utils.WHEEL_MODE_PAGE)
 137
 138 # Open a new tab and select the Address Bar.
 139 command_open_tab = (vim) ->
 140   vim.rootWindow.BrowserOpenTab()
 141
 142 # Switch to the previous tab.
 143 command_tab_prev = (vim) ->
 144   wrap = true
 145   vim.rootWindow.gBrowser.tabContainer.advanceSelectedTab(-1, true) # wrap
 146
 147 # Switch to the next tab.
 148 command_tab_next = (vim) ->
 149   wrap = true
 150   vim.rootWindow.gBrowser.tabContainer.advanceSelectedTab(+1, true) # wrap
 151
 152 # Move the current tab backward.
 153 command_tab_move_left = (vim) ->
 154   { gBrowser } = vim.rootWindow
 155   lastIndex = gBrowser.tabContainer.selectedIndex
 156   gBrowser.moveTabBackward()
 157   if gBrowser.tabContainer.selectedIndex == lastIndex
 158     gBrowser.moveTabToEnd()
 159
 160 # Move the current tab forward.
 161 command_tab_move_right = (vim) ->
 162   { gBrowser } = vim.rootWindow
 163   lastIndex = gBrowser.tabContainer.selectedIndex
 164   gBrowser.moveTabForward()
 165   if gBrowser.tabContainer.selectedIndex == lastIndex
 166     gBrowser.moveTabToStart()
 167
 168 # Load the home page.
 169 command_home = (vim) ->
 170   vim.rootWindow.BrowserHome()
 171
 172 # Switch to the first tab.
 173 command_tab_first = (vim) ->
 174   vim.rootWindow.gBrowser.selectTabAtIndex(0)
 175
 176 # Switch to the last tab.
 177 command_tab_last = (vim) ->
 178   vim.rootWindow.gBrowser.selectTabAtIndex(-1)
 179
 180 # Duplicate current tab.
 181 command_duplicate_tab = (vim) ->
 182   { gBrowser } = vim.rootWindow
 183   gBrowser.duplicateTab(gBrowser.selectedTab)
 184
 185 # Close all tabs from current to the right.
 186 command_close_tabs_to_end = (vim) ->
 187   { gBrowser } = vim.rootWindow
 188   gBrowser.removeTabsToTheEndFrom(gBrowser.selectedTab)
 189
 190 # Close all tabs except the current.
 191 command_close_other_tabs = (vim) ->
 192   { gBrowser } = vim.rootWindow
 193   gBrowser.removeAllTabsBut(gBrowser.selectedTab)
 194
 195 # Close current tab.
 196 command_close_tab = (vim) ->
 197   unless vim.rootWindow.gBrowser.selectedTab.pinned
 198     vim.rootWindow.gBrowser.removeCurrentTab()
 199
 200 # Restore last closed tab.
 201 command_restore_tab = (vim) ->
 202   vim.rootWindow.undoCloseTab()
 203
 204 helper_follow = ({ inTab, multiple }, vim) ->
 205   callback = (matchedMarker, markers) ->
 206     matchedMarker.element.focus()
 207     utils.simulateClick(matchedMarker.element, {metaKey: inTab, ctrlKey: inTab})
 208     isEditable = utils.isElementEditable(matchedMarker.element)
 209     if multiple and not isEditable
 210       # By not resetting immediately one is able to see the last char being
 211       # matched, which gives some nice visual feedback that you've typed the
 212       # right char.
 213       vim.window.setTimeout((-> marker.reset() for marker in markers), 100)
 214       return true
 215
 216   vim.enterMode('hints', callback)
 217
 218 # Follow links with hint markers.
 219 command_follow = helper_follow.bind(undefined, {inTab: false})
 220
 221 # Follow links in a new Tab with hint markers.
 222 command_follow_in_tab = helper_follow.bind(undefined, {inTab: true})
 223
 224 # Follow multiple links with hint markers.
 225 command_follow_multiple = helper_follow.bind(undefined, {inTab: true, multiple: true})
 226
 227 helper_follow_pattern = do ->
 228   # Search for the prev/next patterns in the following attributes of the
 229   # element. `rel` should be kept as the first attribute, since the standard
 230   # way of marking up prev/next links (`rel="prev"` and `rel="next"`) should be
 231   # favored. Even though some of these attributes only allow a fixed set of
 232   # keywords, we pattern-match them anyways since lots of sites don’t follow
 233   # the spec and use the attributes arbitrarily.
 234   attrs = ['rel', 'role', 'data-tooltip', 'aria-label']
 235
 236   return (type, vim) ->
 237     links = utils.getMarkableElements(vim.window.document, {type: 'action'})
 238       .filter(utils.isElementVisible)
 239
 240     patterns = utils.splitListString(getComplexPref("#{ type }_patterns"))
 241
 242     if matchingLink = utils.getBestPatternMatch(patterns, attrs, links)
 243       utils.simulateClick(matchingLink, {metaKey: false, ctrlKey: false})
 244
 245 # Follow previous page.
 246 command_follow_prev = helper_follow_pattern.bind(undefined, 'prev')
 247
 248 # Follow next page.
 249 command_follow_next = helper_follow_pattern.bind(undefined, 'next')
 250
 251 # Go up one level in the URL hierarchy.
 252 command_go_up_path = (vim) ->
 253   path = vim.window.location.pathname
 254   vim.window.location.pathname = path.replace(/// / [^/]+ /?$ ///, '')
 255
 256 # Go up to root of the URL hierarchy.
 257 command_go_to_root = (vim) ->
 258   vim.window.location.href = vim.window.location.origin
 259
 260 # Go back in history.
 261 command_back = (vim) ->
 262   vim.rootWindow.BrowserBack()
 263
 264 # Go forward in history.
 265 command_forward = (vim) ->
 266   vim.rootWindow.BrowserForward()
 267
 268 findStorage = {lastSearchString: ''}
 269
 270 helper_find = (highlight, vim) ->
 271   findBar = vim.rootWindow.gBrowser.getFindBar()
 272
 273   findBar.onFindCommand()
 274   findBar._findField.focus()
 275   findBar._findField.select()
 276
 277   return unless highlightButton = findBar.getElement('highlight')
 278   if highlightButton.checked != highlight
 279     highlightButton.click()
 280
 281 # Open the find bar, making sure that hightlighting is off.
 282 command_find = helper_find.bind(undefined, false)
 283
 284 # Open the find bar, making sure that hightlighting is on.
 285 command_find_hl = helper_find.bind(undefined, true)
 286
 287 helper_find_again = (direction, vim) ->
 288   findBar = vim.rootWindow.gBrowser.getFindBar()
 289   if findStorage.lastSearchString.length > 0
 290     findBar._findField.value = findStorage.lastSearchString
 291     findBar.onFindAgainCommand(direction)
 292
 293 # Search for the last pattern.
 294 command_find_next = helper_find_again.bind(undefined, false)
 295
 296 # Search for the last pattern backwards.
 297 command_find_prev = helper_find_again.bind(undefined, true)
 298
 299 # Enter insert mode.
 300 command_insert_mode = (vim) ->
 301   vim.enterMode('insert')
 302
 303 # Display the Help Dialog.
 304 command_help = (vim) ->
 305   help.injectHelp(vim.window.document, commands)
 306
 307 # Open and select the Developer Toolbar.
 308 command_dev = (vim) ->
 309   vim.rootWindow.DeveloperToolbar.show(true) # focus
 310
 311 command_Esc = (vim, event) ->
 312   utils.blurActiveElement(vim.window)
 313
 314   # Blur active XUL control.
 315   callback = -> event.originalTarget?.ownerDocument?.activeElement?.blur()
 316   vim.window.setTimeout(callback, 0)
 317
 318   help.removeHelp(vim.window.document)
 319
 320   vim.rootWindow.DeveloperToolbar.hide()
 321
 322   vim.rootWindow.gBrowser.getFindBar().close()
 323
 324   vim.rootWindow.TabView.hide()
 325
 326
 327 class Command
 328   constructor: (@group, @name, @func, keys) ->
 329     @defaultKeys = keys
 330     if isPrefSet(@prefName('keys'))
 331       try @keyValues = JSON.parse(getPref(@prefName('keys')))
 332     else
 333       @keyValues = keys
 334
 335   # Name of the preference for a given property.
 336   prefName: (value) -> "commands.#{ @name }.#{ value }"
 337
 338   keys: (value) ->
 339     if value is undefined
 340       return @keyValues
 341     else
 342       @keyValues = value or @defaultKeyValues
 343       setPref(@prefName('keys'), value and JSON.stringify(value))
 344
 345   help: -> _("help_command_#{ @name }")
 346
 347 commands = [
 348   new Command('urls',   'focus',                 command_focus,                 ['o'])
 349   new Command('urls',   'focus_search',          command_focus_search,          ['O'])
 350   new Command('urls',   'paste',                 command_paste,                 ['p'])
 351   new Command('urls',   'paste_tab',             command_paste_tab,             ['P'])
 352   new Command('urls',   'marker_yank',           command_marker_yank,           ['y,f'])
 353   new Command('urls',   'marker_focus',          command_marker_focus,          ['v,f'])
 354   new Command('urls',   'yank',                  command_yank,                  ['y,y'])
 355   new Command('urls',   'reload',                command_reload,                ['r'])
 356   new Command('urls',   'reload_force',          command_reload_force,          ['R'])
 357   new Command('urls',   'reload_all',            command_reload_all,            ['a,r'])
 358   new Command('urls',   'reload_all_force',      command_reload_all_force,      ['a,R'])
 359   new Command('urls',   'stop',                  command_stop,                  ['s'])
 360   new Command('urls',   'stop_all',              command_stop_all,              ['a,s'])
 361
 362   new Command('nav',    'scroll_to_top',         command_scroll_to_top ,        ['g,g'])
 363   new Command('nav',    'scroll_to_bottom',      command_scroll_to_bottom,      ['G'])
 364   new Command('nav',    'scroll_down',           command_scroll_down,           ['j', 'c-e'])
 365   new Command('nav',    'scroll_up',             command_scroll_up,             ['k', 'c-y'])
 366   new Command('nav',    'scroll_left',           command_scroll_left,           ['h'])
 367   new Command('nav',    'scroll_right',          command_scroll_right ,         ['l'])
 368   new Command('nav',    'scroll_half_page_down', command_scroll_half_page_down, ['d'])
 369   new Command('nav',    'scroll_half_page_up',   command_scroll_half_page_up,   ['u'])
 370   new Command('nav',    'scroll_page_down',      command_scroll_page_down,      ['c-f'])
 371   new Command('nav',    'scroll_page_up',        command_scroll_page_up,        ['c-b'])
 372
 373   new Command('tabs',   'open_tab',              command_open_tab,              ['t'])
 374   new Command('tabs',   'tab_prev',              command_tab_prev,              ['J', 'g,T'])
 375   new Command('tabs',   'tab_next',              command_tab_next,              ['K', 'g,t'])
 376   new Command('tabs',   'tab_move_left',         command_tab_move_left,         ['c-J'])
 377   new Command('tabs',   'tab_move_right',        command_tab_move_right,        ['c-K'])
 378   new Command('tabs',   'home',                  command_home,                  ['g,h'])
 379   new Command('tabs',   'tab_first',             command_tab_first,             ['g,H', 'g,^'])
 380   new Command('tabs',   'tab_last',              command_tab_last,              ['g,L', 'g,$'])
 381   new Command('tabs',   'duplicate_tab',         command_duplicate_tab,         [])
 382   new Command('tabs',   'close_tabs_to_end',     command_close_tabs_to_end,     [])
 383   new Command('tabs',   'close_other_tabs',      command_close_other_tabs,      [])
 384   new Command('tabs',   'close_tab',             command_close_tab,             ['x'])
 385   new Command('tabs',   'restore_tab',           command_restore_tab,           ['X'])
 386
 387   new Command('browse', 'follow',                command_follow,                ['f'])
 388   new Command('browse', 'follow_in_tab',         command_follow_in_tab,         ['F'])
 389   new Command('browse', 'follow_multiple',       command_follow_multiple,       ['a,f'])
 390   new Command('browse', 'follow_previous',       command_follow_prev,           ['['])
 391   new Command('browse', 'follow_next',           command_follow_next,           [']'])
 392   new Command('browse', 'go_up_path',            command_go_up_path,            ['g,u'])
 393   new Command('browse', 'go_to_root',            command_go_to_root,            ['g,U'])
 394   new Command('browse', 'back',                  command_back,                  ['H'])
 395   new Command('browse', 'forward',               command_forward,               ['L'])
 396
 397   new Command('misc',   'find',                  command_find,                  ['/'])
 398   new Command('misc',   'find_hl',               command_find_hl,               ['a,/'])
 399   new Command('misc',   'find_next',             command_find_next,             ['n'])
 400   new Command('misc',   'find_prev',             command_find_prev,             ['N'])
 401   new Command('misc',   'insert_mode',           command_insert_mode,           ['i'])
 402   new Command('misc',   'help',                  command_help,                  ['?'])
 403   new Command('misc',   'dev',                   command_dev,                   [':'])
 404
 405   escapeCommand =
 406   new Command('misc',   'Esc',                   command_Esc,                   ['Esc'])
 407 ]
 408
 409 searchForMatchingCommand = (keys) ->
 410   for index in [0...keys.length] by 1
 411     str = keys[index..].join(',')
 412     for command in commands
 413       for key in command.keys()
 414         # The following hack is a workaround for the issue where letter `c` is
 415         # considered a start of command with control modifier `c-xxx`.
 416         if "#{ key },".startsWith("#{ str },")
 417           return {match: true, exact: (key == str), command}
 418
 419   return {match: false}
 420
 421 isEscCommandKey = (keyStr) -> keyStr in escapeCommand.keys()
 422
 423 exports.commands                  = commands
 424 exports.searchForMatchingCommand  = searchForMatchingCommand
 425 exports.isEscCommandKey           = isEscCommandKey
 426 exports.findStorage               = findStorage