extension/lib/hints.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file contains functions for getting markable elements, and related data,
  22 # as well as for creating and inserting markers for markable elements.
  23
  24 huffman = require('n-ary-huffman')
  25 {Marker} = require('./marker')
  26 utils = require('./utils')
  27
  28 try
  29   # TODO: Only use this path when Firefox 44 is released.
  30   {devtools} = Cu.import('resource://devtools/shared/Loader.jsm', {})
  31 catch
  32   {devtools} = Cu.import('resource://gre/modules/devtools/Loader.jsm', {})
  33
  34 CONTAINER_ID = 'VimFxMarkersContainer'
  35
  36 Element = Ci.nsIDOMElement
  37 XULDocument = Ci.nsIDOMXULDocument
  38
  39 shutdownHandlerAdded = false
  40
  41 # For some time we used to return the hints container from `injectHints`, and
  42 # use that reference to remove the hints when needed. That’s fine in theory, but
  43 # in case anything breaks we might loose that reference and end up with
  44 # unremovable hints on the screen. Explicitly looking for an element with the
  45 # container ID is more fail-safe.
  46 removeHints = (window) ->
  47   window.document.getElementById(CONTAINER_ID)?.remove()
  48
  49 # Create `Marker`s for every element (represented by a regular object of data
  50 # about the element—a “wrapper,” a stand-in for the real element, which is only
  51 # accessible in frame scripts) in `wrappers`, and insert them into `window`.
  52 injectHints = (window, wrappers, viewport, options) ->
  53   semantic = []
  54   unsemantic = []
  55   combined = []
  56   markerMap = {}
  57
  58   for wrapper in wrappers
  59     marker = new Marker(wrapper, window.document)
  60     group = switch
  61       when wrapper.parentIndex?
  62         combined
  63       when wrapper.semantic
  64         semantic
  65       else
  66         unsemantic
  67     group.push(marker)
  68     markerMap[wrapper.elementIndex] = marker
  69
  70   markers = semantic.concat(unsemantic)
  71
  72   # Each marker gets a unique `z-index`, so that it can be determined if a
  73   # marker overlaps another. Put more important markers (higher weight) at the
  74   # end, so that they get higher `z-index`, in order not to be overlapped.
  75   zIndex = 0
  76   setZIndexes = (markers) ->
  77     markers.sort((a, b) -> a.weight - b.weight)
  78     for marker in markers when marker not instanceof huffman.BranchPoint
  79       marker.markerElement.style.zIndex = zIndex
  80       zIndex += 1
  81       # Add `z-index` space for all the children of the marker.
  82       zIndex += marker.wrapper.numChildren if marker.wrapper.numChildren?
  83     return
  84
  85   # The `markers` passed to this function have been sorted by `setZIndexes` in
  86   # advance, so we can skip sorting in the `huffman.createTree` function.
  87   hintChars = options.hint_chars
  88   createHuffmanTree = (markers) ->
  89     return huffman.createTree(markers, hintChars.length, {sorted: true})
  90
  91   # Semantic elements should always get better hints and higher `z-index`:es
  92   # than unsemantic ones, even if they are smaller. The former is achieved by
  93   # putting the unsemantic elements in their own branch of the huffman tree.
  94   if unsemantic.length > 0
  95     if markers.length > hintChars.length
  96       setZIndexes(unsemantic)
  97       subTree = createHuffmanTree(unsemantic)
  98       semantic.push(subTree)
  99     else
 100       semantic.push(unsemantic...)
 101
 102   setZIndexes(semantic)
 103
 104   tree = createHuffmanTree(semantic)
 105   tree.assignCodeWords(hintChars, (marker, hint) -> marker.setHint(hint))
 106
 107   # Markers for links with the same href can be combined to use the same hint.
 108   # They should all have the same `z-index` (because they all have the same
 109   # combined weight), but in case any of them cover another they still get a
 110   # unique `z-index` (space for this was added in `setZIndexes`).
 111   for marker in combined
 112     parent = markerMap[marker.wrapper.parentIndex]
 113     marker.markerElement.style.zIndex = parent.markerElement.style.zIndex
 114     parent.markerElement.style.zIndex += 1
 115     marker.setHint(parent.hint)
 116   markers.push(combined...)
 117
 118   removeHints(window) # Better safe than sorry.
 119   container = window.document.createElement('box')
 120   container.id = CONTAINER_ID
 121
 122   zoom = 1
 123
 124   if options.ui
 125     container.classList.add('ui')
 126     window.document.getElementById('browser-panel').appendChild(container)
 127   else
 128     {ZoomManager, gBrowser: {selectedBrowser: browser}} = window
 129     browser.parentNode.appendChild(container)
 130     # If “full zoom” is not used, it means that “Zoom text only” is enabled.
 131     # If so, that “zoom” does not need to be taken into account.
 132     # `.getCurrentMode()` is added by the “Default FullZoom Level” extension.
 133     if ZoomManager.getCurrentMode?(browser) ? ZoomManager.useFullZoom
 134       zoom = ZoomManager.getZoomForBrowser(browser)
 135
 136   for marker in markers
 137     container.appendChild(marker.markerElement)
 138     # Must be done after the hints have been inserted into the DOM (see
 139     # marker.coffee).
 140     marker.setPosition(viewport, zoom)
 141
 142   unless shutdownHandlerAdded
 143     module.onShutdown(removeHints.bind(null, window))
 144     shutdownHandlerAdded = true
 145
 146   return {markers, markerMap}
 147
 148 getMarkableElementsAndViewport = (window, filter) ->
 149   {
 150     clientWidth, clientHeight # Viewport size excluding scrollbars, usually.
 151     scrollWidth, scrollHeight
 152   } = window.document.documentElement
 153   {innerWidth, innerHeight} = window # Viewport size including scrollbars.
 154   # We don’t want markers to cover the scrollbars, so we should use
 155   # `clientWidth` and `clientHeight`. However, when there are no scrollbars
 156   # those might be too small. Then we use `innerWidth` and `innerHeight`.
 157   width  = if scrollWidth  > innerWidth  then clientWidth  else innerWidth
 158   height = if scrollHeight > innerHeight then clientHeight else innerHeight
 159   viewport = {
 160     left: 0
 161     top: 0
 162     right: width
 163     bottom: height
 164     width
 165     height
 166   }
 167
 168   wrappers = []
 169   getMarkableElements(window, viewport, wrappers, filter)
 170   return {wrappers, viewport}
 171
 172 # `filter` is a function that is given every element in every frame of the page.
 173 # It should return wrapper objects for markable elements and a falsy value for
 174 # all other elements. All returned wrappers are added to `wrappers`. `wrappers`
 175 # is modified instead of using return values to avoid array concatenation for
 176 # each frame. It might sound expensive to go through _every_ element, but that’s
 177 # actually what other methods like using XPath or CSS selectors would need to do
 178 # anyway behind the scenes.
 179 getMarkableElements = (window, viewport, wrappers, filter, parents = []) ->
 180   {document} = window
 181
 182   for element in getAllElements(document) when element instanceof Element
 183     # `getRects` is fast and filters out most elements, so run it first of all.
 184     rects = getRects(element, viewport)
 185     continue unless rects.length > 0
 186     continue unless wrapper = filter(
 187       element, (elementArg) ->
 188         return getElementShape(window, viewport, parents, elementArg,
 189                                if elementArg == element then rects else null)
 190     )
 191     wrappers.push(wrapper)
 192
 193   for frame in window.frames when frame.frameElement
 194     rect = frame.frameElement.getBoundingClientRect() # Frames only have one.
 195     continue unless isInsideViewport(rect, viewport)
 196
 197     # Calculate the visible part of the frame, according to the parent.
 198     # coffeelint: disable=colon_assignment_spacing
 199     {clientWidth, clientHeight} = frame.document.documentElement
 200     frameViewport = {
 201       left:   Math.max(viewport.left - rect.left, 0)
 202       top:    Math.max(viewport.top  - rect.top,  0)
 203       right:  clientWidth  + Math.min(viewport.right  - rect.right,  0)
 204       bottom: clientHeight + Math.min(viewport.bottom - rect.bottom, 0)
 205     }
 206     # coffeelint: enable=colon_assignment_spacing
 207
 208     # `.getComputedStyle()` may return `null` if the computed style isn’t
 209     # availble yet. If so, consider the element not visible.
 210     continue unless computedStyle = window.getComputedStyle(frame.frameElement)
 211     offset = {
 212       left: rect.left +
 213         parseFloat(computedStyle.getPropertyValue('border-left-width')) +
 214         parseFloat(computedStyle.getPropertyValue('padding-left'))
 215       top: rect.top +
 216         parseFloat(computedStyle.getPropertyValue('border-top-width')) +
 217         parseFloat(computedStyle.getPropertyValue('padding-top'))
 218     }
 219
 220     getMarkableElements(frame, frameViewport, wrappers, filter,
 221                         parents.concat({window, offset}))
 222
 223   return
 224
 225 getAllElements = (document) ->
 226   unless document instanceof XULDocument
 227     return document.getElementsByTagName('*')
 228
 229   # Use a `Set` since this algorithm may find the same element more than once.
 230   # Ideally we should find a way to find all elements without duplicates.
 231   elements = new Set()
 232   getAllRegular = (element) ->
 233     # The first time `zF` is run `.getElementsByTagName('*')` may oddly include
 234     # `undefined` in its result! Filter those out.
 235     for child in element.getElementsByTagName('*') when child
 236       elements.add(child)
 237       getAllAnonymous(child)
 238     return
 239   getAllAnonymous = (element) ->
 240     for child in document.getAnonymousNodes(element) or []
 241       continue unless child instanceof Element
 242       elements.add(child)
 243       getAllRegular(child)
 244     return
 245   getAllRegular(document.documentElement)
 246   return Array.from(elements)
 247
 248 getRects = (element, viewport) ->
 249   # `element.getClientRects()` returns a list of rectangles, usually just one,
 250   # which is identical to the one returned by `element.getBoundingClientRect()`.
 251   # However, if `element` is inline and line-wrapped, then it returns one
 252   # rectangle for each line, since each line may be of different length, for
 253   # example. That allows us to properly add hints to line-wrapped links.
 254   return Array.filter(
 255     element.getClientRects(), (rect) -> isInsideViewport(viewport, rect)
 256   )
 257
 258 # Returns the “shape” of `element`:
 259 #
 260 # - `nonCoveredPoint`: The coordinates of the first point of `element` that
 261 #   isn’t covered by another element (except children of `element`). It also
 262 #   contains the offset needed to make those coordinates relative to the top
 263 #   frame, as well as the rectangle that the coordinates occur in.
 264 # - `area`: The area of the part of `element` that is inside `viewport`.
 265 #
 266 # Returns `null` if `element` is outside `viewport` or entirely covered by other
 267 # elements.
 268 getElementShape = (window, viewport, parents, element, rects = null) ->
 269   rects ?= getRects(element, viewport)
 270   totalArea = 0
 271   visibleRects = []
 272   for rect in rects
 273     visibleRect = adjustRectToViewport(rect, viewport)
 274     continue if visibleRect.area == 0
 275     totalArea += visibleRect.area
 276     visibleRects.push(visibleRect)
 277
 278   if visibleRects.length == 0
 279     if rects.length == 1 and totalArea == 0
 280       [rect] = rects
 281       if rect.width > 0 or rect.height > 0
 282         # If we get here, it means that everything inside `element` is floated
 283         # and/or absolutely positioned (and that `element` hasn’t been made to
 284         # “contain” the floats). For example, a link in a menu could contain a
 285         # span of text floated to the left and an icon floated to the right.
 286         # Those are still clickable. Therefore we return the shape of the first
 287         # visible child instead. At least in that example, that’s the best bet.
 288         for child in element.children
 289           shape = getElementShape(window, viewport, parents, child)
 290           return shape if shape
 291     return null
 292
 293   # Even if `element` has a visible rect, it might be covered by other elements.
 294   for visibleRect in visibleRects
 295     nonCoveredPoint = getFirstNonCoveredPoint(window, viewport, element,
 296                                               visibleRect, parents)
 297     break if nonCoveredPoint
 298
 299   return null unless nonCoveredPoint
 300
 301   return {
 302     nonCoveredPoint, area: totalArea
 303   }
 304
 305 MINIMUM_EDGE_DISTANCE = 4
 306 isInsideViewport = (rect, viewport) ->
 307   return \
 308     rect.left   <= viewport.right  - MINIMUM_EDGE_DISTANCE and
 309     rect.top    <= viewport.bottom + MINIMUM_EDGE_DISTANCE and
 310     rect.right  >= viewport.left   + MINIMUM_EDGE_DISTANCE and
 311     rect.bottom >= viewport.top    - MINIMUM_EDGE_DISTANCE
 312
 313 adjustRectToViewport = (rect, viewport) ->
 314   # The right and bottom values are subtracted by 1 because
 315   # `document.elementFromPoint(right, bottom)` does not return the element
 316   # otherwise.
 317   left   = Math.max(rect.left,       viewport.left)
 318   right  = Math.min(rect.right - 1,  viewport.right)
 319   top    = Math.max(rect.top,        viewport.top)
 320   bottom = Math.min(rect.bottom - 1, viewport.bottom)
 321
 322   # Make sure that `right >= left and bottom >= top`, since we subtracted by 1
 323   # above.
 324   right  = Math.max(right, left)
 325   bottom = Math.max(bottom, top)
 326
 327   width  = right - left
 328   height = bottom - top
 329   area   = Math.floor(width * height)
 330
 331   return {
 332     left, right, top, bottom
 333     height, width, area
 334   }
 335
 336 getFirstNonCoveredPoint = (window, viewport, element, elementRect, parents) ->
 337   # Tries a point `(x + dx, y + dy)`. Returns `(x, y)` (and the frame offset)
 338   # if it passes the tests. Otherwise it tries to the right of whatever is at
 339   # `(x, y)`, `tryRight` times . If nothing succeeds, `false` is returned. `dx`
 340   # and `dy` are used to offset the wanted point `(x, y)` while trying (see the
 341   # invocations of `tryPoint` below).
 342   tryPoint = (x, dx, y, dy, tryRight = 0) ->
 343     elementAtPoint = window.document.elementFromPoint(x + dx, y + dy)
 344     offset = {left: 0, top: 0}
 345     found = false
 346     firstLevel = true
 347
 348     # Ensure that `element`, or a child of `element` (anything inside an `<a>`
 349     # is clickable too), really is present at (x,y). Note that this is not 100%
 350     # bullet proof: Combinations of CSS can cause this check to fail, even
 351     # though `element` isn’t covered. We don’t try to temporarily reset such CSS
 352     # because of performance. Instead we rely on that some of the attempts below
 353     # will work. (See further down for the special value `-1` of `tryRight`.)
 354     if contains(element, elementAtPoint) or tryRight == -1
 355       found = true
 356       # If we’re currently in a frame, there might be something on top of the
 357       # frame that covers `element`. Therefore we ensure that the frame really
 358       # is present at the point for each parent in `parents`.
 359       currentWindow = window
 360       for parent in parents by -1
 361         # If leaving the devtools container take the devtools zoom into account.
 362         if currentWindow.DevTools and not parent.window.DevTools
 363           toolbox = window.gDevTools.getToolbox(
 364             devtools.TargetFactory.forTab(window.top.gBrowser.selectedTab)
 365           )
 366           if toolbox
 367             devtoolsZoom = toolbox.zoomValue
 368             offset.left *= devtoolsZoom
 369             offset.top  *= devtoolsZoom
 370             x  *= devtoolsZoom
 371             y  *= devtoolsZoom
 372             dx *= devtoolsZoom
 373             dy *= devtoolsZoom
 374
 375         offset.left += parent.offset.left
 376         offset.top  += parent.offset.top
 377         elementAtPoint = parent.window.document.elementFromPoint(
 378           offset.left + x + dx, offset.top + y + dy
 379         )
 380         firstLevel = false
 381         unless contains(currentWindow.frameElement, elementAtPoint)
 382           found = false
 383           break
 384         currentWindow = parent.window
 385
 386     return {x, y, offset} if found
 387
 388     return false if elementAtPoint == null or tryRight <= 0
 389     rect = elementAtPoint.getBoundingClientRect()
 390
 391     # `.getBoundingClientRect()` does not include pseudo-elements that are
 392     # absolutely positioned so that they go outside of the element (which is
 393     # common for `/###\`-looking tabs), but calling `.elementAtPoint()` on the
 394     # pseudo-element _does_ return the element. This means that the covering
 395     # element’s _rect_ won’t cover the element we’re looking for. If so, it’s
 396     # better to try again, forcing the element to be considered located at this
 397     # point. That’s what `-1` for the `tryRight` argument means.
 398     if firstLevel and rect.right <= x + offset.left
 399       return tryPoint(x, dx, y, dy, -1)
 400
 401     x = rect.right - offset.left + 1
 402     return false if x > viewport.right
 403     return tryPoint(x, 0, y, 0, tryRight - 1)
 404
 405
 406   # Try the left-middle point, or immediately to the right of a covering element
 407   # at that point. If both of those are covered the whole element is considered
 408   # to be covered. The reasoning is:
 409   #
 410   # - A marker should show up as near the left edge of its visible area as
 411   #   possible. Having it appear to the far right (for example) is confusing.
 412   # - We can’t try too many times because of performance.
 413   # - We used to try left-top first, but if `element` has `border-radius`, the
 414   #   corners won’t really belong to `element`, so `document.elementFromPoint()`
 415   #   will return whatever is behind. This will result in missing or
 416   #   out-of-place markers. The solution is to temporarily add a CSS class that
 417   #   removes `border-radius`, but that turned out to be rather slow, making it
 418   #   not worth it. Usually you don’t see the difference between left-top and
 419   #   left-middle, because links are usually not that high.
 420   # - We used to try left-bottom as well, but that is so rare that it’s not
 421   #   worth it.
 422   #
 423   # It is safer to try points at least one pixel into the element from the
 424   # edges, hence the `+1`.
 425   {left, top, bottom, height} = elementRect
 426   nonCoveredPoint = tryPoint(left, +1, Math.floor(top + height / 2), 0, 1)
 427
 428   return nonCoveredPoint
 429
 430 # In XUL documents there are “anonymous” elements. These are never returned by
 431 # `document.elementFromPoint` but their closest non-anonymous parents are.
 432 normalize = (element) ->
 433   normalized = element.ownerDocument.getBindingParent(element) or element
 434   normalized = normalized.parentNode while normalized.prefix?
 435   return normalized
 436
 437 # Returns whether `element` corresponds to `elementAtPoint`. This is only
 438 # complicated for browser elements in the web page content area.
 439 # `.elementAtPoint()` always returns `<tabbrowser#content>` then. The element
 440 # might be in another tab and thus invisible, but `<tabbrowser#content>` is the
 441 # same and visible in _all_ tabs, so we have to check that the element really
 442 # belongs to the current tab.
 443 contains = (element, elementAtPoint) ->
 444   return false unless elementAtPoint
 445   container = normalize(element)
 446   if elementAtPoint.nodeName == 'tabbrowser' and elementAtPoint.id == 'content'
 447     {gBrowser} = element.ownerGlobal.top
 448     tabpanel = gBrowser.getNotificationBox(gBrowser.selectedBrowser)
 449     return tabpanel.contains(element)
 450   else
 451     # Note that `a.contains(a)` is supposed to be true, but strangely aren’t for
 452     # `<menulist>`s in the Add-ons Manager, so do a direct comparison as well.
 453     return container == elementAtPoint or container.contains(elementAtPoint)
 454
 455 module.exports = {
 456   removeHints
 457   injectHints
 458   getMarkableElementsAndViewport
 459 }