extension/lib/modes.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014.
   4 # Copyright Wang Zhuochun 2014.
   5 #
   6 # This file is part of VimFx.
   7 #
   8 # VimFx is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # VimFx is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  20 ###
  21
  22 { commands
  23 , findStorage }              = require('./commands')
  24 defaults                     = require('./defaults')
  25 help                         = require('./help')
  26 hints                        = require('./hints')
  27 translate                    = require('./l10n')
  28 { rotateOverlappingMarkers } = require('./marker')
  29 utils                        = require('./utils')
  30
  31 { interfaces: Ci } = Components
  32
  33 XULDocument = Ci.nsIDOMXULDocument
  34
  35 # Helper to create modes in a DRY way.
  36 mode = (modeName, obj, commands) ->
  37   obj.name  = translate.bind(null, "mode.#{ modeName }")
  38   obj.order = defaults.mode_order[modeName]
  39   obj.commands = {}
  40   for commandName, fn of commands
  41     pref = "mode.#{ modeName }.#{ commandName }"
  42     obj.commands[commandName] =
  43       pref:        defaults.BRANCH + pref
  44       run:         fn
  45       category:    defaults.categoryMap[pref]
  46       description: translate.bind(null, pref)
  47       order:       defaults.command_order[pref]
  48   exports[modeName] = obj
  49
  50
  51
  52 mode('normal', {
  53   onEnter: ->
  54
  55   onLeave: ({ vim, storage }) ->
  56     storage.inputs = null
  57     help.removeHelp(vim.rootWindow)
  58
  59   onInput: (args, match) ->
  60     { vim, storage, event } = args
  61     { keyStr } = match
  62
  63     if storage.inputs
  64       index = storage.inputs.indexOf(vim.window.document.activeElement)
  65       if index >= 0
  66         storage.inputIndex = index
  67       else
  68         storage.inputs = null
  69
  70     autoInsertMode = (match.focus != null)
  71     if match.type == 'none' or (autoInsertMode and not match.force)
  72       return false
  73
  74     if match.type == 'full'
  75       { command } = match
  76       # Rely on the default `<tab>` behavior, since it allows web pages to
  77       # provide tab completion, for example, inside text inputs.
  78       unless match.toplevel and not storage.inputs and
  79              ((command.run == commands.focus_previous and keyStr == '<tab>') or
  80               (command.run == commands.focus_next     and keyStr == '<s-tab>'))
  81         command.run(args)
  82
  83     # At this point the match is either full, partial or part of a count. Then
  84     # we always want to suppress, except for one case: The Escape key.
  85     #
  86     # - It allows for stopping the loading of the page.
  87     # - It allows for closing many custom dialogs (and perhaps other things
  88     #   -- Esc is a very commonly used key).
  89     # - It is not passed if Esc is used for `command_Esc` and we’re blurring
  90     #   an element. That allows for blurring an input in a custom dialog
  91     #   without closing the dialog too.
  92     # - There are two reasons we might suppress it in other modes. If some
  93     #   custom dialog of a website is open, we should be able to cancel hint
  94     #   markers on it without closing it. Secondly, otherwise cancelling hint
  95     #   markers on Google causes its search bar to be focused.
  96     # - It may only be suppressed in web pages, not in browser chrome. That
  97     #   allows for reseting the location bar when blurring it, and closing
  98     #   dialogs such as the “bookmark this page” dialog (<c-d>).
  99     document = event.originalTarget.ownerDocument
 100     inBrowserChrome = (document instanceof XULDocument)
 101     if keyStr == '<escape>' and (not autoInsertMode or inBrowserChrome)
 102       return false
 103
 104     return true
 105
 106 }, commands)
 107
 108
 109
 110 mode('hints', {
 111   onEnter: ({ vim, storage, args: [ filter, callback ] }) ->
 112     [ markers, container ] = hints.injectHints(
 113       vim.rootWindow, vim.window, filter, vim.parent.options
 114     )
 115     if markers.length > 0
 116       storage.markers   = markers
 117       storage.container = container
 118       storage.callback  = callback
 119       storage.numEnteredChars = 0
 120     else
 121       vim.enterMode('normal')
 122
 123   onLeave: ({ vim, storage }) ->
 124     { container } = storage
 125     vim.rootWindow.setTimeout((->
 126       container?.remove()
 127     ), vim.parent.options.hints_timeout)
 128     for key of storage
 129       storage[key] = null
 130
 131   onInput: (args, match) ->
 132     { vim, storage } = args
 133     { markers, callback } = storage
 134
 135     if match.type == 'full'
 136       match.command.run(args)
 137     else if match.keyStr in vim.parent.options.hint_chars
 138       matchedMarkers = []
 139
 140       for marker in markers when marker.hintIndex == storage.numEnteredChars
 141         matched = marker.matchHintChar(match.keyStr)
 142         marker.hide() unless matched
 143         if marker.isMatched()
 144           marker.markMatched(true)
 145           matchedMarkers.push(marker)
 146
 147       if matchedMarkers.length > 0
 148         again = callback(matchedMarkers[0])
 149         if again
 150           vim.rootWindow.setTimeout((->
 151             marker.markMatched(false) for marker in matchedMarkers
 152           ), vim.parent.options.hints_timeout)
 153           marker.reset() for marker in markers
 154           storage.numEnteredChars = 0
 155         else
 156           vim.enterMode('normal')
 157       else
 158         storage.numEnteredChars++
 159
 160     return true
 161
 162 }, {
 163   exit: ({ vim, storage }) ->
 164     # The hints are removed automatically when leaving the mode, but after a
 165     # timeout. When aborting the mode we should remove the hints immediately.
 166     storage.container?.remove()
 167     vim.enterMode('normal')
 168
 169   rotate_markers_forward: ({ storage }) ->
 170     rotateOverlappingMarkers(storage.markers, true)
 171
 172   rotate_markers_backward: ({ storage }) ->
 173     rotateOverlappingMarkers(storage.markers, false)
 174
 175   delete_hint_char: ({ storage }) ->
 176     for marker in storage.markers
 177       switch marker.hintIndex - storage.numEnteredChars
 178         when  0 then marker.deleteHintChar()
 179         when -1 then marker.show()
 180     storage.numEnteredChars-- unless storage.numEnteredChars == 0
 181 })
 182
 183
 184
 185 mode('ignore', {
 186   onEnter: ({ vim, storage, args: [ count ] }) ->
 187     storage.count = count ? null
 188
 189   onLeave: ({ vim }) ->
 190     utils.blurActiveElement(vim.window)
 191
 192   onInput: (args, match) ->
 193     { vim, storage } = args
 194     switch storage.count
 195       when null
 196         if match.type == 'full'
 197           match.command.run(args)
 198           return true
 199       when 1
 200         vim.enterMode('normal')
 201       else
 202         storage.count--
 203     return false
 204
 205 }, {
 206   exit: ({ vim }) -> vim.enterMode('normal')
 207 })
 208
 209
 210
 211 mode('find', {
 212   onEnter: ->
 213
 214   onLeave: ({ vim }) ->
 215     findBar = vim.rootWindow.gBrowser.getFindBar()
 216     findStorage.lastSearchString = findBar._findField.value
 217
 218   onInput: (args, match) ->
 219     args.findBar = args.vim.rootWindow.gBrowser.getFindBar()
 220     if match.type == 'full'
 221       match.command.run(args)
 222       return true
 223     return false
 224
 225 }, {
 226   exit: ({ findBar }) -> findBar.close()
 227 })