extension/lib/button.coffee

   1 ###
   2 # Copyright Simon Lydell 2015.
   3 #
   4 # This file is part of VimFx.
   5 #
   6 # VimFx is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # VimFx is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  18 ###
  19
  20 # This file creates VimFx’s toolbar button.
  21
  22 help = require('./help')
  23 translate = require('./l10n')
  24 utils = require('./utils')
  25
  26 cui = Cu.import('resource:///modules/CustomizableUI.jsm', {}).CustomizableUI
  27
  28 BUTTON_ID = 'VimFxButton'
  29
  30 injectButton = (vimfx) ->
  31   cui.createWidget({
  32     id: BUTTON_ID
  33     defaultArea: cui.AREA_NAVBAR
  34     label: 'VimFx'
  35     tooltiptext: translate('button.tooltip.normal')
  36     onCommand: (event) ->
  37       button = event.originalTarget
  38       window = button.ownerGlobal
  39       return unless vim = vimfx.getCurrentVim(window)
  40
  41       if vim.mode == 'normal'
  42         help.injectHelp(window, vimfx)
  43       else
  44         vim.enterMode('normal')
  45   })
  46   module.onShutdown(cui.destroyWidget.bind(cui, BUTTON_ID))
  47
  48   vimfx.on('modeDisplayChange', (vim) ->
  49     {window} = vim
  50     # When the browser starts, the button might not be available yet.
  51     return unless button = getButton(window)
  52
  53     tooltip =
  54       if vim.mode == 'normal'
  55         translate('button.tooltip.normal')
  56       else
  57         translate('button.tooltip.other_mode',
  58                   translate("mode.#{vim.mode}"), translate('mode.normal'))
  59     button.setAttribute('tooltiptext', tooltip)
  60   )
  61
  62 getButton = (window) -> window.document.getElementById(BUTTON_ID)
  63
  64 module.exports = {
  65   injectButton
  66   getButton
  67 }