extension/lib/main.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file pulls in all the different parts of VimFx, initializes them, and
  22 # stiches them together.
  23
  24 button = require('./button')
  25 config = require('./config')
  26 defaults = require('./defaults')
  27 UIEventManager = require('./events')
  28 {applyMigrations} = require('./legacy')
  29 messageManager = require('./message-manager')
  30 migrations = require('./migrations')
  31 modes = require('./modes')
  32 options = require('./options')
  33 parsePref = require('./parse-prefs')
  34 prefs = require('./prefs')
  35 utils = require('./utils')
  36 VimFx = require('./vimfx')
  37 test = try require('../test/index')
  38
  39 Cu.import('resource://gre/modules/AddonManager.jsm')
  40
  41 module.exports = (data, reason) ->
  42   # Set default prefs and apply migrations as early as possible.
  43   prefs.default.init()
  44   applyMigrations(migrations)
  45
  46   parsedOptions = {}
  47   for pref of defaults.all_options
  48     parsedOptions[pref] = parsePref(pref)
  49   vimfx = new VimFx(modes, parsedOptions)
  50   vimfx.id = data.id
  51   vimfx.version = data.version
  52   AddonManager.getAddonByID(vimfx.id, (info) -> vimfx.info = info)
  53
  54   utils.loadCss("#{ADDON_PATH}/skin/style.css")
  55
  56   options.observe(vimfx)
  57
  58   prefs.observe('', (pref) ->
  59     if pref.startsWith('mode.') or pref.startsWith('custom.')
  60       vimfx.createKeyTrees()
  61     else if pref of defaults.all_options
  62       value = parsePref(pref)
  63       vimfx.options[pref] = value
  64   )
  65
  66   button.injectButton(vimfx)
  67
  68   setWindowAttribute = (window, name, value = 'none') ->
  69     window.document.documentElement.setAttribute("vimfx-#{name}", value)
  70
  71   onModeDisplayChange = (vimOrEvent) ->
  72     window = vimOrEvent.window ? vimOrEvent.originalTarget.ownerGlobal
  73
  74     # If the passed `vim` is brand new, `vim.mode` is not available until in the
  75     # next tick (see `Vim::constructor`), so wait for it.
  76     utils.nextTick(window, ->
  77       # The 'modeChange' event provides the `vim` object that changed mode, but
  78       # it might not be the current `vim` anymore so always get the current one.
  79       return unless vim = vimfx.getCurrentVim(window)
  80
  81       setWindowAttribute(window, 'mode', vim.mode)
  82       vimfx.emit('modeDisplayChange', vim)
  83     )
  84
  85   vimfx.on('modeChange', onModeDisplayChange)
  86   vimfx.on('TabSelect',  onModeDisplayChange)
  87
  88   vimfx.on('focusTypeChange', ({vim, focusType}) ->
  89     setWindowAttribute(vim.window, 'focus-type', focusType)
  90   )
  91
  92   windows = new WeakSet()
  93   messageManager.listen('tabCreated', (data, callback, browser) ->
  94     # Frame scripts are run in more places than we need. Tell those not to do
  95     # anything.
  96     unless browser.getAttribute('messagemanagergroup') == 'browsers'
  97       callback(false)
  98       return
  99
 100     window = browser.ownerGlobal
 101     vimfx.addVim(browser)
 102
 103     unless windows.has(window)
 104       windows.add(window)
 105       eventManager = new UIEventManager(vimfx, window)
 106       eventManager.addListeners(vimfx, window)
 107       setWindowAttribute(window, 'mode', 'normal')
 108       setWindowAttribute(window, 'focus-type', null)
 109
 110     callback(true)
 111   )
 112
 113   messageManager.load("#{ADDON_PATH}/content/bootstrap.js")
 114
 115   config.load(vimfx)
 116   vimfx.on('shutdown', -> messageManager.send('unloadConfig'))
 117   module.onShutdown(->
 118     # Make sure to run the below lines in this order. The second line results in
 119     # removing all message listeners in frame scripts, including the one for
 120     # 'unloadConfig' (see above).
 121     vimfx.emit('shutdown')
 122     messageManager.send('shutdown')
 123   )
 124
 125   if test
 126     test(vimfx)
 127     runFrameTests = true
 128     messageManager.listen('runTests', (data, callback) ->
 129       callback(runFrameTests)
 130       runFrameTests = false
 131     )