extension/lib/events-frame.coffee

   1 ###
   2 # Copyright Simon Lydell 2015, 2016.
   3 #
   4 # This file is part of VimFx.
   5 #
   6 # VimFx is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # VimFx is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  18 ###
  19
  20 # This file is the equivalent to events.coffee, but for frame scripts.
  21
  22 notation = require('vim-like-key-notation')
  23 commands = require('./commands-frame')
  24 messageManager = require('./message-manager')
  25 prefs = require('./prefs')
  26 utils = require('./utils')
  27
  28 nsIFocusManager = Cc['@mozilla.org/focus-manager;1']
  29   .getService(Ci.nsIFocusManager)
  30
  31 XULDocument = Ci.nsIDOMXULDocument
  32
  33 class FrameEventManager
  34   constructor: (@vim) ->
  35     @numFocusToSuppress = 0
  36     @keepInputs = false
  37     @currentUrl = false
  38     @disconnectActiveElementObserver = null
  39
  40   listen: utils.listen.bind(null, FRAME_SCRIPT_ENVIRONMENT)
  41   listenOnce: utils.listenOnce.bind(null, FRAME_SCRIPT_ENVIRONMENT)
  42
  43   addListeners: ->
  44     # If the page already was loaded when VimFx was initialized, send the
  45     # 'frameCanReceiveEvents' message straight away.
  46     if @vim.content.document.readyState == 'complete'
  47       messageManager.send('frameCanReceiveEvents', true)
  48
  49     @listen('readystatechange', (event) =>
  50       target = event.originalTarget
  51       topDocument = @vim.content.document
  52       [oldUrl, @currentUrl] = [@currentUrl, @vim.content.location.href]
  53
  54       switch target.readyState
  55         when 'interactive'
  56           if target == topDocument or
  57              # When loading the editor on codepen.io, a frame gets
  58              # 'readystatechange' → 'interactive' quite a bit before the
  59              # toplevel document does. Checking for this case lets us send
  60              # 'locationChange' earlier, allowing to enter Ignore mode earlier,
  61              # for example. Be careful not to trigger a 'locationChange' for
  62              # frames loading _after_ the toplevel document, though. Finally,
  63              # checking for 'uninitialized' is needed to be able to blacklist
  64              # some XUL pages.
  65              (topDocument.readyState in ['loading', 'uninitialized'] and
  66               oldUrl == null)
  67             messageManager.send('locationChange', @currentUrl)
  68
  69         when 'complete'
  70           if target == topDocument
  71             messageManager.send('frameCanReceiveEvents', true)
  72     )
  73
  74     @listen('pageshow', (event) =>
  75       [oldUrl, @currentUrl] = [@currentUrl, @vim.content.location.href]
  76
  77       # When navigating the history, `event.persisted` is `true` (meaning that
  78       # the page loaded from cache) and 'readystatechange' won’t be fired, so
  79       # send a 'locationChange' message to make sure that the blacklist is
  80       # applied etc. The reason we don’t simply _always_ do this on the
  81       # 'pageshow' event, is because it usually fires too late. However, it also
  82       # fires after having moved a tab to another window. In that case it is
  83       # _not_ a location change; the blacklist should not be applied.
  84       if event.persisted
  85         url = @vim.content.location.href
  86         messageManager.send('cachedPageshow', null, (movedToNewTab) =>
  87           if not movedToNewTab and oldUrl != @currentUrl
  88             messageManager.send('locationChange', @currentUrl)
  89         )
  90     )
  91
  92     @listen('pagehide', (event) =>
  93       target = event.originalTarget
  94       @currentUrl = null
  95
  96       if target == @vim.content.document
  97         messageManager.send('frameCanReceiveEvents', false)
  98
  99       # If the target isn’t the topmost document, it means that a frame has
 100       # changed: It could have been removed or its `src` attribute could have
 101       # been changed. If the frame contains other frames, 'pagehide' events have
 102       # already been fired for them.
 103       @vim.resetState(target)
 104     )
 105
 106     messageManager.listen('getMarkableElementsMovements', (data, callback) =>
 107       diffs = @vim.state.markerElements.map(({element, originalRect}) ->
 108         newRect = element.getBoundingClientRect()
 109         return {
 110           dx: newRect.left - originalRect.left
 111           dy: newRect.top  - originalRect.top
 112         }
 113       )
 114       callback(diffs)
 115     )
 116
 117     @listen('overflow', (event) =>
 118       target = event.originalTarget
 119       @vim.state.scrollableElements.addChecked(target)
 120     )
 121
 122     @listen('underflow', (event) =>
 123       target = event.originalTarget
 124       @vim.state.scrollableElements.deleteChecked(target)
 125     )
 126
 127     @listen('keydown', (event) =>
 128       @keepInputs = false
 129     )
 130
 131     @listen('keydown', ((event) =>
 132       suppress = false
 133
 134       # This message _has_ to be synchronous so we can suppress the event if
 135       # needed. To avoid sending a synchronous message on _every_ keydown, this
 136       # hack of toggling a pref when a `<late>` shortcut is encountered is used.
 137       if prefs.get('late')
 138         suppress = messageManager.get('lateKeydown', {
 139           defaultPrevented: event.defaultPrevented
 140         })
 141
 142       if @vim.state.inputs and @vim.mode == 'normal' and not suppress and
 143          not event.defaultPrevented
 144         # There is no need to take `ignore_keyboard_layout` and `translations`
 145         # into account here, since we want to override the _native_ `<tab>`
 146         # behavior. Then, `event.key` is the way to go. (Unless the prefs are
 147         # customized. YAGNI until requested.)
 148         keyStr = notation.stringify(event)
 149         direction = switch keyStr
 150           when ''
 151             null
 152           when prefs.get('focus_previous_key')
 153             -1
 154           when prefs.get('focus_next_key')
 155             +1
 156           else
 157             null
 158         if direction?
 159           suppress = commands.move_focus({@vim, direction})
 160           @keepInputs = true
 161
 162       if suppress
 163         utils.suppressEvent(event)
 164         @listenOnce('keyup', utils.suppressEvent, false)
 165     ), false)
 166
 167     @listen('mousedown', (event) =>
 168       # Allow clicking on another text input without exiting “gi mode”. Listen
 169       # for 'mousedown' instead of 'click', because only the former runs before
 170       # the 'blur' event. Also, `event.originalTarget` does _not_ work here.
 171       @keepInputs = (@vim.state.inputs and event.target in @vim.state.inputs)
 172
 173       # Clicks are always counted as page interaction. Listen for 'mousedown'
 174       # instead of 'click' to mark the interaction as soon as possible.
 175       @vim.markPageInteraction()
 176     )
 177
 178     messageManager.listen('browserRefocus', =>
 179       # Suppress the next two focus events (for `document` and `window`; see
 180       # `blurActiveBrowserElement`).
 181       @numFocusToSuppress = 2
 182     )
 183
 184     @listen('focus', (event) =>
 185       target = event.originalTarget
 186
 187       if @numFocusToSuppress > 0
 188         utils.suppressEvent(event)
 189         @numFocusToSuppress -= 1
 190         return
 191
 192       @vim.state.explicitBodyFocus = (target == @vim.content.document.body)
 193
 194       @sendFocusType()
 195
 196       # Reset `hasInteraction` when (re-)selecting a tab, or coming back from
 197       # another window, in order to prevent the common “automatically re-focus
 198       # when switching back to the tab” behaviour many sites have, unless a text
 199       # input _should_ be re-focused when coming back to the tab (see the 'blur'
 200       # event below).
 201       if target == @vim.content.document
 202         if @vim.state.shouldRefocus
 203           @vim.state.hasInteraction = true
 204           @vim.state.shouldRefocus = false
 205         else
 206           @vim.state.hasInteraction = false
 207         return
 208
 209       # Save the last focused text input regardless of whether that input might
 210       # be blurred because of autofocus prevention.
 211       if utils.isTextInputElement(target)
 212         @vim.state.lastFocusedTextInput = target
 213         @vim.state.hasFocusedTextInput = true
 214
 215       # Blur the focus target, if autofocus prevention is enabled…
 216       if prefs.get('prevent_autofocus') and
 217          @vim.mode in prefs.get('prevent_autofocus_modes').split(/\s+/) and
 218          # …and the user has interacted with the page…
 219          not @vim.state.hasInteraction and
 220          # …and the event is programmatic (not caused by clicks or keypresses)…
 221          nsIFocusManager.getLastFocusMethod(null) == 0 and
 222          # …and the target may steal most keystrokes…
 223          utils.isTypingElement(target) and
 224          # …and the page isn’t a Firefox internal page (like `about:config`).
 225          @vim.content.document not instanceof XULDocument
 226         # Some sites (such as icloud.com) re-focuses inputs if they are blurred,
 227         # causing an infinite loop of autofocus prevention and re-focusing.
 228         # Therefore, blur events that happen just after an autofocus prevention
 229         # are suppressed.
 230         @listenOnce('blur', utils.suppressEvent)
 231         target.blur()
 232         @vim.state.hasFocusedTextInput = false
 233     )
 234
 235     @listen('blur', (event) =>
 236       target = event.originalTarget
 237
 238       @sendFocusType()
 239
 240       # If a text input is blurred immediately before the document loses focus,
 241       # it most likely means that the user switched tab, for example by pressing
 242       # `<c-tab>`, or switched to another window, while the text input was
 243       # focused. In this case, when switching back to that tab, the text input
 244       # will, and should, be re-focused (because it was focused when you left
 245       # the tab). This case is kept track of so that the autofocus prevention
 246       # does not catch it.
 247       if utils.isTypingElement(target)
 248         utils.nextTick(@vim.content, =>
 249           @vim.state.shouldRefocus = not @vim.content.document.hasFocus()
 250
 251           # “gi mode” ends when blurring a text input, unless `<tab>` was just
 252           # pressed.
 253           unless @vim.state.shouldRefocus or @keepInputs
 254             commands.clear_inputs({@vim})
 255         )
 256     )
 257
 258   sendFocusType: ({ignore = []} = {}) ->
 259     return unless activeElement = utils.getActiveElement(@vim.content)
 260     focusType = utils.getFocusType(activeElement)
 261     messageManager.send('focusType', focusType) unless focusType in ignore
 262
 263     # If a text input is removed from the DOM while it is focused, no 'focus'
 264     # or 'blur' events will be fired, making VimFx think that the text input is
 265     # still focused. Therefore we add a temporary observer for the currently
 266     # focused element and re-send the focusType if it gets removed.
 267     @disconnectActiveElementObserver?()
 268     @disconnectActiveElementObserver =
 269       if focusType == 'none'
 270         null
 271       else
 272         utils.onRemoved(activeElement, @sendFocusType.bind(this))
 273
 274 module.exports = FrameEventManager